Я и PAWN | Изучаю, потому что интересно

[ThePhoenix]

Тук тук. Я тут это, смотря на ребят, у которых уже есть такая тема, где им помогают и объясняют - себе тоже захотел такую :)

Я не могу сказать, что яро хочу изучать скриптинг, писать плагины и т.д. Просто хочется быть чутка более полезным + иногда себе нужно что-то сделать!
Собсна, создал тему, чтобы уточнить какие-то небольшие моменты, нюансы и чтобы не потерять их, создавая кучу тем.

То, что я хотел узнать и успешно узнал, будет храниться здесь, под спойлером, чтобы каждый, при нужде, смог ознакомиться и воспользоваться информацией :)

Спойлер: секретные данные минобороны :D

Вопрос:
Как можно получить id игрока, если же в паблике не указан изначально id или const id?

Ответ:
С помощью цикла ниже.

for(new id = 1; id <= g_iMaxPlayers; id++)
    {}

Или если в таске нужно, тогда создать его где-то в public'e, где изначально указан id и вписать его, как id таска:

public client_authorized(id)
    set_task(1.0, "TaskMain", id ,.flags = "b");

public TaskMain(id) {}

Вопрос:
Как можно поставить на паузу плагин на картах с префиксами?

Ответ:
С помощью цикла ниже.

    new szMapPrefix[][] = {"fy_", "35hp", "awp_", "aim_", "$"};
    new szMapName[32]; get_mapname( szMapName, charsmax(szMapName));

    for( new i; i < sizeof( szMapPrefix ); i++)
    {
        if(containi( szMapName, szMapPrefix[i] ) != -1)
        {
            pause("ad");
            break;
        }
    }

Вопрос:
Как можно выключить хук на картах с префиксами?

Ответ:
С помощью кода ниже

new HookChain: g_Spawn; // создаём переменную вкл/выкл хука

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);

    g_Spawn = RegisterHookChain(RG_CSGameRules_PlayerSpawn, "refwd_PlayerSpawn_Post", true); // регистрируем хук

    new szMapPrefix[][] = {"fy_", "35hp", "awp_", "aim_", "cs_deagle"};
    new szMapName[32]; get_mapname( szMapName, charsmax(szMapName));

    for( new i; i < sizeof( szMapPrefix ); i++)
    {
        if(containi( szMapName, szMapPrefix[i] ) != -1) // проверяем на наличие префикса в названии карты
        {
            DisableHookChain(g_Spawn); // выключаем хук
            break; // конец цикла
        }
    }
}

Вопрос:
Как можно выключить все хуки или их часть на конкретной карте?

Ответ:
С помощью кода ниже

public plugin_init()
{
    new mapName[32]; // создаём переменную. куда будет записано название карты
    get_mapname(mapName, charsmax(mapName)); // получаем название текущей карты в переменную mapName

    if (equal(mapName, "35hp_new")) // проверяем на полное название карты
        return; // если текущая карта совпадает с желаемой, тогда ретюрним и дальше код выполняться не будет, т.е зарегистрированные хуки работать не будут

    RegisterHookChain(RG_CSGameRules_PlayerSpawn, "refwd_PlayerSpawn_Post", true)
}

Вопрос:
В чём разница между rg_send_audio и rh_emit_sound?

Ответ:
rh_emit_sound - могут услышать игроки, которые находятся рядом!

Вопрос:
Как можно получить счётчики выигранных раундов СТ или ТТ ?

Ответ:
Мемберы: m_iNumCTWins и m_iNumTerroristWins

Вопрос:
Как можно получить координаты точки, которая находится через сто метров (сделать блинк там или ещё что) ?

Ответ:

#include <amxmodx>
#include <fakemeta>
#include <xs>

public test(player)
{
    // Угол напрления взгляда игрока
    new Float:vecViewAngle[3];
    pev(player, pev_v_angle, vecViewAngle);

    // Создаем вектора напраяления из ViewAngle
    // Рузультат будет сохранен в глобальные переменные glb_v_forward, glb_v_up, glb_v_right
    engfunc(EngFunc_MakeVectors, vecViewAngle);

    // Получем вектор направления 'вперед' из глобальной переменной
    new Float:vecForward[3];
    global_get(glb_v_forward, vecForward);

    // Умножаем вектор 'вперед' на необходимое значение (расстояние в юнитах)
    xs_vec_mul_scalar(vecForward, 100.0, vecForward);

    // Текущие координаты игрока
    new Float:vecOrigin[3];
    pev(player, pev_origin, vecOrigin);

    // Получем координаты точки в напраялении 100 юнитов вперед
    xs_vec_add(vecOrigin, vecForward, vecOrigin);
}

Вопрос:
Что делает натив?

server_exec();

Ответ:
Принудительное выполнение сервером введенной в консоль команды (server_cmd();)

Я и PAWN | Изучаю, потому что интересно

ThePhoenix, а зачем тебе создавать новый массив, чтобы поместить в него значения из другого, чтобы найти максимальное значение?

dev-cs.ru

Вопрос:
Как сохранить данные об игроке по STEAMID на одну карту?

Ответ:

#include <amxmodx>

enum _:Data {
    data_level,
    data_some_info[32]
};

new g_data[MAX_PLAYERS + 1][Data];
new Trie:g_trieData = Invalid_Trie;

public plugin_init()
{
    g_trieData = TrieCreate();
}

public client_authorized(id, const szAuthId[])
{
    arrayset(g_data[id], 0, Data);

    if (TrieGetArray(g_trieData, szAuthId, g_data[id], Data)) {
        return; // Data found and copied from g_trieData to g_data.
    }

    // Data isn't found. So let's create new entry.
    g_data[id][data_level] = 123;
    formatex(g_data[id][data_some_info], charsmax(g_data[][data_some_info]), "Some Info %d", 123);

    TrieSetArray(g_trieData, szAuthId, g_data[id], Data);
}

