Меню сервера

IIIKuIIeP · 3 Авг 2019

Добрый вечер , может найдется человек который разбирается в плагинах и поможет исправить данную проблему в плагине ,))

Ayk · 4 Авг 2019

Перенеси создание меню целиком в plugin_init().

IIIKuIIeP · 4 Авг 2019

Ayk, увы не скриптер в этом не шарю(

Ayk · 4 Авг 2019

SaHTuK, всё что внутри
public plugin_cfg()
переходит в
public plugin_init()

Izmayl7 · 4 Авг 2019

SaHTuK,

C-like:

#include <amxmodx>

new g_iMenu;

public plugin_init()
{
    register_plugin("Server Menu", "0.1", "maFFyoZZyk")
    register_clcmd("say /menu", "function_menu")
    register_clcmd("menu", "function_menu")
    register_clcmd("nightvision", "function_menu")
       
    g_iMenu = menu_create("\yМеню\w Нашего\r Сервера\d", "menu_handler")
   
    menu_additem(g_iMenu,"\r[\yОбнулить счет\r]","1")
    menu_additem(g_iMenu,"\r[\yНоминировать карту\r]","2")
    menu_additem(g_iMenu,"\r[\yЗаткнуть игрока\r]","3")
    menu_additem(g_iMenu,"\r[\yГолосование за БАН\r]","4")
    menu_additem(g_iMenu,"\r[\yКупить админку\r]","5")
    menu_additem(g_iMenu,"\r[\yКупить випку\r]","6")
    menu_additem(g_iMenu,"\r[\yТоп 10\r]","7")
    menu_additem(g_iMenu,"\r[\yAdmin&Vip Онлайн\r]","8")
    menu_additem(g_iMenu,"\r[\yВип Меню\r]","9")
    menu_additem(g_iMenu,"\r[\yАдмин Меню\r]","10")
   
    menu_setprop(g_iMenu, MPROP_EXITNAME, "Выход")
    menu_setprop(g_iMenu, MPROP_EXIT,MEXIT_ALL)  
}

public function_menu(id)
{
    menu_display(id,g_iMenu,0)
    return PLUGIN_HANDLED
}

public menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
       
    new data[6], iName[64], access, callback
    menu_item_getinfo(menu, item, access, data, 5, iName, 63, callback)
       
    new key = str_to_num(data)
       
    switch(key)
    {
        case 1: client_cmd(id, "say /rs")
        case 2: client_cmd(id, "say /maps")
        case 3: client_cmd(id, "say /mute")
        case 4: client_cmd(id, "say /voteban")
        case 5: client_cmd(id, "say /adminka")
        case 6: client_cmd(id, "say /vipka")
        case 7: client_cmd(id, "say /top10")
        case 8: client_cmd(id, "say /admins")
        case 9: client_cmd(id, "vipmenu")
        case 10:client_cmd(id, "amxmodmenu")
    }
    return PLUGIN_HANDLED
}

IIIKuIIeP · 4 Авг 2019

Izmayl7, благодарю сейчас проверю)

fantom · 4 Авг 2019

Izmayl7 написал(а):
menu_destroy(menu)

перенести в plugin_end

Izmayl7 · 5 Авг 2019

Держи и проверяй!) спасибо fantom

C-like:

#include <amxmodx>

new g_iMenu;

public plugin_init() {
    register_plugin("Server Menu", "0.1", "maFFyoZZyk");
    register_clcmd("say /menu", "CmdMenu");
    register_clcmd("menu", "CmdMenu");
    register_clcmd("nightvision", "CmdMenu");
}

public plugin_cfg() {
    g_iMenu = menu_create("\yМеню\w Нашего\r Сервера\d", "MenuHandler")
    menu_additem(g_iMenu, "\r[\yОбнулить счет\r]", "1");
    menu_additem(g_iMenu, "\r[\yНоминировать карту\r]", "2");
    menu_additem(g_iMenu, "\r[\yЗаткнуть игрока\r]", "3");
    menu_additem(g_iMenu, "\r[\yГолосование за БАН\r]", "4");
    menu_additem(g_iMenu, "\r[\yКупить админку\r]", "5");
    menu_additem(g_iMenu, "\r[\yКупить випку\r]", "6");
    menu_additem(g_iMenu, "\r[\yТоп 10\r]", "7");
    menu_additem(g_iMenu, "\r[\yAdmin&Vip Онлайн\r]", "8");
    menu_additem(g_iMenu, "\r[\yВип Меню\r]", "9");
    menu_additem(g_iMenu, "\r[\yАдмин Меню\r]", "10");
    
    menu_setprop(g_iMenu, MPROP_NEXTNAME, "Далее");
    menu_setprop(g_iMenu, MPROP_BACKNAME, "Назад");
    menu_setprop(g_iMenu, MPROP_EXITNAME, "Выход");
    menu_setprop(g_iMenu, MPROP_EXIT,MEXIT_ALL);
}

public plugin_end() {
    menu_destroy(g_iMenu);
}

public CmdMenu(id) {
    menu_display(id, g_iMenu);
    return PLUGIN_HANDLED;
}

public MenuHandler(id, menu, item) {
    if (item == MENU_EXIT) {
        return;
    }
        
    new data[6];
    menu_item_getinfo(menu, item, .info = data, .infolen = charsmax(data));
    switch (str_to_num(data)) {
        case 1: client_cmd(id, "say /rs");
        case 2: client_cmd(id, "say /maps");
        case 3: client_cmd(id, "say /mute");
        case 4: client_cmd(id, "say /voteban");
        case 5: client_cmd(id, "say /adminka");
        case 6: client_cmd(id, "say /vipka");
        case 7: client_cmd(id, "say /top10");
        case 8: client_cmd(id, "say /admins");
        case 9: client_cmd(id, "vipmenu");
        case 10:client_cmd(id, "amxmodmenu");
    }
}