Block Change Team 1.0.0

[fantom]

fantom добавил(а) новый ресурс:

Block Change Team - Плагин блокирует смену команды

Простой плагин блокировки смены команды.

Узнать больше об этом ресурсе...

 

[onixs]

Is it possible to block only if the player is alive? In other words, if you are dead you can switch teams.

 

[NoNameNPC]

onixs, Of course, just check if the player is alive.

 

[onixs]

onixs, Of course, just check if the player is alive.

Could you give me an example of how to check if the player is alive in this code?

 

[Ayk]

onixs,

#include <amxmodx>
#include <reapi>

public plugin_init() {
    register_plugin("Block Change Team for Alive Players", "1.0.0", "F@nt0M");
    RegisterHookChain(RG_ShowVGUIMenu, "ShowVGUIMenu_Pre", false);
    RegisterHookChain(RG_HandleMenu_ChooseTeam, "HandleMenu_ChooseTeam_Pre", false);
}

public ShowVGUIMenu_Pre(const id, const VGUIMenu:menuType) {
    if (menuType != VGUI_Menu_Team || get_member(id, m_bJustConnected) || !is_user_alive(id)) {
        return HC_CONTINUE;
    }
    set_member(id, m_iMenu, 0);
    return HC_SUPERCEDE;
}

public HandleMenu_ChooseTeam_Pre(const id) {
    if (get_member(id, m_bJustConnected) || !is_user_alive(id)) {
        return HC_CONTINUE;
    }
    SetHookChainReturn(ATYPE_INTEGER, false);
    return HC_SUPERCEDE;
}

 

[Javekson]

Ayk, fantom а случайно внутри is_user_alive нету проверка на коннект игрока? Или все же стоит чекать m_bJustConnected ?

 

[Ayk]

Javekson, да, в is_user_alive() есть проверка на коннект.
m_bJustConnected не проверяется как доказательство коннекта, а как этап подключения игрока.
Пока у игрока m_bJustConnected == true, то у него и команды по сути то нет. Он не валиден для спавна.

ЛЕ: сам вызов хуков и есть проверка на коннект, т.к. они не вызываются для невалидных игроков.

 

[fantom]

Javekson, m_bJustConnected момент, когда игрок толбко подключается. В этот момент разрешаем ему выбор. Смену позже, посреди игры, суперсидим.

 

[BlackSignature]

fantom, но в данном случае, разве is_user_alive() не покрывает собой m_bJustConnected в том плане, что при входе на сервер игрок не жив? Думаю Javekson как раз это имел ввиду.

 

[fantom]

BlackSignature, если брать пример от Ayk, то выгляд так, что одной проверки на is alive достаьочно, но бы сделал именно так как он.

 

[Ayk]

разве is_user_alive() не покрывает собой m_bJustConnected

Подумал об этом, но не решился убрать без возможности протестировать.

 

[onixs]

I found a code in AM and made some changes using ocixcrom's colorchat and it worked well for me, this is the code that solved my problem:

#include <amxmodx>
#include <cstrike>
#include <cromchat>

#define PLUGIN "Block Team Change Alive"
#define VERSION "3.0"
#define AUTHOR "onixs | CAMEL"

new blockteam

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    blockteam = register_cvar("amxx_blockteams","1")
    register_clcmd("chooseteam", "cmdChooseTeam")

    CC_SetPrefix("[^4AMXX^1]")
}

public cmdChooseTeam(id)
{
    if (is_user_alive(id) && get_pcvar_num(blockteam))
    {
        CC_SendMatched(id, CC_COLOR_RED, "&x07You cannot change teams while you are alive&x01!");
        return PLUGIN_HANDLED;
    }

    if (!is_user_alive(id))
        return PLUGIN_CONTINUE;

    if (cs_get_user_team(id) == CS_TEAM_SPECTATOR)
        return PLUGIN_CONTINUE;

    return PLUGIN_HANDLED;
}

Thank you all!

 

[fantom]

onixs, put command into your console jointeam 1; joinclass 5 and plugin doesn't block it

 

[onixs]

fantom Oh .. you're right, fixed thanks!

#include <amxmodx>
#include <cstrike>
#include <cromchat>

#define PLUGIN "Block Team Change Alive"
#define VERSION "3.0"
#define AUTHOR "onixs | CAMEL"

new blockteam

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    blockteam = register_cvar("amxx_blockteams","1")
    register_clcmd("chooseteam", "cmdChooseTeam")
    register_clcmd("jointeam", "cmdChooseTeam")

    CC_SetPrefix("[^4AMXX^1]")
}

public cmdChooseTeam(id)
{
    if (is_user_alive(id) && get_pcvar_num(blockteam))
    {
        CC_SendMatched(id, CC_COLOR_RED, "&x07You cannot change teams while you are alive&x01!");
        return PLUGIN_HANDLED;
    }

    if (!is_user_alive(id))
        return PLUGIN_CONTINUE;

    if (cs_get_user_team(id) == CS_TEAM_SPECTATOR)
        return PLUGIN_CONTINUE;

    return PLUGIN_HANDLED;
}

 

[Se_IaQe]

#pragma semicolon 1

#pragma ctrlchar '\'



#include <amxmisc>

#include <amxmodx>

#include <cstrike>

#include <fakemeta>



#define OFFSET_MENU 205



public plugin_init()

{

    register_plugin("Anti ChooseTeam Crash", "0.1", "Cruzer //");

  

    register_clcmd("joinclass", "join_class");

    register_clcmd("menuselect", "menu_select");

}



public plugin_modules()

{

    require_module("amxmisc");

    require_module("amxmodx");

    require_module("cstrike");

    require_module("fakemeta");

}



public join_class(id)

{

    new CsTeams:teamId=cs_get_user_team(id);

  

    if(teamId!=CS_TEAM_T&&teamId!=CS_TEAM_CT)

  

    return PLUGIN_HANDLED;

    return PLUGIN_CONTINUE;

}



public menu_select(id)

{

    new iMenu=get_pdata_int(id, OFFSET_MENU);

  

    if(iMenu==3)

    {

    new CsTeams:teamId=cs_get_user_team(id);

  

    if(teamId!=CS_TEAM_T&&teamId!=CS_TEAM_CT)

    {

    set_pdata_int(id, OFFSET_MENU, 0);

  

    return PLUGIN_HANDLED;

        }

    }

    return PLUGIN_CONTINUE;

}

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE

*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }

*/

 

[fantom]

Se_IaQe, и что вы хотите сказать? в чем суть вашего поста?