Chat Manager 1.1.2-16

TOplM · 7 Дек 2018

Не работает цвет чата

7 Дек 2018

TOplM написал(а):
Не работает цвет чата

Алексеич · 7 Дек 2018

TOplM, у меня работает

fantom · 7 Дек 2018

TOplM, 1. вам в раздел https://dev-cs.ru/forums/plugins-errors/post-thread
2. уточните за каких обстоятельств не работает

TOplM · 9 Дек 2018

Ладно сам поищу чё там случилось :good2:

Rasul · 13 Дек 2018

Разобрался)))

TDinfestedterran · 23 Мар 2019

На 10/10.
Но беда в том, что для того, чтобы приставка отображалась на первом месте, пришлось весь код изучать, и джамшутить все под себя.

23 Мар 2019

+ У меня на сервере, везде, буквально во всех плагинах, есть приставка - имя сервера.
А тут пол часа искал строку c [^4ChatManager]

Но все равно 10/10

VladJkee · 23 Мар 2019

TDinfestedterran, наверное потому-что ^4[ChatManager]^1

TDinfestedterran · 26 Мар 2019

Засуньте это в "шапку".

Меняем местами функции вывода (префикс, aes звание, стим и т.д.)

public FormatMessage(sender, name_color, chat_color, time_code[], message[])
{

new szText[MESSAGE_LENGTH], len = 1;
szText[0] = PRETEXT_COLOR;

#if defined FUNCTION_PLAYER_PREFIX
len += formatex(szText[len], charsmax(szText) - len, "%s", g_sPlayerPrefix[sender]);
#endif

#if defined FUNCTION_AES_TAGS
new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag));
len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag);
#endif

#if defined FUNCTION_ADD_STEAM_PREFIX
if(g_bSteamPlayer[sender])
{
len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX);
}
#endif

#if defined FUNCTION_ADD_TIME_CODE
len += formatex(szText[len], charsmax(szText) - len, "%s", time_code);
#endif

#if defined FUNCTION_BETA_SUPPORT
new name[32]; get_user_name(sender, name, charsmax(name));
len += formatex(szText[len], charsmax(szText) - len, "%c%s^1 :%c %s", name_color, name, chat_color, message);
#else
len += formatex(szText[len], charsmax(szText) - len, "%c%%s1^1 :%c %s", name_color, chat_color, message);
#endif

copy(g_sMessage, charsmax(g_sMessage), szText);
}

Заходим в исходник, и ищем строку:

Код:

public FormatMessage

Поставим, например так: Сначала [BGCOLOR=rgb(0, 0, 0)]префикс[/BGCOLOR], потом [BGCOLOR=rgb(44, 130, 201)]звание[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]Стим[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]ник[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]сообщение[/BGCOLOR]. И удалим Жив/мертв и Тим строку:
Удаляем строки:

Код:

    if(channel % 2)
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s", channel != 7 ? "*DEAD*" : "*SPEC*");
    }

и вот эту:

Код:

static const szTeamNames[CsTeams][] = {"(Spectator)", "(Terrorist)", "(Counter-Terrorist)", "(Spectator)"};

А так же:

Код:

    if(channel > 1 && channel < 7)
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s ", szTeamNames[sender_team]);
    }
    else if(channel)
    {
        len += formatex(szText[len], charsmax(szText) - len, " ");
    }

Далее, сортируем.

Находим и вырезаем:

Код:

    #if defined FUNCTION_PLAYER_PREFIX
    len += formatex(szText[len], charsmax(szText) - len, "%s", g_sPlayerPrefix[sender]);
    #endif

Вставляем Под

Код:

    new szText[MESSAGE_LENGTH], len = 1;
    szText[0] = PRETEXT_COLOR;

Под Префиксом вставляем:

Код:

    #if defined FUNCTION_AES_TAGS
    new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag));
    len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag);
    #endif

Под званием вставляем:

Код:

    #if defined FUNCTION_ADD_STEAM_PREFIX

    if(g_bSteamPlayer[sender])

    {

        len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX);

    }

    #endif

Сохраняем, компилим.

Небольшой бонус: изменяем сообщение о смене языка

Ищем:

Код:

public Command_LangChange

и строку

Код:

color_print(id, "^4[ChatManager]^1 You changed language to ^3%s^1.", g_bTranslite[id] ? "rus" : "eng");

заменяем на:

Код:

color_print(id, "^1[^4ChatManager^1] Вы сменили язык на ^3%s^1.", g_bTranslite[id] ? "русский" : "Английский");

Вот так этот Менеджер обходит по всем фронтам Скльпльский Chat RBS.

TDinfestedterran · 28 Мар 2019

TDinfestedterran написал(а):
Засуньте это в "шапку".

Меняем местами функции вывода (префикс, aes звание, стим и т.д.)

