Склад полезного кода [GoldSrc]

[juice]

Спойлер: #100

Спойлер: Надет ли глушитель

// Надет ли глушитель
bool:IsWeaponSilenced(const ItemId){
    static WeaponState:State; State = get_member(ItemId, m_Weapon_iWeaponState);
    return bool:(State & WPNSTATE_USP_SILENCED || State & WPNSTATE_M4A1_SILENCED);
}

почему не макрос?

 

[fl0wer]

Спойлер: #100

А так же: почему статик? Почему неправильная работа с битами?

 

[ArKaNeMaN]

Спойлер: #100

Почему неправильная работа с битами?

Хм... Действительно... Чёт не подумал об этом... Ща будет

почему не макрос?

Тоже поправлю

UPD: Поправил

 

[Nordic Warrior]

Сток позволяет отправить звук одному игроку или всем, как в rg_send_audio(), но с той разницей, что в rg_send_audio звуки перебивают друг друга, что бывает очень неудобно.

stock rg_send_audio2(const iPlayer, const szAudio[])
{
    if(!iPlayer)
    {
        for(new i = 1; i <= MaxClients; i++)
        {
            if(!is_user_connected(i) || is_user_hltv(i) || is_user_bot(i))
                continue;

            rh_emit_sound2(i, i, CHAN_STATIC, szAudio);
        }
    }
    else
    {
        rh_emit_sound2(iPlayer, iPlayer, CHAN_STATIC, szAudio);
    }
}

 

[d3m37r4]

Спойлер: #100

sbelov020, эмитсаунд по другому работает.

 

[Nordic Warrior]

Спойлер: #100

d3m37r4, я в курсе, как они работают

 

[d3m37r4]

Спойлер: #100

sbelov020, одно другим не заменяется. Send_audio воспроизводит мессагу для игрока, а emit_sound эмулирует звук от указанного объекта.

 

[Nordic Warrior]

Спойлер: #100

d3m37r4, я ещё раз повторяю, я знаю, как работают эти функции. Мне нужно было воспроизводить звуки игрокам индивидуально, но чтоб они не перебивали друг друга и без клиент команды - я нашел такой способ. Теперь делюсь им со всеми.

 

[the_hunter]

Макросы для работы с битсуммами

#define get_bit(%1,%2) (%1 & (1 << (%2 & 31)))
#define set_bit(%1,%2) (%1 |= (1 << (%2 & 31)))
#define reset_bit(%1,%2) (%1 &= ~(1 << (%2 & 31)))
#define invert_bit(%1,%2) (%1 ^= (1 << (%2 & 31)))

Часто вижу юзают set_bit и reset_bit (он же clr_bit). Но иногда, в зависимости от какого-то условия, приходится либо устанавливать бит, либо занулить. Что приводит примерно к такому коду:

Спойлер

    new bool:someCondition = true;
    if (someCondition)
    {
        set_bit(g_bits, playerIndex);
    }
    else
    {
        clr_bit(g_bits, playerIndex);
    }

В этом случае, было бы удобней без макроса clr_bit (ИМХО). Использовать только макрос set_bit, в который можно передавать значение true (установить бит) и flase (очистить бит). Сам макрос выглядит так:

#define set_bit(%1,%2,%3) (%3 && (%1 |= (1 << (%2 & 31))) || (%1 &= ~(1 << (%2 & 31))))
Теперь, можно переписать код который под спойлером, без макроса clr_bit:

    new bool:someCondition = true;
    set_bit(g_bits, playerIndex, someCondition);

 

[fantom]

Спойлер: #109

the_hunter, есть же togglebit https://dev-cs.ru/threads/7672/post-67446

13 Окт 2019

А у тебя условие. Ну хз. Как по мне, это ни к чему ИМХО.

 

[the_hunter]

Спойлер: #109

@the_hunter, есть же togglebit

toggle - переключение бита, с нуля на 1 и обратно. Не нужно путать. Это немного другое. А если нужно быть уверенным, что бит будет очищен или установлен? То есть делаю toggle - ожидаю что бит будет 0 (но бит по каким-либо причинам и так был 0) получаю 1.
Ведь биты могут быть изменены в других функциях. А хранятся все в глобальной переменной.

 

[fantom]

Данным стоком можно только что выданное оружие сделать активным. Ну или например сделать переключение на последнее активное.
Зависимости:

#include <hamsandwich>
#include <reapi>

stock bool:switchItem(const id, const item) {
    if (is_nullent(item)) {
        return false;
    }

    new activeItem = get_member(id, m_pActiveItem);
    if (is_nullent(activeItem)) {
        return false;
    }

    if (!ExecuteHamB(Ham_Item_CanHolster, activeItem)) {
        return false;
    }

    if (!ExecuteHamB(Ham_Item_CanDeploy, item)) {
        return false;
    }

    set_member(id, m_pLastItem, activeItem);
    ExecuteHamB(Ham_Item_Holster, activeItem, 0);

    set_member(id, m_pActiveItem, item);
    ExecuteHamB(Ham_Item_Deploy, item);
    return true;
}

 

[Ruby]

Спойлер: #109

fantom, rg_switch_weapon есть же

 

[fantom]

Спойлер: #109

Ruby, не заметил. И вправду есть. Ну в любом случае пример не навредит.

 

[d3m37r4]

Пример открытия стандартного меню закупки, может использоваться в CSDM (пример использования тут), чтобы не городить свои кастомные менюхи.

#include <reapi>

public plugin_init() {
    RegisterHookChain(RG_CBasePlayer_OnSpawnEquip, "HC_CBasePlayer_OnSpawnEquip_Post", true);
}

public HC_CBasePlayer_OnSpawnEquip_Post(const id, bool:addDefault, bool:equipGame) {
    OpenDefaultBuyMenu(id);
}

OpenDefaultBuyMenu(id) {
    _show_vgui_menu(id, VGUI_Menu_Buy, (MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_7|MENU_KEY_8|MENU_KEY_0), "#Buy");
    set_member(id, m_iMenu, Menu_Buy);    // for oldstyle menu
}

stock _show_vgui_menu(const index, const any:menu, const keys, text[]) {
    if(get_member(index, m_bVGUIMenus) || menu > any:VGUI_Menu_Buy_Item) {
        static msgVGUIMenu;

        if(!msgVGUIMenu ) {
            msgVGUIMenu = get_user_msgid("VGUIMenu");
        }

        message_begin(index ? MSG_ONE : MSG_ALL, msgVGUIMenu, _, index);
        write_byte(menu);
        write_short(keys);
        write_char(-1);
        write_byte(0);
        write_string(text);
        message_end();
    } else {
        show_menu(index, keys, text);
    }
}

 

[Emma Jule]

Исправленный и рабочий вариант: https://dev-cs.ru/threads/222/page-7#post-70997

Этот сток позволит конвертировать число в Kilo формат, как в соц. сетях

// By impossible
stock kilo(num)
{

                  new s[10]; num_to_str(num, s, charsmax(s))

                  if (num > 999) {
                              new l = num > 99999 ? 3 : num > 9999 ? 2 : 1

                              switch (s[l])
                              {
                                                case: '1': replace(s, charsmax(s), s[l], ".1K")
                                                case: '2': replace(s, charsmax(s), s[l], ".2K")
                                                case: '3': replace(s, charsmax(s), s[l], ".3K")
                                                case: '4': replace(s, charsmax(s), s[l], ".4K")
                                                case: '5': replace(s, charsmax(s), s[l], ".5K")
                                                case: '6': replace(s, charsmax(s), s[l], ".6K")
                                                case: '7': replace(s, charsmax(s), s[l], ".7K")
                                                case: '8': replace(s, charsmax(s), s[l], ".8K")
                                                case: '9': replace(s, charsmax(s), s[l], ".9K")
                                                default: replace(s, charsmax(s), s[l], "K")
                                }
                   }

                   return s;
}

 

[d3m37r4]

Спойлер: #116

Impossible, оберни код в тэг соответствующий.

 

[Garey]

Спойлер: #116

Impossible,

server_print("%s", kilo(1000));
server_print("%s", kilo(10000));
server_print("%s", kilo(100000));
>>>
1K
1K0
1K00

так и должно работать? и что за kilo формат? имеется ввиду это?

 

[Minni]

Спойлер: #116

Garey, да. Правда, применения этому в 1.6 - не вижу. Вернее, не вижу смысла. Разве что, в каких-то системах накопления чего-либо, в эстетических целях оформления.

 

[fl0wer]

Спойлер: #116

Minni, стата дамага, правда код нерабочий.