Нужна ваша помощь

sultvnbek · 9 Апр 2024

Доброго времени суток форумчане! Плагин компилируется, но возраждение работает при онлайне от 2х игроков. Несмотря что в исходнике стоит minplayer: 14
Помогите исправить

avice · 9 Апр 2024

Покажите вывод arev_minplayers из консоли сервера.

sultvnbek · 9 Апр 2024

avice,
"arev_minplayers" is "14"

avice · 9 Апр 2024

SNauPeR

Code_0xABC · 9 Апр 2024

Ну конечноже, функуия register_cvat вернет нам id зарегистрированного квара и мы записываем в g_iCvarMinP, вот поэтому там значение непонятно, а не 14 и тут мы делаем эту проверку iPlayerCount < g_iCvarMinP, где сравниваете количество игроков с id квара

mlibre · 9 Апр 2024

mp_forcerespawn?

sultvnbek · 9 Апр 2024

@Code_0xABC,Можете помочь с кодом?если не затруднит

Code_0xABC · 9 Апр 2024

sultvnbek, прикрепи это фаил auto_revive.txt

sultvnbek · 11 Апр 2024

Проблема решена!
Код переписал https://dev-cs.ru/members/10921/ , спасибо за помощь!
Если кому-то понадобиться оставлю исходник здесь

Код:

#include <amxmodx>
#include <amxmisc>
#include <reapi>

#define rg_get_user_team(%0)  TeamName:get_member(%0, m_iTeam)
#define is_user(%0) bool:(0 < %0 <= MaxClients)
const TASK_CHECK = 0x505C6;

enum any:DATA_USER {
    TeamName:TEAM,
    COUNT
};

enum any:DATA_REVIVE {
    RV_COUNT_TER,
    RV_COUNT_CT,
    RV_TIME,
    RV_MONAY,
    RV_MIN_USER,
    RV_ROUND
};

enum any:DATA_GAME {
    TIME,
    COUNT_TER,
    COUNT_CT
};

new
    gl_eCvar[DATA_REVIVE],
    gl_eCurrent[DATA_GAME],
    bool:gl_bUserSpawn[MAX_PLAYERS +1];

public plugin_init() {
    new const szNamePlugin[] = "(REAPI)Auto_Revive";
    register_plugin(szNamePlugin, "10.04.24", "DEV-CS.RU");

    RegisterHookChain(RG_CSGameRules_RestartRound, "RG_CSGameRules_RestartRound_Post", true);
    RegisterHookChain(RG_CBasePlayer_Killed, "RG_CBasePlayer_Killed_Post", true);
    RegisterHookChain(RG_CBasePlayer_Spawn, "RG_CBasePlayer_Spawn_Post", true);

    UTIL_Cvar(szNamePlugin[7]);
}

UTIL_Cvar(const szBuffer[]) {
    bind_pcvar_num(create_cvar("arev_players_t", "2"), gl_eCvar[RV_COUNT_TER]);
    bind_pcvar_num(create_cvar("arev_players_ct", "2"), gl_eCvar[RV_COUNT_CT]);
    bind_pcvar_num(create_cvar("arev_time", "30"), gl_eCvar[RV_TIME]);
    bind_pcvar_num(create_cvar("arev_money", "0"), gl_eCvar[RV_MONAY]);
    bind_pcvar_num(create_cvar("arev_minplayers", "9"), gl_eCvar[RV_MIN_USER]);
    bind_pcvar_num(create_cvar("arev_roundstart", "2"), gl_eCvar[RV_ROUND]);

    AutoExecConfig(true, szBuffer);
}

public client_disconnected(id)
    gl_bUserSpawn[id] = false;

public RG_CSGameRules_RestartRound_Post() {
    new iRound = get_member_game(m_iTotalRoundsPlayed) +1;

    if(iRound >= gl_eCvar[RV_ROUND]) {
        gl_eCurrent[COUNT_TER] = gl_eCvar[RV_COUNT_TER];
        gl_eCurrent[COUNT_CT] = gl_eCvar[RV_COUNT_CT];

        gl_eCurrent[TIME] = get_systime(gl_eCvar[RV_TIME] > 0 ? gl_eCvar[RV_TIME] : floatround(get_cvar_float("mp_buytime") * 60.0));
    }

    else gl_eCurrent[COUNT_TER] = gl_eCurrent[COUNT_CT] = gl_eCurrent[TIME] = 0;

    arrayset(gl_bUserSpawn, false, MaxClients);
}

public RG_CBasePlayer_Killed_Post(const pVictim, const pKiller, const iGib) {
    new eBuffer[DATA_USER];

    eBuffer[TEAM] = rg_get_user_team(pVictim);
    eBuffer[COUNT] = get_playersnum_ex(GetPlayers_MatchTeam, "CT") + get_playersnum_ex(GetPlayers_MatchTeam, "TERRORIST");

    if(is_user_bot(pVictim) || !is_user(pVictim) || gl_eCurrent[TIME] < get_systime())
        return HC_CONTINUE;

    if((!gl_eCurrent[COUNT_CT] && eBuffer[TEAM] == TEAM_CT) || (!gl_eCurrent[COUNT_TER] && eBuffer[TEAM] == TEAM_TERRORIST))
        return HC_CONTINUE;

    if(TEAM_TERRORIST > eBuffer[TEAM] > TEAM_CT)
        return HC_CONTINUE;

    if(eBuffer[COUNT] > gl_eCvar[RV_MIN_USER])
        set_task(0.1, "UTIL_ReviveCheck", TASK_CHECK +pVictim, eBuffer, COUNT);

    return HC_CONTINUE;
}

public UTIL_ReviveCheck(const eBuffer[], id) {
    id -= TASK_CHECK;

    if(!is_user_alive(id)) {
        set_member(id, m_flRespawnPending, 0.15);

        eBuffer[TEAM] == TEAM_CT ? --gl_eCurrent[COUNT_CT] : --gl_eCurrent[COUNT_TER];
        gl_bUserSpawn[id] = true;

        client_print_color(0, id, "^4• ^1Игрок ^3%n ^1был возрожден", id);
    }
}

public RG_CBasePlayer_Spawn_Post(const id) {
    if(gl_bUserSpawn[id]) {
        if(gl_eCvar[RV_MONAY]) {
            client_print_color(id, id, "^4* ^1Вы были возрождены, вам выдано ^3%d$", gl_eCvar[RV_MONAY]);
            rg_add_account(id, gl_eCvar[RV_MONAY], AS_ADD);
        }
    }
}

Тему можно закрывать.