public FormatMessage(sender, name_color, chat_color, time_code[], message[])
{

new szText[MESSAGE_LENGTH], len = 1;
szText[0] = PRETEXT_COLOR;

#if defined FUNCTION_PLAYER_PREFIX
len += formatex(szText[len], charsmax(szText) - len, "%s", g_sPlayerPrefix[sender]);
#endif

#if defined FUNCTION_AES_TAGS
new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag));
len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag);
#endif

#if defined FUNCTION_ADD_STEAM_PREFIX
if(g_bSteamPlayer[sender])
{
len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX);
}
#endif

#if defined FUNCTION_ADD_TIME_CODE
len += formatex(szText[len], charsmax(szText) - len, "%s", time_code);
#endif

#if defined FUNCTION_BETA_SUPPORT
new name[32]; get_user_name(sender, name, charsmax(name));
len += formatex(szText[len], charsmax(szText) - len, "%c%s^1 :%c %s", name_color, name, chat_color, message);
#else
len += formatex(szText[len], charsmax(szText) - len, "%c%%s1^1 :%c %s", name_color, chat_color, message);
#endif

copy(g_sMessage, charsmax(g_sMessage), szText);
}

Заходим в исходник, и ищем строку:

Код:

public FormatMessage

Поставим, например так: Сначала [BGCOLOR=rgb(0, 0, 0)]префикс[/BGCOLOR], потом [BGCOLOR=rgb(44, 130, 201)]звание[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]Стим[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]ник[/BGCOLOR], [BGCOLOR=rgb(0, 0, 0)]сообщение[/BGCOLOR]. И удалим Жив/мертв и Тим строку:
Удаляем строки:

Код:

if(channel % 2) { len += formatex(szText[len], charsmax(szText) - len, "%s", channel != 7 ? "*DEAD*" : "*SPEC*"); }

и вот эту:

Код:

static const szTeamNames[CsTeams][] = {"(Spectator)", "(Terrorist)", "(Counter-Terrorist)", "(Spectator)"};

А так же:

Код:

if(channel > 1 && channel < 7) { len += formatex(szText[len], charsmax(szText) - len, "%s ", szTeamNames[sender_team]); } else if(channel) { len += formatex(szText[len], charsmax(szText) - len, " "); }

Далее, сортируем.

Находим и вырезаем:

Код:

#if defined FUNCTION_PLAYER_PREFIX len += formatex(szText[len], charsmax(szText) - len, "%s", g_sPlayerPrefix[sender]); #endif

Вставляем Под

Код:

new szText[MESSAGE_LENGTH], len = 1; szText[0] = PRETEXT_COLOR;

Под Префиксом вставляем:

Код:

#if defined FUNCTION_AES_TAGS new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag)); len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag); #endif

Под званием вставляем:

Код:

#if defined FUNCTION_ADD_STEAM_PREFIX if(g_bSteamPlayer[sender]) { len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX); } #endif

Сохраняем, компилим.

Небольшой бонус: изменяем сообщение о смене языка

Ищем:

Код:

public Command_LangChange

и строку

Код:

color_print(id, "^4[ChatManager]^1 You changed language to ^3%s^1.", g_bTranslite[id] ? "rus" : "eng");

заменяем на:

Код:

color_print(id, "^1[^4ChatManager^1] Вы сменили язык на ^3%s^1.", g_bTranslite[id] ? "русский" : "Английский");

Вот так этот Менеджер обходит по всем фронтам Скльпльский Chat RBS.

Исходник того, что наверху. Удачно скомпилировался как на 1.8.2 так и на 1.9.0.

r1nk0 · 1 Июн 2019

Кто нить может помочь как реализовать префикс всем остальным игрокам у кого нет флага?
пробовал вот так,но он отображается с другими префиксами у кого флаг есть.

Код:

    if(channel > 1 && channel < 7)
    {
        len += formatex(szText[len], charsmax(szText) - len, "^1[^3Префикс^1] %s ", szTeamNames[sender_team]);
    }

По флагу "z" не вариант)

Разобрался ставить префикс по умолчанию можно в строке

Код:

            if(!bFoundPrefix)
            {
                g_sPlayerPrefix[id] = "";
            }

Подскажите увеличение

#define PREFIX_MAX_LENGTH с 32 до 64 это ничего плохого?) Всмысле последствий не имеет же? А то это ограничение на длину...

praccprefere · 2 Июн 2019

Доброго временит суток. Ребята есть 2 вопроса:
1)кто подскажет по коду, как убрать префикс STEAM и звание aes у игроков с флагами
2)как расширить кол-во знаков в префиксе?

Minni · 2 Июн 2019

praccprefere написал(а):
1)кто подскажет по коду, как убрать префикс STEAM и звание aes у игроков с флагами

Деффолтный способ:

Код:

++if(~get_user_flags(sender) & ТУТ_СТАВИШЬ_ФЛАГ) {
    #if defined FUNCTION_ADD_STEAM_PREFIX
    if(g_bSteamPlayer[sender])
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX);
    }
    #endif
        
    #if defined FUNCTION_AES_TAGS
    new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag));
    len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag);
    #endif
++}

praccprefere написал(а):
2)как расширить кол-во знаков в префиксе?

