Regen HP/AP for Knife (регенерация)

[pataychlenix]

привет, может кто помочь добавить флаги в исходник, чтоб к примеру хп регенилось у обычных игроков, армор у випов
Regen HP/AP for Knife (регенерация) | Dev-CS.ru

#include <amxmodx>
#include <reapi>

#define REGEN_TIME            5                    // Interval time
#define REGEN_AMOUNT_HP        15                    // Amount HP for interval
#define REGEN_AMOUNT_AP        15                  // Amount AP for interval

#define MAX_HP    100        // max hp
#define MAX_AP    100        // max ap

public plugin_init()
{
    register_plugin("Regen HP AP for knife", "1.0", "I Am LeGenD")
    
    RegisterHookChain(RG_CBasePlayer_PostThink, "@CBasePlayer_PostThink")
}

@CBasePlayer_PostThink(const Player)
{
    new Float: flTime = get_gametime()
    new Float: flHealth = Float: get_entvar(Player, var_health)
    new Float: flAmmor = Float: get_entvar(Player, var_armorvalue)
    
    static Float: flLife[MAX_CLIENTS + 1]
    
    if(get_user_weapon(Player) == CSW_KNIFE)
    {
        if(flLife[Player] < flTime)
        {
            flLife[Player] = flTime + REGEN_TIME.0
            
            if(flHealth < MAX_HP.0 || flAmmor < MAX_AP.0)
            {
                set_entvar(Player, var_health, floatmin (flHealth + REGEN_AMOUNT_HP.0, MAX_HP.0))
                set_entvar(Player, var_armorvalue, floatmin (flAmmor + REGEN_AMOUNT_AP.0, MAX_AP.0))
            }
        }
    }
}

 

[Code_0xABC]

pataychlenix, а попытки будут?

 

[pataychlenix]

Code_0xABC, какие?)

 

[Code_0xABC]

Реализаци проверок на флаг доступа

 

[pataychlenix]

Code_0xABC, если это нужно, то хорошо, я плохо разбираюсь в этом

 

[Code_0xABC]

pataychlenix, не помню есть ли флаг доступа у всех ADMIN_USER, проверь будет ли добовалять хп випам, если что подправим

#include <amxmodx>
#include <reapi>

#define REGEN_TIME            5                    // Interval time
#define REGEN_AMOUNT_HP        15                    // Amount HP for interval
#define REGEN_AMOUNT_AP        15                  // Amount AP for interval

#define MAX_HP    100        // max hp
#define MAX_AP    100        // max ap

public plugin_init()
{
    register_plugin("Regen HP AP for knife", "1.0", "I Am LeGenD")
  
    RegisterHookChain(RG_CBasePlayer_PostThink, "@CBasePlayer_PostThink")
}

@CBasePlayer_PostThink(const Player)
{
    if(!is_user_alive(Player))
        return;

    if(get_user_weapon(Player) == CSW_KNIFE)
    {   
        new Float: flTime = get_gametime()
        static Float: flLife[MAX_CLIENTS + 1]

        if(flLife[Player] < flTime)
        {
            flLife[Player] = flTime + REGEN_TIME.0
          
            if(get_user_flags(Player) & ADMIN_LEVEL_H)
            {
                Float: flAmmor = Float: get_entvar(Player, var_armorvalue)
              
                flAmmor < MAX_AP.0)
                    set_entvar(Player, var_armorvalue, floatmin (flAmmor + REGEN_AMOUNT_AP.0, MAX_AP.0))
            }
            
            new Float: flHealth = Float: get_entvar(Player, var_health)
              
            if(flHealth < MAX_HP.0)
                set_entvar(Player, var_health, floatmin (flHealth + REGEN_AMOUNT_HP.0, MAX_HP.0))
        }
    }
}

 

[ImmortalAmxx]

Code_0xABC, ADMIN_USER - флаг z, если его не выдают в момент выдачи привилегии, то у игрока его не будет. Если хочешь сделать для всех - не делать проверку, либо использовать ADMIN_ALL.

 

[Code_0xABC]

