show_activity_id

Синтаксис

									stock show_activity_id(idtarget, idadmin, const name[], const fmt[], any:...)
									{
     if (idtarget == 0 || !is_user_connected(idtarget))
     {
          return;
     }

     static __amx_show_activity;
     if (__amx_show_activity == 0)
     {
          __amx_show_activity = get_cvar_pointer("amx_show_activity");

          // if still not found, then register the cvar as a dummy
          if (__amx_show_activity == 0)
          {
               __amx_show_activity = register_cvar("amx_show_activity", "2", FCVAR_PROTECTED);
          }
     }

     static prefix[10];
     if (is_user_admin(idadmin))
     {
          copy(prefix, charsmax(prefix), "ADMIN");
     }
     else
     {
          copy(prefix, charsmax(prefix), "PLAYER");
     }

     static buffer[512];
     vformat(buffer, charsmax(buffer), fmt, 5);

     switch (get_pcvar_num(__amx_show_activity))
     {
          case 5: // hide name only to admins, show nothing to normal users
          {
               if (is_user_admin(idtarget))
               {
                    client_print(idtarget, print_chat, "%L: %s", idtarget, prefix, buffer);
               }
          }
          case 4: // show name only to admins, show nothing to normal users
          {
               if (is_user_admin(idtarget))
               {
                    client_print(idtarget, print_chat, "%L %s: %s", idtarget, prefix, name, buffer);
               }
          }
          case 3: // show name only to admins, hide name from normal users
          {
               if (is_user_admin(idtarget))
               {
                    client_print(idtarget, print_chat, "%L %s: %s", idtarget, prefix, name, buffer);
               }
               else
               {
                    client_print(idtarget, print_chat, "%L: %s", idtarget, prefix, buffer);
               }
          }
          case 2: // show name to all
          {
               client_print(idtarget, print_chat, "%L %s: %s", idtarget, prefix, name, buffer);
          }
          case 1: // hide name to all
          {
               client_print(idtarget, print_chat, "%L: %s", idtarget, prefix, buffer);
          }
     }
}
								

Client index to display message to

Client index performing the action

Name of client performing the action

Formatting rules

Variable number of formatting parameters

Описание

Standard method to show admin activity to a single client. This depends on the amx_show_activity cvar. See documentation for more details.

Возвращает

Функция ничего не возвращает