Менять значение тут:

#define PREFIX_MAX_LENGTH 32
#define AES_MAX_LENGTH 32

Алексеич · 3 Июн 2019

хватит решать свои личные проблемы в общей теме! Создавайте новую тему в нужном разделе.

Dev1se · 6 Июн 2019

А почему пишет в чате "s1" а потом уже то что написал?

6 Июн 2019

Код:

;Color tags: !d - default, !t - teamcolor, !g - green
;"steam" "STEAM_0:1:1234123" "[!gScripter!d] "
;"name" "Nick" "[Prefix] "
;"flag" "a" "[VIP] "
"STEAM" "STEAM_0:0:59589666" "[!gAdministrator!d] "

Что я ни так делаю? Подскажите пожалуйста. Ниже я предоставил как в ini файле настраивал прифекс

6 Июн 2019

Помогите разобраться с прифексами, желательно с примерами

RockTheStreet · 6 Июн 2019

Dev1se написал(а):
пишет в чате "s1"

#define FUNCTION_BETA_SUPPORT

Denzer · 7 Июн 2019

Dev1se написал(а):

Код:

;Color tags: !d - default, !t - teamcolor, !g - green
;"steam" "STEAM_0:1:1234123" "[!gScripter!d] "
;"name" "Nick" "[Prefix] "
;"flag" "a" "[VIP] "
"STEAM" "STEAM_0:0:59589666" "[!gAdministrator!d] "

у тебя выше пример со всеми подробностями, неужели так сложно посмотреть, умник?

Denzer · 9 Июн 2019

Добавил возможность прописывать префиксы по SQL. Вдруг кто-то хочет доработать под себя и продавать префиксы.
При старте плагина выполняется SQL-запрос на удаление истекших префиксов. Время в UNIX-формате.

Настройки:

Код:

#define FUNCTION_SQL_PREFIX

new const szHost[] = "127.0.0.1";
new const szUser[] = "root";
new const szPass[] = "root";
new const szDb[] = "hns";
new const szTable[] = "prefixes";

Код:

/**
* Credits: BlackRose, Ian Cammarata, PRoSToTeM@.
1.1.1-12 - Add SQL for prefixes - Denzer
*/
#include <amxmodx>
#include <amxmisc>
#include <cstrike>

#define PLUGIN "[SQL] Chat Manager"
#define VERSION "1.1.1-12"
#define AUTHOR "Mistrick"

#pragma semicolon 1

#define ADMIN_FLAG ADMIN_CHAT

//Colors: DEFAULT, TEAM, GREEN
#define PRETEXT_COLOR            DEFAULT
#define PLAYER_CHAT_COLOR        DEFAULT
#define ADMIN_CHAT_COLOR        GREEN
#define PLAYER_NAME_COLOR        TEAM
#define ADMIN_NAME_COLOR        TEAM

#define FUNCTION_ALL_CHAT

#if defined FUNCTION_ALL_CHAT
//Flags: ALIVE_SEE_DEAD, DEAD_SEE_ALIVE, TEAM_SEE_TEAM
#define PLAYER_CHAT_FLAGS (ALIVE_SEE_DEAD|DEAD_SEE_ALIVE)
#define ADMIN_CHAT_FLAGS (ALIVE_SEE_DEAD|DEAD_SEE_ALIVE)
#endif

#define FUNCTION_PLAYER_PREFIX
#define FUNCTION_SQL_PREFIX
//#define FUNCTION_ADD_TIME_CODE
//#define FUNCTION_LOG_MESSAGES
//#define FUNCTION_HIDE_SLASH
//#define FUNCTION_TRANSLITE
//#define FUNCTION_AES_TAGS
#define FUNCTION_BETA_SUPPORT

//#define FUNCTION_ADD_STEAM_PREFIX

#if defined FUNCTION_ADD_STEAM_PREFIX
new const STEAM_PREFIX[] = "^1[^4Steam^1] ";
#endif

#define PREFIX_MAX_LENGTH 32
#define AES_MAX_LENGTH 32

#if defined FUNCTION_SQL_PREFIX
#include <sqlx>

new const szHost[] = "127.0.0.1";
new const szUser[] = "root";
new const szPass[] = "root";
new const szDb[] = "hns";
new const szTable[] = "prefixes";

enum _:SQL
{
    SQL_LOAD,
    SQL_CLEAR
};

enum _:FIELDS
{
    FIELD_ID,
    FIELD_STEAMID,
    FIELD_PREFIX,
    FIELD_EXPIRED
};

new Handle:g_SqlTuple;
new g_szError[512];
new g_sSqlPreifx[MAX_PLAYERS + 1][PREFIX_MAX_LENGTH];
#endif

//DONT CHANGE!!!
#define COLOR_BUFFER 6
#define TEXT_LENGTH 128
#define MESSAGE_LENGTH 189

#if defined FUNCTION_AES_TAGS
native aes_get_player_stats(id,data[4]);
native aes_get_level_name(lvlnum,level[],len,idLang = 0);
new const AES_TAG_FORMAT[] = "^1[^3%s^1] ";
#endif