ImmortalAmxx, нужно тому у когонет никаких флагов

 

[ImmortalAmxx]

Code_0xABC, тогда все верно, ADMIN_USER для этого нужен.

 

[Code_0xABC]

ImmortalAmxx, не понятен его вопрос, либо дать только випам и только обычнм или випам и то и то, а игрокам только хп

23 Ноя 2023

Пишу с телефона, опечатка

--flAmmor < MAX_AP.0)
++if(flAmmor < MAX_AP.0)

 

[pataychlenix]

спасибо, помог Code_0xABC

 

[pataychlenix]

опечатка*
new Float: flAmmor = Float: get_entvar(Player, var_armorvalue)

 

[Code_0xABC]

pataychlenix, с телефона неудобства

 

[pataychlenix]

Code_0xABC, флаг работает, плагин почему-то багается когда проходит урон, допустим если 100 армора, тебе сносят до 90 армора и он сбивает армор в 0, секунд 10 набирает 5-10, потом до 100 доходит, поставлю тогда без флагов, чтоб не заморачиваться с фиксом флагов, все равно спасибо тебе

 

[Code_0xABC]

pataychlenix, приеду домой посмотрю, получать броню и хп надо тогда до проверки на нож

23 Ноя 2023

Буквально через часик, а то с телефона тяжело писать

 

[Code_0xABC]

pataychlenix, держи

#include <amxmodx>
#include <reapi>

#define REGEN_TIME             5.0                      // Interval time
#define REGEN_AMOUNT_HP        15.0                    // Amount HP for interval
#define REGEN_AMOUNT_AP        15.0                    // Amount AP for interval

#define MAX_HP    100.0        // max hp
#define MAX_AP    100.0        // max ap

#define IS_HANDS_KNIFE(%0) bool:(get_user_weapon(%0) == CSW_KNIFE)

#define IS_VIP(%0) bool:(get_user_flags(%0) & ACCESS)
#define ACCESS ADMIN_LEVEL_H  // Флаг доступа для випа

#define RG_GET_ARMOR(%0) get_entvar(%0, var_armorvalue)
#define RG_SET_ARMOR(%0,%1) set_entvar(%0, var_armorvalue, floatmin(flAmmor +%1, MAX_AP))
#define RG_GET_HEALTH(%0) get_entvar(%0, var_health)
#define RG_SET_HEALTH(%0,%1) set_entvar(%0, var_health, floatmin(flHealth +%1, MAX_HP))

public plugin_init() {
    register_plugin("Regen HP AP for knife", "1.0", "I Am LeGenD");

    RegisterHookChain(RG_CBasePlayer_PostThink, "CBasePlayer_PostThink");
}

public CBasePlayer_PostThink(const Player) {
    if(is_user_alive(Player) && IS_HANDS_KNIFE(Player)) {
        new
            Float:flAmmor = RG_GET_ARMOR(Player),
            Float:flHealth = RG_GET_HEALTH(Player),
            Float:flTime = get_gametime();

        static Float:flLife[MAX_CLIENTS +1];

        if(flLife[Player] < flTime) {
            flLife[Player] = flTime + REGEN_TIME;

            if(IS_VIP(Player) && flAmmor < MAX_AP)
                RG_SET_ARMOR(Player, REGEN_AMOUNT_AP);

            if(flHealth < MAX_HP)
                RG_SET_HEALTH(Player, REGEN_AMOUNT_HP);
        }
    }
}

 

[pataychlenix]

Code_0xABC, проверил, все работает без проблем, спасибо

 

[Code_0xABC]

pataychlenix,

Спойлер: offtop

Не забывайте ставить решение вопроса, на пост который помог

 

[pataychlenix]

Code_0xABC,

Спойлер: оффтоп

да, я бы с радостью, только не могу найти кнопку, что твой ответ мне помог, раньше видел такую кнопку, возможно у меня тунельное зрение

 

[ImmortalAmxx]

Code_0xABC,

Спойлер: Оффтоп

Тут нету, ибо это вопрос по созданию и модификации.