Вопрос:
Как скрыть худ конкретного элемента?

Ответ:

set_member(id, m_iHideHUD, get_member(id, m_iHideHUD) | CBasePlayer::m_iHideHUD);

Единственное, что таймер почему-то не скрывается сам по себе и радар скрывается вместе с жизнями, броней.

Вопрос:
Как удалить на карте 35хп триггер, который добивает до нужного значения хп?

Ответ:

new ent = -1;

while((ent = rg_find_ent_by_class(ent, "game_player_hurt")))
{
    set_entvar(ent, var_flags, FL_KILLME);
}

p.s. Да и мне интересно, какая функция, как используется и где используется))

UPD: Обновил первый пост. Залил всю инфу, которая накопилась!!!

 

[SergeyShorokhov]

Коль каждый себе такую тему создаёт - в знак благодарности - оформляйте первый пост как заголовок, в котором будет собраны вопросы на ответы

 

[ThePhoenix]

wopox1337, без проблем, по мере поступления информации, буду обновлять первый пост, вписывая туда вопрос и собсна ответ. (Заодно и самому будет удобнее)

 

[Minni]

Да и мне интересно, какая функция, как используется и где используется

Большую часть можно лицезреть в исходах геймлибы.

 

[hajimura]

Minni,

Спойлер: Оффтоп

Ему бы в павне освоиться для начала

 

[Minni]

shadow, тогда ему лучше и вовсе с питона начать, а то павн ему дается плохо пока что)))

 

[ThePhoenix]

Это конечно не совсем по теме, но разве может не работать простейший код, при игре с ботами?
Ну тип, запустил локалку, хотел кое что написать, да вот только функция убийства не воркает, от слова совсем :D

#include <amxmodx>
#include <reapi>

public plugin_unit()
{
    RegisterHookChain(RG_CBasePlayer_Killed, "@CBasePlayer__Killed_Post", true);
}

public client_putinserver(id)
{
    log_amx("id: %d", get_user_userid(id));
}

@CBasePlayer__Killed_Post(iVictim, iAttacker, iGib)
{
    log_amx("working");
    log_amx("id2: %d", get_user_userid(iAttacker));
}

В итоге создал отдельно такой код, запустил, айдишники на путине считались, а при любом убийстве, ничего не происходит :D

L 06/10/2020 - 01:27:56: [check.amxx] id: 19
L 06/10/2020 - 01:27:58: [check.amxx] id: 70
L 06/10/2020 - 01:27:58: [check.amxx] id: 71
L 06/10/2020 - 01:27:59: [check.amxx] id: 72
L 06/10/2020 - 01:27:59: [check.amxx] id: 73
L 06/10/2020 - 01:27:59: [check.amxx] id: 74
L 06/10/2020 - 01:28:00: [check.amxx] id: 75
L 06/10/2020 - 01:28:00: [check.amxx] id: 76
L 06/10/2020 - 01:28:01: [check.amxx] id: 77
L 06/10/2020 - 01:28:01: [check.amxx] id: 78
L 06/10/2020 - 01:28:01: [check.amxx] id: 79

Это как так-то?

UPD: Прикольно. Прописываю название плагину, версию и т.д. а он не реагирует

[ 24] unknown unknown unknown check.amxx debug

 

[gyxoBka]

ThePhoenix, потому что hook не зареган.

 

[d3m37r4]

Это конечно не совсем по теме, но разве может не работать простейший код, при игре с ботами?
Ну тип, запустил локалку, хотел кое что написать, да вот только функция убийства не воркает, от слова совсем :D

Разве RG_CBasePlayer_Killed вызывается для ботов?

 

[steelzzz]

ThePhoenix, потому что плагин не зареган.

plugin_unit

 

[Javekson]

d3m37r4, да

 

[ThePhoenix]

gyxoBka, steelzzz, ахахахахах, это я могу :D Я даже и не заметил, спасибо :)

 

[ThePhoenix]

Как получить id игрока в паблике? Например, в паблике таска, где по дефолту не пишется public func(id) {}

Я всегда пользовался таким:

for(new id = 1; id < g_iMaxPlayers; id++)
    {}

Но, мне сказали, что условие id < g_iMaxPlayers = игнорирует последнего игрока. Это так?
И как вообще это работает? (получение IDшника)

p.s. я просто циклы никогда не любит и не особо в них понимал, как их правильно делать, хотя логика +- в голове была.

 

[d3m37r4]

мне сказали, что условие id < g_iMaxPlayers = игнорирует последнего игрока. Это так?

-id < g_iMaxPlayers
+id <= g_iMaxPlayers

 

[BiZaJe]

ThePhoenix, Достаточно посмотреть алгоритм работы цикла в блок-схемах.
В гугле их уйма, посмотри для интереса тогда м.б и будет понятнее

 

[ThePhoenix]

А если без цикла, то каким образом получить id? Может стоком каким-нибудь?

 

[BiZaJe]

ThePhoenix, Может меня поправят кнч, но можно так

set_task(1.0, "ShowHUD", id+INDEX_TASK, _, _, "b")

и передать в аргументы

public ShowHud(iTask){
    new id = iTask-INDEX_TASK
}

 

[d3m37r4]

BiZaJe, необязательно для таска еще конкретный индекс задавать.

 

[BiZaJe]

d3m37r4, Т.е достаточно просто id игрока передать?

 

[d3m37r4]

BiZaJe, да, если не планируется более никаких тасков юзать.