const ALIVE_SEE_DEAD = (1 << 0);
const DEAD_SEE_ALIVE = (1 << 1);
const TEAM_SEE_TEAM = (1 << 2);

enum
{
    DEFAULT = 1,
    TEAM = 3,
    GREEN = 4
};

enum _:FLAG_PREFIX_INFO
{
    m_Flag,
    m_Prefix[PREFIX_MAX_LENGTH]
};

new const g_TextChannels[][] =
{
    "#Cstrike_Chat_All",
    "#Cstrike_Chat_AllDead",
    "#Cstrike_Chat_T",
    "#Cstrike_Chat_T_Dead",
    "#Cstrike_Chat_CT",
    "#Cstrike_Chat_CT_Dead",
    "#Cstrike_Chat_Spec",
    "#Cstrike_Chat_AllSpec"
};

new g_SayText;
new g_sMessage[MESSAGE_LENGTH];

#if defined FUNCTION_PLAYER_PREFIX
new const FILE_PREFIXES[] = "chatmanager_prefixes.ini";

new g_bCustomPrefix[33], g_sPlayerPrefix[33][PREFIX_MAX_LENGTH];
new Trie:g_tSteamPrefixes, g_iTrieSteamSize;
new Trie:g_tNamePrefixes, g_iTrieNameSize;
new Array:g_aFlagPrefixes, g_iArrayFlagSize;
#endif

#if defined FUNCTION_LOG_MESSAGES
new g_szLogFile[128];
#endif

#if defined FUNCTION_TRANSLITE
new g_bTranslite[33];
#endif

#if defined FUNCTION_ADD_STEAM_PREFIX
new g_bSteamPlayer[33];
#endif

enum Forwards
{
    SEND_MESSAGE
};

enum _:MessageReturn
{
    MESSAGE_IGNORED,
    MESSAGE_CHANGED,
    MESSAGE_BLOCKED
};

new g_iForwards[Forwards];
new g_sNewMessage[MESSAGE_LENGTH];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
  
    #if defined FUNCTION_PLAYER_PREFIX
    register_concmd("cm_set_prefix", "Command_SetPrefix", ADMIN_RCON, "<name or #userid> <prefix>");
    #endif
  
    #if defined FUNCTION_TRANSLITE
    register_clcmd("say /rus", "Command_LangChange");
    register_clcmd("say /eng", "Command_LangChange");
    #endif

    #if defined FUNCTION_SQL_PREFIX
    InitSQL();
    #endif
  
    register_clcmd("say", "Command_SayHandler");
    register_clcmd("say_team", "Command_SayHandler");
  
    register_message((g_SayText = get_user_msgid("SayText")), "Message_SayText");

    // cm_player_send_message(id, message[], team_chat);
    g_iForwards[SEND_MESSAGE] = CreateMultiForward("cm_player_send_message", ET_STOP, FP_CELL, FP_STRING, FP_CELL);
}
public plugin_cfg()
{
    #if defined FUNCTION_LOG_MESSAGES
    new szDir[] = "addons/amxmodx/logs/chatmanager";
    if(!dir_exists(szDir))
    {
        mkdir(szDir);
    }
    new szDate[16]; get_time("%Y%m%d", szDate, charsmax(szDate));
    formatex(g_szLogFile, charsmax(g_szLogFile), "%s/chatlog_%s.html", szDir, szDate);
    if(!file_exists(g_szLogFile))
    {
        write_file(g_szLogFile, "<meta charset=utf-8><title>ChatManager Log</title>");
    }
    #endif
  
    #if defined FUNCTION_PLAYER_PREFIX
    LoadPlayersPrefixes();
    #endif
  
    #if defined FUNCTION_AES_TAGS
    register_dictionary("aes.txt");
    #endif
}
#if defined FUNCTION_PLAYER_PREFIX
LoadPlayersPrefixes()
{
    new szDir[128]; get_localinfo("amxx_configsdir", szDir, charsmax(szDir));
    new szFile[128]; formatex(szFile, charsmax(szFile), "%s/%s", szDir, FILE_PREFIXES);
  
    if(!file_exists(szFile))
    {
        log_amx("Prefixes file doesn't exist!");
        return;
    }
  
    g_tSteamPrefixes = TrieCreate();
    g_tNamePrefixes = TrieCreate();
    g_aFlagPrefixes = ArrayCreate(FLAG_PREFIX_INFO);
  
    new file = fopen(szFile, "rt");
  
    if(file)
    {
        new szText[128], szType[6], szAuth[32], szPrefix[PREFIX_MAX_LENGTH + COLOR_BUFFER], eFlagPrefix[FLAG_PREFIX_INFO];
        while(!feof(file))
        {
            fgets(file, szText, charsmax(szText));
            parse(szText, szType, charsmax(szType), szAuth, charsmax(szAuth), szPrefix, charsmax(szPrefix));
          
            if(!szType[0] || szType[0] == ';' || !szAuth[0] || !szPrefix[0]) continue;
          
            replace_color_tag(szPrefix);
          
            switch(szType[0])
            {
                case 's'://steam
                {
                    TrieSetString(g_tSteamPrefixes, szAuth, szPrefix);
                    g_iTrieSteamSize++;
                }
                case 'n'://name
                {
                    TrieSetString(g_tNamePrefixes, szAuth, szPrefix);
                    g_iTrieNameSize++;
                }
                case 'f'://flag
                {
                    eFlagPrefix[m_Flag] = read_flags(szAuth);
                    copy(eFlagPrefix[m_Prefix], charsmax(eFlagPrefix[m_Prefix]), szPrefix);
                    ArrayPushArray(g_aFlagPrefixes, eFlagPrefix);
                    g_iArrayFlagSize++;
                }
            }
        }
        fclose(file);
    }
}
#endif
#if defined FUNCTION_SQL_PREFIX
public InitSQL()
{
    g_SqlTuple = SQL_MakeDbTuple(szHost, szUser, szPass, szDb);
    SQL_SetCharset(g_SqlTuple, "utf8");
    new ErrorCode, Handle: SqlConnection = SQL_Connect(g_SqlTuple, ErrorCode, g_szError, charsmax(g_szError));

    if(SqlConnection == Empty_Handle)
        set_fail_state(g_szError);

    new Handle:Queries;
    Queries = SQL_PrepareQuery(SqlConnection, "CREATE TABLE IF NOT EXISTS `%s` \
    (`id` INT NOT NULL AUTO_INCREMENT PRIMARY KEY, \
    `player_steamid` varchar(32) DEFAULT 'N/A', \
    `prefix` varchar(32) DEFAULT 'N/A', \
    `expired` INT(64) DEFAULT 0);", szTable);

    if(!SQL_Execute(Queries))
    {
        SQL_QueryError(Queries, g_szError, charsmax(g_szError));
        set_fail_state(g_szError);
    }
    SQL_FreeHandle(Queries);
    SQL_FreeHandle(SqlConnection);
    SQL_Clear();
}

