Run time error 10: native error (native "client_print")

zmuser · 23 Ноя 2023

Суть плагина - когда стреляешь в зомби, то тебе в центре экрана показывает его хп
Находил несколько таких плагинов, но везде эта ошибка в консоле присутствует. Погуглил - ничего для себя не нашел как пофиксить это

Код:

L 11/22/2023 - 20:39:24: [AMXX]    [0] zp_showZmHp.sma::event_damage (line 13)
L 11/22/2023 - 20:39:25: Invalid player id 132
L 11/22/2023 - 20:39:25: [AMXX] Displaying debug trace (plugin "zp_showZmHp.amxx", version "1.0")

Code_0xABC · 23 Ноя 2023

zmuser, перед тем как получить здоровье жертвы через функцию get_user_health(id), игрок успел выйти с сервера. Нужно сделать проверку на коннект игрока!

Код:

#include <amxmodx>
#include <zombieplague>

public plugin_init() {
    register_plugin("ZP: Show Victim HP On Damage", "1.0", "<VeCo>");
    register_event("Damage","event_damage","b","2!0","3=0","4!0");
}

public event_damage(id) {
    if(!is_user_connected(id))
        return;
      
    new killer = get_user_attacker(id);
  
    if(zp_get_user_zombie(id))
        client_print(killer, print_center, "hp %i", get_user_health(id));
}

b0t. · 23 Ноя 2023

zmuser,

Код:

/**
    0.1 (23.11.2023) by b0t.
        - Релиз;
*/
new const VERSION[] = "0.1";
#include <amxmodx>
#include <zombieplague>
#include <reapi>
public plugin_init() {
    register_plugin("ZM: Show zombie hp",VERSION,"b0t.");
    RegisterHookChain(RG_CBasePlayer_TakeDamage,"CBasePlayer_TakeDamage_Post", .post = true);
}
public CBasePlayer_TakeDamage_Post(const pVictim,const iInflictor,const pAttacker) {
    if(!is_user_connected(pAttacker))
        return;
    
    if(zp_get_user_zombie(pVictim))
        client_print(pAttacker,print_center,"hp %i",floatround(Float:get_entvar(pVictim,var_health)));
}

Код:

/**
    0.1 (23.11.2023) by b0t.
        - Релиз;
*/
new const VERSION[] = "0.1";
#include <amxmodx>
#include <zombieplague>
#include <hamsandwich>
#include <fakemeta>
public plugin_init() {
    register_plugin("ZM: Show zombie hp",VERSION,"b0t.");
    RegisterHam(Ham_TakeDamage,"player","Ham_TakeDamage_Post",true);
}
public Ham_TakeDamage_Post(const pVictim,const iInflictor,const pAttacker) {
    if(!is_user_connected(pAttacker))
        return;
    
    if(zp_get_user_zombie(pVictim))
        client_print(pAttacker,print_center,"hp %i",floatround(Float:pev(pVictim,pev_health)));
}

Code_0xABC · 23 Ноя 2023

b0t.,

Самое интересное, эта тема обсуждалась миллион раз, даже забить в поисковик трудно

b0t. · 23 Ноя 2023

Code_0xABC,

Как выяснилось, и не раз, многие не умеют им пользоваться

Code_0xABC · 23 Ноя 2023

b0t., кстате, тебе тоже ошибка прилетит, ты получаешь здоровье жертвы floatround(Float:get_entvar(pVictim,var_health)), а на коннект проверяешь атакующего

b0t. · 23 Ноя 2023

Code_0xABC, В какой момент. Отметь в коде.

23 Ноя 2023

Code_0xABC, ну так это логично... Форвард получения урона в post, т.е. после того как игрок получил урон.
Атакующий может кинуть гранату и выйти, а вот жертва не сможет сначала выйти с сервера, а уже после получить урон

Code_0xABC · 23 Ноя 2023

b0t., на пример подвис

b0t. · 23 Ноя 2023

Code_0xABC, не логично :)
Сколько не смотрели, всё прекрасно, даже если игрок подвисает.
А вот проверить находиться ли атакующий на сервере стоит. Опять же пример с гранатой

Code_0xABC · 23 Ноя 2023

b0t., Обьясни, не смотрел, client_print через мессагу отсылается? Если шлется через MSG_BROADCAST и MSG_ONE_UNRELIABLE , то какой смысл проверять игрока на коннект (атакующего), и ошибка я считаю прилетела со стороны жертвы, подвис и держи еррорку. В его варианте, нужно проверить жертву, в твоем варианте, я думаю она не прилетит даже, если не проверить ни жертву на атакующего.

23 Ноя 2023

Ну не могу точно сказать конечно, не смотрел как работает client_print

BiZaJe · 23 Ноя 2023

Code_0xABC, https://github.com/alliedmodders/am...ab0d4d70e0a650074fd485d/amxmodx/util.cpp#L280

Code_0xABC · 23 Ноя 2023

b0t., хотя забираю слова обратно по поводу client_print, требуется проверка на коннект аттакующего

Error
If a single client is specified and the index is not within
the range of 1 to MaxClients, an error will be thrown.

BiZaJe, Спасибо, посмотрел

Код:

if (pEntity)
    MESSAGE_BEGIN(MSG_ONE, gmsgTextMsg, NULL, pEntity);
else
    MESSAGE_BEGIN(MSG_BROADCAST, gmsgTextMsg);

zmuser · 23 Ноя 2023

Спасибо за решение! Не знал какое решение отметить, отметил первое
На счёт поиска по форуму - что-то не подумал, в гугле полазил, думал и от сюда он ответы предложит, но нет

Code_0xABC · 23 Ноя 2023

zmuser, если ты выбрал первый вариант, то там тогда требуется еще проверка, а то сообщение тоже выдаст ошибку, если игрок кинет гранату и выйдет. Добавь между 13 и 14 строкой

Код:

++ if(!is_user_connected(killer)) return;

zmuser · 23 Ноя 2023

Code_0xABC, хорошо
Спасибо большое Code_0xABC и b0t. за помощь
Лайки не могу ставить, к сожалению(

Code_0xABC · 23 Ноя 2023

zmuser,

дело не в лайках, достаточно спасибо

Run time error 10: native error (native "client_print")

zmuser

Code_0xABC

b0t.

Download all Attachments

Code_0xABC

b0t.

Code_0xABC

b0t.

Code_0xABC

b0t.

Code_0xABC

BiZaJe

Code_0xABC

zmuser

Code_0xABC

zmuser

Code_0xABC

Пользователи, просматривающие эту тему