Проблема с DR Checkpoints

ufame · 31 Мар 2019

Немного подогнал под свои нужды, но от сюда сразу проблема (на скрине)

Проблема именно с финишем, с другими чекпоинтами все в порядке, соприкосновение - срабатывание кода, блок повторного срабатывания, если уже касался. С финишем же не так, блока повторного срабатывания будто нет, а он вроде как, есть.

Стоит ли использовать SetTouch(reapi) вместо дефолтного Ham_Touch который предлагает автор? (С реапи пока тоже непонятно, то работает, то нет.

31 Мар 2019

Немного помудрив, решил проблему следующим способом:

Это (в функции create_checkpoint)

Код:

    if (!iEventsRegistration)
    {
        register_event("HLTV", "Event_HLTV", "a", "1=0", "2=0")
        
        RegisterHookChain(RG_RoundEnd, "RoundEnd", true);
        RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn", true);
        
-        SetTouch(iEnt, "Touch_Checkpoint");
        
        if (g_iWasChanged)
            SetTouch(iEnt, "");
        
        Event_HLTV()
            
        iEventsRegistration = 1
    }

Заменив на это

Код:

+    SetTouch(iEnt, "Touch_Checkpoint");
    
    if (!iEventsRegistration)
    {
        register_event("HLTV", "Event_HLTV", "a", "1=0", "2=0")
        
        RegisterHookChain(RG_RoundEnd, "RoundEnd", true);
        RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn", true);
        
        if (g_iWasChanged)
            SetTouch(iEnt, "");
        
        Event_HLTV()
            
        iEventsRegistration = 1
    }

До меня дошло что функция вызывалась всего 1 раз, на первую создаваемую ентити.

Как это работало у Psycrow я так и не допер :crazy:

(не смотрел старый код после своих правок, но у него функция регистрации тача была на том же месте :pardon:

)

MaZahakA · 10 Янв 2021

А мона полный код для добавления уведомления времени узнать? Ну или подробнее объяснить куда конкретно добавить замененный код?

ufame · 10 Янв 2021

MaZahakA,

Код:

/*
https://next21.ru/2013/06/deathrun-чекпоинты/
*/

#include <amxmodx>
#include <reapi>
#include <fakemeta_util>
#include <deathrun_duel>

#if AMXX_VERSION_NUM < 183
#include <colorchat>
#include <dhudmessage>
#endif

#define PLUGIN "Checkpoints"
#define VERSION "0.8"
#define AUTHOR "Psycrow"

#define MODEL_CHECKPOINT            "models/agr/other/checkpoint.mdl"
#define SOUND_CHECKPOINT            "agr/other/checkpoint.wav"

#define CLASSNAME_CHECKPOINT        "checkpoint"

#define MAX_CHECKPOINTS                32
#define TASK_SECONDS                40401

#define CHECKPOINT_RADIUS    45.0

#define CHECKPOINT_KEY        450893

#define    CHAT_PREFIX            "^4***"

enum _:CvarList
{
    CVAR_CHECKPOINT_REWARD,                // common reward, 0 - none
    CVAR_CHECKPOINT_KOEF,                // common reward multiplier
    CVAR_CHECKPOINT_FINISH_REWARD[3],    // rewards for finish, 0 - none   
}

new
    g_iCheckpointsNum,
    g_iCheckpoint[MAX_CHECKPOINTS],
    g_iWasChanged,
    g_iRoundEnd,
    g_iFinishedNum,
    g_iDuelStart,
    g_pCvars[CvarList]

new g_fwdFinish;
new g_iSecond[MAX_PLAYERS + 1];
new g_iPlrCompleted[MAX_PLAYERS + 1];

public plugin_precache()
{
    precache_model(MODEL_CHECKPOINT)
    precache_sound(SOUND_CHECKPOINT)
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
        
    register_menucmd(register_menuid("Checkpoint Menu"), 1023, "handler_checkpoint_menu");

    register_concmd("cp_origins", "show_checkpoint_menu", ADMIN_MAP, "-Open Checkpoint Spawn Menu")

    register_dictionary("deathrun_checkpoints.txt")
    
    g_pCvars[CVAR_CHECKPOINT_REWARD] = register_cvar("cv_checkpoint_reward", "300")
    g_pCvars[CVAR_CHECKPOINT_KOEF] = register_cvar("cv_checkpoint_money_koef", "1")
    g_pCvars[CVAR_CHECKPOINT_FINISH_REWARD][0] = register_cvar("cv_checkpoint_money_last_first", "2000")
    g_pCvars[CVAR_CHECKPOINT_FINISH_REWARD][1] = register_cvar("cv_checkpoint_money_last_second", "1000")
    g_pCvars[CVAR_CHECKPOINT_FINISH_REWARD][2] = register_cvar("cv_checkpoint_money_last_third", "500")

    g_fwdFinish = CreateMultiForward("cv_touch_last_checkpoint", ET_IGNORE, FP_CELL);

    load_checkpoints()
}

/*** Checkpoints functions ***/

load_checkpoints()
{
    new szMap[48]
    get_mapname(szMap, 47)
    add(szMap, 47, ".ini")
    
    new szDirCfg[128], iDir, szFile[128]
    get_localinfo("amxx_configsdir", szDirCfg, 127)
    add(szDirCfg, 127, "/settings/checkpoints")
    
    iDir = open_dir(szDirCfg, szFile, 126)
    
    if (!iDir)
    {
        server_print("[%s] Checkpoints were not loaded", PLUGIN)
        return
    }
    
    while (next_file(iDir, szFile, 126))
    {
        if (szFile[0] == '.')
            continue
            
        if (equali(szMap, szFile))
        {
            format(szFile, 126, "%s/%s", szDirCfg, szFile)
            load_spawn(szFile)
            break
        }
    }
    
    close_dir(iDir)
}

load_spawn(const szFile[])
{   
    new iFile = fopen(szFile, "rt")

    if (!iFile)
    {
        server_print("[%s] Unable to open %s.", PLUGIN, szFile)
        return
    }
    
    new szLineData[512], szOrigin[3][24], Float: fOrigin[3], szAngle[24], Float: fAngle
    
    while (iFile && !feof(iFile))
    {
        fgets(iFile, szLineData, 511)

        if (!szLineData[0] || szLineData[0] == ';')
            continue

        parse(szLineData, szOrigin[0], 23, szOrigin[1], 23, szOrigin[2], 23, szAngle, 23)
        
        fOrigin[0] = str_to_float(szOrigin[0])
        fOrigin[1] = str_to_float(szOrigin[1])
        fOrigin[2] = str_to_float(szOrigin[2])
        fAngle = str_to_float(szAngle)

        create_checkpoint(fOrigin, fAngle)
    }
    
    fclose(iFile)
    
    switch (g_iCheckpointsNum)
    {
        case 0: server_print("[%s] Checkpoints were not loaded", PLUGIN)
        case 1: server_print("[%s] Loaded one checkpoint", PLUGIN)
        default: server_print("[%s] Loaded %d checkpoints", PLUGIN, g_iCheckpointsNum)
    }

    set_finish_bodypart()
}

create_checkpoint(const Float: fOrigin[3], const Float: fAngle)
{
    static iEventsRegistration

    if (g_iCheckpointsNum == MAX_CHECKPOINTS)
        return 1
        
    new iEnt = rg_create_entity("info_target");

    if (is_nullent(iEnt))
        return 1

    set_entvar(iEnt, var_origin, fOrigin)
    engfunc(EngFunc_SetModel, iEnt, MODEL_CHECKPOINT)

    set_entvar(iEnt, var_mins, Float: {-CHECKPOINT_RADIUS, -CHECKPOINT_RADIUS, -CHECKPOINT_RADIUS})
    set_entvar(iEnt, var_maxs, Float: {CHECKPOINT_RADIUS, CHECKPOINT_RADIUS, CHECKPOINT_RADIUS})
            
    new Float: fAngles[3]
    fAngles[1] = fAngle
    set_entvar(iEnt, var_angles, fAngles)
            
    set_entvar(iEnt, var_solid, SOLID_TRIGGER)
    set_entvar(iEnt, var_movetype, MOVETYPE_NOCLIP)
    set_entvar(iEnt, var_classname, CLASSNAME_CHECKPOINT)
    set_entvar(iEnt, var_impulse, CHECKPOINT_KEY)
    
    set_entvar(iEnt, var_framerate, 1.0)
    set_entvar(iEnt, var_colormap, random(256))
    
    new Float: fGlow = 1.0
    if (fGlow > 0.0)
    {
        new Float: fColors[3]
        fColors[0] = random(256) + 0.0
        fColors[1] = random(256) + 0.0
        fColors[2] = random(256) + 0.0
        
        set_entvar(iEnt, var_renderfx, kRenderFxGlowShell)
        set_entvar(iEnt, var_renderamt, fGlow)
        set_entvar(iEnt, var_rendercolor, fColors)
    }

    g_iCheckpoint[g_iCheckpointsNum++] = iEnt

    SetTouch(iEnt, "Touch_Checkpoint");

    if (!iEventsRegistration)
    {
        register_event("HLTV", "Event_HLTV", "a", "1=0", "2=0")
        
        RegisterHookChain(RG_RoundEnd, "RoundEnd", true);
        RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn", true);
        
        if (g_iWasChanged)
            SetTouch(iEnt, "");
        
        Event_HLTV()
            
        iEventsRegistration = 1
    }
    
    return 0
}

set_finish_bodypart()
{
    if (!g_iCheckpointsNum)   
        return
    
    for (new i = 0; i < g_iCheckpointsNum - 1; i++)
    {
        set_entvar(g_iCheckpoint[i], var_body, 0)
        set_entvar(g_iCheckpoint[i], var_skin, 0)
    }
        
    set_entvar(g_iCheckpoint[g_iCheckpointsNum - 1], var_body, 1)
    set_entvar(g_iCheckpoint[g_iCheckpointsNum - 1], var_skin, 1)
}

save_checkpoints()
{
    new szDirCfg[128], szFile[128]
    get_localinfo("amxx_configsdir", szDirCfg, 127)
    add(szDirCfg, 127, "/settings/checkpoints")
    
    get_mapname(szFile, 127)
    format(szFile, 127, "%s/%s.ini", szDirCfg, szFile)
    
    if (!dir_exists(szDirCfg))
        mkdir(szDirCfg)
    
    delete_file(szFile)
    
    if (!g_iCheckpointsNum)
        return 0
        
    for (new i = 0; i < g_iCheckpointsNum; i++)
    {
        new szText[128], Float: fOrigin[3], Float: fAngles[3]
        get_entvar(g_iCheckpoint[i], var_origin, fOrigin)
        get_entvar(g_iCheckpoint[i], var_angles, fAngles)
        format(szText, 127, "^"%f^" ^"%f^" ^"%f^" ^"%f^"",
            fOrigin[0], fOrigin[1], fOrigin[2], fAngles[2])
        write_file(szFile, szText, -1)
    }
    
    return 0
}

/*** Menu handlers ***/

public show_checkpoint_menu(id)
{
    if (get_user_flags(id) & ADMIN_MAP)
        display_checkpoint_menu(id)
    
    return PLUGIN_HANDLED
}

display_checkpoint_menu(const id)
{
    new szMenu[512], iLen, iKeys = (1 << 9);
    
    iLen = formatex(szMenu, 511, "%L \d[%i|%i]^n^n",
        LANG_PLAYER, "MENU_HEADER", g_iCheckpointsNum, MAX_CHECKPOINTS)
        
    if (g_iCheckpointsNum != MAX_CHECKPOINTS)
    {
        iLen += formatex(szMenu[iLen], 511 - iLen, "\d[1] \w%L^n", id, "MENU_SPAWN")
        iKeys |= (1 << 0);
    }
            
    if (g_iCheckpointsNum)
    {
        iLen += formatex(szMenu[iLen], 511 - iLen, "\d[2] \w%L^n", id, "MENU_REMOVE")
        iLen += formatex(szMenu[iLen], 511 - iLen, "\d[3] \w%L^n", id, "MENU_REMOVE_ALL")
        iKeys |= (1 << 1|1 << 2);
    }
    
    if (g_iWasChanged)
    {
        iLen += formatex(szMenu[iLen], 511 - iLen, "^n\d[4] \w%L^n", id, "MENU_SAVE")
        iKeys |= (1 << 3);
    }
    
    iLen += formatex(szMenu[iLen], 511 - iLen, "^n\d[0] \w%L", id, "MENU_EXIT")

    show_menu(id, iKeys, szMenu, -1, "Checkpoint Menu")
}

public handler_checkpoint_menu(id, key)
{
    if (key == 9)
        return PLUGIN_CONTINUE

    switch (key)
    {
        case 0:
        {
            new Float: fOrigin[3], Float: fAngles[3];
            new iEnt = _fm_get_aim_origin(id, fOrigin);

            fOrigin[2] += CHECKPOINT_RADIUS;
            get_entvar(id, var_v_angle, fAngles)

            if (!create_checkpoint(fOrigin, fAngles[1]))
            {
                set_finish_bodypart()
                g_iWasChanged = 1
                SetTouch(iEnt, "");

                
                if (check_stuck(fOrigin, id))
                    client_print_color(id, print_team_red, "%s ^1%L", CHAT_PREFIX, LANG_PLAYER, "CP_CAN_STUCK")
            }
        }
        case 1:
        {
            SetTouch(g_iCheckpoint[--g_iCheckpointsNum], "");
            rg_remove_entity(g_iCheckpoint[g_iCheckpointsNum])

            if (g_iCheckpointsNum)
                set_finish_bodypart()

            g_iWasChanged = 1
        }
        case 2:
        {
            for (new i = 0; i < g_iCheckpointsNum; i++)
            {
                SetTouch(g_iCheckpoint[i], "");
                rg_remove_entity(g_iCheckpoint[i])
            }
                
            g_iCheckpointsNum = 0
            g_iWasChanged = 1
        }
        case 3:
        {
            if (!save_checkpoints())
            {
                client_print_color(id, print_team_red, "%s ^1%L", CHAT_PREFIX, LANG_PLAYER, "CP_SAVED")
                g_iWasChanged = 0
                
                if (g_iCheckpointsNum)
                {
                    for (new i = 0; i < g_iCheckpointsNum; i++)
                        SetTouch(g_iCheckpoint[i], "Touch_Checkpoint");
                }

                arrayset(g_iPlrCompleted, -1, 33)
                g_iFinishedNum = 0
            }
        }
    }
    
    display_checkpoint_menu(id)
    return PLUGIN_CONTINUE
}

/*** Global events ***/

public client_disconnected(id)
{
    g_iSecond[id] = 0;
    remove_task(id + TASK_SECONDS);
    g_iPlrCompleted[id] = -1;
}

public Event_HLTV()
{
    g_iRoundEnd = 0
    g_iFinishedNum = 0
    arrayset(g_iPlrCompleted, -1, 33)

    for (new i = 1; i <= MaxClients; i++)
    {
        if (!is_user_connected(i))
            continue;
        
        g_iSecond[i] = 0;
        remove_task(i + TASK_SECONDS);
    }
}

public RoundEnd(WinStatus: winStatus, ScenarioEventEndRound: scenarioEvent, Float: fDelay)
{
    if (winStatus == WINSTATUS_CTS || winStatus == WINSTATUS_TERRORISTS || winStatus == WINSTATUS_DRAW)
        g_iRoundEnd = 1;
}

public CBasePlayer_Spawn(id)
{
    g_iSecond[id] = 0;
    remove_task(id + TASK_SECONDS);

    if (get_member(id, m_iTeam) == TEAM_CT)
        set_task(1.0, "Task_Seconds", id + TASK_SECONDS, _, _, "b");
}

public Task_Seconds(id)
{
    id -= TASK_SECONDS;

    if (!is_user_connected(id) || !is_user_alive(id) || get_member(id, m_iTeam) != TEAM_CT)
    {
        remove_task(id + TASK_SECONDS);
        return;
    }
    g_iSecond[id]++;
}

public Touch_Checkpoint(const iEnt, const iPlayer)
{       
    static i, iPos

    if (g_iRoundEnd || get_entvar(iEnt, var_impulse) != CHECKPOINT_KEY)
        return HC_CONTINUE;

    if (g_iDuelStart)
        return HC_CONTINUE;
    
    for (i = 0; i < g_iCheckpointsNum; i++)
    {
        if (g_iCheckpoint[i] == iEnt)
        {
            iPos = i
            break
        }
    }

    if (g_iPlrCompleted[iPlayer] >= iPos || !is_user_alive(iPlayer))
        return HC_CONTINUE;

    client_cmd(iPlayer, "spk %s", SOUND_CHECKPOINT)

    new iReward

    if (iPos == g_iCheckpointsNum - 1)
    {
        new playerName[32];
        get_user_name(iPlayer, playerName, charsmax(playerName));

        client_print_color(0, print_team_default, "^4*** ^1%L", iPlayer, "CP_FINISH_CHAT", playerName, ++g_iFinishedNum, g_iSecond[iPlayer]);

        new fmt[450];
        formatex(fmt, charsmax(fmt), "%L", LANG_PLAYER, "CP_FINISH_HUD", g_iFinishedNum, g_iSecond[iPlayer]);

        replace_all(fmt, charsmax(fmt), "\n", "^n");

        say_dhudmessage(0, 155, 155, 155, -1.0, 0.14, 4, fmt);

        if (g_iFinishedNum > 3)
            iReward = get_pcvar_num(g_pCvars[CVAR_CHECKPOINT_REWARD])
        else
            iReward = get_pcvar_num(g_pCvars[CVAR_CHECKPOINT_FINISH_REWARD][g_iFinishedNum - 1])

        new returnvalue;
        ExecuteForward(g_fwdFinish, returnvalue, iPlayer);
    }
    else
    {
        iReward = get_pcvar_num(g_pCvars[CVAR_CHECKPOINT_REWARD])
        say_hudmessage(iPlayer, 155, 155, 155, -1.0, 0.78, 2, "%L", LANG_PLAYER, "CP_COMPLETE", iPos + 1, iReward);
    }
    
    if (iReward)
        rg_add_account(iPlayer, iReward)

    g_iPlrCompleted[iPlayer] = iPos

    return HC_CONTINUE;
}

public dr_duel_start(iPlayerCT, iPlayerTE) g_iDuelStart = 1
public dr_duel_finish() g_iDuelStart = 0
public dr_duel_canceled() g_iDuelStart = 0

stock _fm_get_aim_origin(index, Float:origin[3]) {
    new Float:start[3], Float:view_ofs[3];
    pev(index, pev_origin, start);
    pev(index, pev_view_ofs, view_ofs);
    xs_vec_add(start, view_ofs, start);

    new Float:dest[3];
    pev(index, pev_v_angle, dest);
    engfunc(EngFunc_MakeVectors, dest);
    global_get(glb_v_forward, dest);
    xs_vec_mul_scalar(dest, 9999.0, dest);
    xs_vec_add(start, dest, dest);

    engfunc(EngFunc_TraceLine, start, dest, 0, index, 0);
    get_tr2(0, TR_vecEndPos, origin);

    return get_tr2(0, TR_pHit);
}

stock say_hudmessage(const iIndex, const iRed, const iGreen, const iBlue, Float: fX = -1.0, Float: fY = -1.0, iHoldTime = 10, szMessage[], any:...)
{
    new szMsg[512];
    vformat(szMsg, charsmax(szMsg), szMessage, 9);

    new iMsgSync;
    if (!iMsgSync)
        iMsgSync = CreateHudSyncObj();

    set_hudmessage(iRed, iGreen, iBlue, fX, fY, 0, 6.0, float(iHoldTime), 0.1, 0.2, -1);
    ShowSyncHudMsg(iIndex, iMsgSync, szMsg);
}

stock say_dhudmessage(const iIndex, const iRed, const iGreen, const iBlue, Float: fX = -1.0, Float: fY = -1.0, iHoldTime = 10, szMessage[], any:...)
{
    new szMsg[512];
    vformat(szMsg, charsmax(szMsg), szMessage, 9);

    set_dhudmessage(iRed, iGreen, iBlue, fX, fY, 0, 6.0, float(iHoldTime), 0.1, 0.2);
    show_dhudmessage(iIndex, szMsg);
}

stock rg_remove_entity(iEnt)
{
    if (is_entity(iEnt))
    {
        set_entvar(iEnt, var_flags, get_entvar(iEnt, var_flags) | FL_KILLME);
        set_entvar(iEnt, var_nextthink, get_gametime());
    }
}

stock bool: check_stuck(const Float: fOrigin[3], const iPlayer)
{
    static tr
    engfunc(EngFunc_TraceHull, fOrigin, fOrigin, 0, HULL_HUMAN, iPlayer, tr)

    if (!get_tr2(tr, TR_StartSolid) || !get_tr2(tr, TR_AllSolid))
        return false
    return true
}

Проблема с DR Checkpoints

ufame

MaZahakA

ufame

Пользователи, просматривающие эту тему