public QueryHandle(iFailState, Handle:hQuery, szError[], iErrnum, cData[], iSize, Float:fQueueTime)
{
    if(iFailState != TQUERY_SUCCESS)
    {
        log_amx("SQL Error #%d - %s", iErrnum, szError);
        return PLUGIN_CONTINUE;
    }

    switch(cData[0])
    {
        case SQL_LOAD:
        {
            new id; id = cData[1];
            if(!is_user_connected(id))
                return PLUGIN_CONTINUE;

            if(SQL_NumResults(hQuery))
            {
                SQL_ReadResult(hQuery, FIELD_PREFIX, g_sSqlPreifx[id], charsmax(g_sSqlPreifx[]));
                mysql_escape_string(g_sSqlPreifx[id], charsmax(g_sSqlPreifx[]));
            }
        }
        case SQL_CLEAR: {}
    }
    return PLUGIN_CONTINUE;
}

public SQL_Load(id)
{
    new szQuery[256], szAuth[24];
    new cData[2]; cData[0] = SQL_LOAD; cData[1] = id;
    get_user_authid(id, szAuth, charsmax(szAuth));

    formatex(szQuery, charsmax(szQuery), "SELECT * FROM `%s` WHERE `player_steamid` = ^"%s^"", szTable, szAuth);
    SQL_ThreadQuery(g_SqlTuple, "QueryHandle", szQuery, cData, sizeof(cData));
}

public SQL_Clear()
{
    new szQuery[512];
    new cData[1]; cData[0] = SQL_CLEAR;

    formatex(szQuery, charsmax(szQuery), "DELETE FROM `%s` WHERE `expired` < %d AND `expired` <> 0", szTable, get_systime());
    SQL_ThreadQuery(g_SqlTuple, "QueryHandle", szQuery, cData, sizeof(cData));
}
#endif
public plugin_natives()
{
    register_native("cm_set_player_message", "native_set_player_message");
}
public native_set_player_message(plugin, params)
{
    enum { arg_new_message = 1 };
    get_string(arg_new_message, g_sNewMessage, charsmax(g_sNewMessage));
}
public client_putinserver(id)
{
    #if defined FUNCTION_TRANSLITE
    g_bTranslite[id] = false;
    #endif
  
    #if defined FUNCTION_PLAYER_PREFIX
    g_sPlayerPrefix[id] = "";
    g_bCustomPrefix[id] = false;
  
    new szSteam[32]; get_user_authid(id, szSteam, charsmax(szSteam));
    if(g_iTrieSteamSize && TrieKeyExists(g_tSteamPrefixes, szSteam))
    {
        g_bCustomPrefix[id] = true;
        TrieGetString(g_tSteamPrefixes, szSteam, g_sPlayerPrefix[id], charsmax(g_sPlayerPrefix[]));
    }
    #endif

    #if defined FUNCTION_SQL_PREFIX
    SQL_Load(id);
    #endif
  
    #if defined FUNCTION_ADD_STEAM_PREFIX
    g_bSteamPlayer[id] = is_user_steam(id);
    #endif
}
#if defined FUNCTION_PLAYER_PREFIX
public Command_SetPrefix(id, level, cid)
{
    if(!cmd_access(id, level, cid, 2)) return PLUGIN_HANDLED;

    new szArg[32]; read_argv(1, szArg, charsmax(szArg));
    new player = cmd_target(id, szArg, CMDTARGET_ALLOW_SELF);
  
    if(!player) return PLUGIN_HANDLED;
  
    new szPrefix[PREFIX_MAX_LENGTH + COLOR_BUFFER]; read_argv(2, szPrefix, charsmax(szPrefix));
    replace_color_tag(szPrefix);
  
    console_print(id, "You changed player prefix from %s to %s.", g_sPlayerPrefix[player], szPrefix);
  
    copy(g_sPlayerPrefix[player], charsmax(g_sPlayerPrefix[]), szPrefix);
    g_bCustomPrefix[player] = true;
  
    return PLUGIN_HANDLED;
}
#endif
#if defined FUNCTION_TRANSLITE
public Command_LangChange(id)
{
    g_bTranslite[id] = !g_bTranslite[id];
    color_print(id, "^4[ChatManager]^1 You changed language to ^3%s^1.", g_bTranslite[id] ? "rus" : "eng");
    return PLUGIN_HANDLED;
}
#endif
public Command_SayHandler(id)
{
    if (!is_user_connected(id)) return PLUGIN_HANDLED;
  
    new message[TEXT_LENGTH];
  
    read_argv(0, message, charsmax(message));
    new is_team_msg = (message[3] == '_');
  
    read_args(message, charsmax(message));
    remove_quotes(message);
    replace_wrong_simbols(message);
    trim(message);
  
    if(!message[0]) return PLUGIN_HANDLED;
  
    #if defined FUNCTION_HIDE_SLASH
    if(message[0] == '/') return PLUGIN_HANDLED_MAIN;
    #endif
  
    new flags = get_user_flags(id);
  
    new name[32]; get_user_name(id, name, charsmax(name));
  
    #if defined FUNCTION_PLAYER_PREFIX
    if(!g_bCustomPrefix[id])
    {
        if(g_iTrieNameSize && TrieKeyExists(g_tNamePrefixes, name))
        {
            TrieGetString(g_tNamePrefixes, name, g_sPlayerPrefix[id], charsmax(g_sPlayerPrefix[]));
        }
        else if(g_iArrayFlagSize)
        {
            new eFlagPrefix[FLAG_PREFIX_INFO], bFoundPrefix = false;
            for(new i; i < g_iArrayFlagSize; i++)
            {
                ArrayGetArray(g_aFlagPrefixes, i, eFlagPrefix);
                if(check_flags(flags, eFlagPrefix[m_Flag]))
                {
                    bFoundPrefix = true;
                    copy(g_sPlayerPrefix[id], charsmax(g_sPlayerPrefix[]), eFlagPrefix[m_Prefix]);
                    break;
                }
            }
          
            if(!bFoundPrefix)
            {
                g_sPlayerPrefix[id] = "";
            }
        }
    }
    #endif
  
    #if defined FUNCTION_TRANSLITE
    if(g_bTranslite[id])
    {
        if(message[0] == '/')
        {
            copy(message, charsmax(message), message[1]);
        }
        else
        {
            new szTranslitedText[TEXT_LENGTH];
            translite_string(szTranslitedText, charsmax(szTranslitedText), message);
            copy(message, charsmax(message), szTranslitedText);
        }
    }
    #endif
  
    new ret; ExecuteForward(g_iForwards[SEND_MESSAGE], ret, id, message, is_team_msg);

    if(ret)
    {
        if(ret == MESSAGE_BLOCKED)
        {
            return PLUGIN_HANDLED;
        }
        copy(message, charsmax(message), g_sNewMessage);
    }

    if(!message[0])
    {
        return PLUGIN_HANDLED;
    }

    new name_color = flags & ADMIN_FLAG ? ADMIN_NAME_COLOR : PLAYER_NAME_COLOR;
    new chat_color = flags & ADMIN_FLAG ? ADMIN_CHAT_COLOR : PLAYER_CHAT_COLOR;
  
    new time_code[16]; get_time("[%H:%M:%S] ", time_code, charsmax(time_code));
  
    new is_sender_alive = is_user_alive(id);
    new CsTeams:sender_team = cs_get_user_team(id);
  
    new channel = get_user_text_channel(is_sender_alive, is_team_msg, sender_team);
  
    FormatMessage(id, sender_team, channel, name_color, chat_color, time_code, message);
  
    #if defined FUNCTION_ALL_CHAT
    new players[32], players_num; get_players(players, players_num, "ch");
    new player, is_player_alive, CsTeams:player_team, player_flags;
  
    for(new i; i < players_num; i++)
    {
        player = players[i];
      
        if(player == id) continue;
      
        is_player_alive = is_user_alive(player);
        player_team = cs_get_user_team(player);
        player_flags = get_user_flags(player) & ADMIN_FLAG ? ADMIN_CHAT_FLAGS : PLAYER_CHAT_FLAGS;
      
        if(player_flags & ALIVE_SEE_DEAD && !is_sender_alive && is_player_alive && (!is_team_msg || is_team_msg && sender_team == player_team) //flag ALIVE_SEE_DEAD
        || player_flags & DEAD_SEE_ALIVE && is_sender_alive && !is_player_alive && (!is_team_msg || is_team_msg && sender_team == player_team) //flag DEAD_SEE_ALIVE
        || player_flags & TEAM_SEE_TEAM && is_team_msg && sender_team != player_team) //flag TEAM_SEE_TEAM
        {
            emessage_begin(MSG_ONE, g_SayText, _, player);
            ewrite_byte(id);
            ewrite_string(g_TextChannels[channel]);
            ewrite_string("");
            ewrite_string("");
            emessage_end();
        }
    }
    #endif
  
    #if defined FUNCTION_LOG_MESSAGES
    static const szTeamColor[CsTeams][] = {"gray", "red", "blue", "gray"};
    new szLogMessage[256];
    formatex(szLogMessage, charsmax(szLogMessage), "<br><font color=black>%s %s %s <font color=%s><b>%s</b> </font>:</font><font color=%s> %s </font>", time_code, is_sender_alive ? "" : (_:sender_team == 1 || _:sender_team == 2 ? "*DEAD*" : "*SPEC*"), is_team_msg ? "(TEAM)" : "", szTeamColor[sender_team], name, chat_color == GREEN ? "green" : "#FFB41E", message);
    write_file(g_szLogFile, szLogMessage);
    #endif
  
    return PLUGIN_CONTINUE;
}
public FormatMessage(sender, CsTeams:sender_team, channel, name_color, chat_color, time_code[], message[])
{
    static const szTeamNames[CsTeams][] = {"(Spectator)", "(Terrorist)", "(Counter-Terrorist)", "(Spectator)"};
  
    new szText[MESSAGE_LENGTH], len = 1;
    szText[0] = PRETEXT_COLOR;
  
    if(channel % 2)
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s", channel != 7 ? "*DEAD*" : "*SPEC*");
    }
  
    if(channel > 1 && channel < 7)
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s ", szTeamNames[sender_team]);
    }
    else if(channel)
    {
        len += formatex(szText[len], charsmax(szText) - len, " ");
    }
  
    #if defined FUNCTION_ADD_TIME_CODE
    len += formatex(szText[len], charsmax(szText) - len, "%s", time_code);
    #endif
  
    #if defined FUNCTION_ADD_STEAM_PREFIX
    if(g_bSteamPlayer[sender])
    {
        len += formatex(szText[len], charsmax(szText) - len, "%s", STEAM_PREFIX);
    }
    #endif
  
    #if defined FUNCTION_AES_TAGS
    new data[4], szAesTag[AES_MAX_LENGTH]; aes_get_player_stats(sender, data); aes_get_level_name(data[1], szAesTag, charsmax(szAesTag));
    len += formatex(szText[len], charsmax(szText) - len, AES_TAG_FORMAT, szAesTag);
    #endif
  
    #if defined FUNCTION_PLAYER_PREFIX
    len += formatex(szText[len], charsmax(szText) - len, "%s", g_sPlayerPrefix[sender]);
    #endif

    #if defined FUNCTION_SQL_PREFIX
    if(g_sSqlPreifx[sender][0])
        len += formatex(szText[len], charsmax(szText) - len, "[^4%s^1] ", g_sSqlPreifx[sender]);
    #endif

    #if defined FUNCTION_BETA_SUPPORT
    new name[32]; get_user_name(sender, name, charsmax(name));
    len += formatex(szText[len], charsmax(szText) - len, "%c%s^1 :%c %s", name_color, name, chat_color, message);
    #else
    len += formatex(szText[len], charsmax(szText) - len, "%c%%s1^1 :%c %s", name_color, chat_color, message);
    #endif
  
    copy(g_sMessage, charsmax(g_sMessage), szText);
}
public Message_SayText(msgid, dest, receiver)
{
    if(get_msg_args() != 4) return PLUGIN_CONTINUE;
  
    new str2[22]; get_msg_arg_string(2, str2, charsmax(str2));
  
    new channel = get_msg_channel(str2);
  
    if(!channel) return PLUGIN_CONTINUE;
  
    new str3[2]; get_msg_arg_string(3, str3, charsmax(str3));
  
    if(str3[0]) return PLUGIN_CONTINUE;
  
    set_msg_arg_string(2, g_sMessage);
    set_msg_arg_string(4, "");
  
    return PLUGIN_CONTINUE;
}
get_msg_channel(str[])
{
    for(new i; i < sizeof(g_TextChannels); i++)
    {
        if(equal(str, g_TextChannels[i]))
        {
            return i + 1;
        }
    }
    return 0;
}
stock get_user_text_channel(is_sender_alive, is_team_msg, CsTeams:sender_team)
{
    if (is_team_msg)
    {
        switch(sender_team)
        {
            case CS_TEAM_T:
            {
                return is_sender_alive ? 2 : 3;
            }
            case CS_TEAM_CT:
            {
                return is_sender_alive ? 4 : 5;
            }
            default:
            {
                return 6;
            }
        }
    }
    return is_sender_alive ? 0 : (sender_team == CS_TEAM_SPECTATOR ? 7 : 1);
}
stock replace_wrong_simbols(string[])
{
    new len = 0;
    for(new i; string[i] != EOS; i++)
    {
        if(string[i] == '%' || string[i] == '#' || 0x01 <= string[i] <= 0x04) continue;
        string[len++] = string[i];
    }
    string[len] = EOS;
}
#if defined FUNCTION_PLAYER_PREFIX
replace_color_tag(string[])
{
    new len = 0;
    for (new i; string[i] != EOS; i++)
    {
        if (string[i] == '!')
        {
            switch (string[++i])
            {
                case 'd': string[len++] = 0x01;
                case 't': string[len++] = 0x03;
                case 'g': string[len++] = 0x04;
                case EOS: break;
                default: string[len++] = string[i];
            }
        }
        else
        {
            string[len++] = string[i];
        }
    }
    string[len] = EOS;
}
#endif
stock translite_string(string[], size, source[])
{
    static const table[][] =
    {
        "Э", "#", ";", "%", "?", "э", "(", ")", "*", "+", "б", "-", "ю", ".", "0", "1", "2", "3", "4",
        "5", "6", "7", "8", "9", "Ж", "ж", "Б", "=", "Ю", ",", "^"", "Ф", "И", "С", "В", "У", "А", "П",
        "Р", "Ш", "О", "Л", "Д", "Ь", "Т", "Щ", "З", "Й", "К", "Ы", "Е", "Г", "М", "Ц", "Ч", "Н", "Я",
        "х", "\", "ъ", ":", "_", "ё", "ф", "и", "с", "в", "у", "а", "п", "р", "ш", "о", "л", "д", "ь",
        "т", "щ", "з", "й", "к", "ы", "е", "г", "м", "ц", "ч", "н", "я", "Х", "/", "Ъ", "Ё"
    };
  
    new len = 0;
    for (new i = 0; source[i] != EOS && len < size; i++)
    {
        new ch = source[i];
      
        if ('"' <= ch <= '~')
        {
            ch -= '"';
            string[len++] = table[ch][0];
            if (table[ch][1] != EOS)
            {
                string[len++] = table[ch][1];
            }
        }
        else
        {
            string[len++] = ch;
        }
    }
    string[len] = EOS;
  
    return len;
}
stock color_print(id, text[], any:...)
{
    new formated[190]; vformat(formated, charsmax(formated), text, 3);
    message_begin(id ? MSG_ONE : MSG_ALL, g_SayText, _, id);
    write_byte(id);
    write_string(formated);
    message_end();
}
stock check_flags(flags, need_flags)
{
    return ((flags & need_flags) == need_flags) ? 1 : 0;
}
stock is_user_steam(id)
{
    static dp_pointer;
    if(dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
    {
        server_cmd("dp_clientinfo %d", id); server_exec();
        return (get_pcvar_num(dp_pointer) == 2) ? true : false;
    }
    return false;
}
#if defined FUNCTION_SQL_PREFIX
stock mysql_escape_string(dest[],len)
{
    //copy(dest, len, source);
    replace_all(dest,len,"\\","\\\\");
    replace_all(dest,len,"\0","\\0");
    replace_all(dest,len,"\n","\\n");
    replace_all(dest,len,"\r","\\r");
    replace_all(dest,len,"\x1a","\Z");
    replace_all(dest,len,"'","''");
    replace_all(dest,len,"^"","^"^"");
}
#endif

Mistrick · 26 Июл 2019

Ресурс Chat Manager был обновлен:

1.1.2 build 15

Нажмите на эту ссылку, чтобы узнать подробности обновления

Mistrick · 27 Июл 2019

Ресурс Chat Manager был обновлен:

1.1.2 build 16

Нажмите на эту ссылку, чтобы узнать подробности обновления

1337322228 · 28 Июл 2019

Mistrick, При включении поддержки нового билда когда пишешь в чате одни s выходят

28 Июл 2019

писал со стим клиента на нонстиме ещё не пробовал

Chat Manager 1.1.2-16

TOplM

Вложения

Алексеич

fantom

TOplM

Rasul

TDinfestedterran

VladJkee

TDinfestedterran

TDinfestedterran

Вложения

r1nk0

praccprefere

Minni

Алексеич

Dev1se

Вложения

RockTheStreet

Саппорт года

Denzer

Denzer

Mistrick

Mistrick

1337322228

Пользователи, просматривающие эту тему