Убрать меню с выбором класса

[Vaqtincha]

YahOoo, тестил на регейме там все норм (без классов) с VGUI так и OldMenu

 

[YahOoo]

Vaqtincha, Спасибо тебе, щас тоже на другом сервере проверил, все ок, а на моем только с выбором класса, даже не возрождает, пока класс не выберешь.
Хотя, все решил, только вот надо как то менюшку с классами убирать

 

[BaJIepbI4]

И что в итоге получилось в виде кода?

 

[SergeyShorokhov]

BaJIepbI4, Убрать меню с выбором класса

 

[YahOoo]

BaJIepbI4, Именно ^ Потом проблемы были на моей стороне, не смотри на них.

 

[Andrey]

Сделал плагин, но не дает зайти в игру на картах типа дм с бескон. раундом с возрождением, все время мертв. что тут не правильно?

Спойлер: плагин

#include <amxmodx>

#include <cstrike>

#include <fakemeta>



new g_MapName[32], bool:g_VIPMap = false;



public plugin_init()

{

    register_plugin("Change Team", "1.1", "neygomon & Alienware");

    register_clcmd("chooseteam", "ShowMenu");

    register_menucmd(register_menuid("Team Menu"), MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_5|MENU_KEY_6|MENU_KEY_0, "HandleMenu");

    register_message(get_user_msgid("ShowMenu"), "MessageShowMenu");

    register_message(get_user_msgid("VGUIMenu"), "MessageVGUIMenu");

    get_mapname(g_MapName, charsmax(g_MapName));

    if(containi(g_MapName, "as_") != -1) g_VIPMap = true;

}



public MessageVGUIMenu(iMsgId, iMsgDest, iReceiver)

{

    if(get_msg_arg_int(1) == 2)

    {

        set_pdata_int(iReceiver, 205, 0);

        return ShowMenu(iReceiver);

    }

    if(get_msg_arg_int(1) == 27 || get_msg_arg_int(1) == 26)

    {

        return PLUGIN_HANDLED;

    }

    return PLUGIN_CONTINUE;

}



public ShowMenu(id)

{

    new szMenu[512], iLen = formatex(szMenu, charsmax(szMenu), "\rВыбор команды \wby \yRB|18+|:^n^n"), iKeys = MENU_KEY_0;

    new CsTeams:iTeam = cs_get_user_team(id);

    

    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y1. \rТеррористы^n");

    iKeys |= MENU_KEY_1;



    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y2. \wКонтр-террористы^n^n");

    iKeys |= MENU_KEY_2;



    if(g_VIPMap) {

        if(iTeam != CS_TEAM_CT) iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y3. \dСтать VIP^n^n");

        else {

            iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y3. \wСтать VIP^n^n");

            iKeys |= MENU_KEY_3;

        }

    }



    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y5. \rСлучайный \yвыбор^n");

    iKeys |= MENU_KEY_5;



    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y6. \wНаблюдение^n^n^n");

    iKeys |= MENU_KEY_6;

    formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y0. \rВыход");

    return show_menu(id, iKeys, szMenu, -1, "Team Menu");

}



public HandleMenu(id, iKey)

{

    switch(iKey)

    {

        case 0:

        {

            set_pdata_int(id, 125, get_pdata_int(id, 125) & ~(1<<8));

            engclient_cmd(id, "jointeam", "1");

        }

        case 1:

        {

            set_pdata_int(id, 125, get_pdata_int(id, 125) & ~(1<<8));

            engclient_cmd(id, "jointeam", "2");

        }

        case 2:

        {

            set_pdata_int(id, 125, get_pdata_int(id, 125) & ~(1<<8));

            engclient_cmd(id, "jointeam", "3");

        }

        case 4:

        {

            set_pdata_int(id, 125, get_pdata_int(id, 125) & ~(1<<8));

            engclient_cmd(id, "jointeam", "5");

        }

        case 5:

        {

            user_kill(id, 1);

            engclient_cmd(id, "jointeam", "6");

        }

    }

    new iMsgBlock = get_msg_block(get_user_msgid("ShowMenu"));

    set_msg_block(get_user_msgid("ShowMenu"), BLOCK_ONCE);

    engclient_cmd(id, "joinclass", "5");

    set_msg_block(get_user_msgid("ShowMenu"), iMsgBlock);

    return PLUGIN_HANDLED;

}



public MessageShowMenu(iMsgId, iMsgDest, iReceiver)

{

    static szArg4[20];

    get_msg_arg_string(4, szArg4, charsmax(szArg4));

    

    if(equal(szArg4, "#CT_Select") || equal(szArg4, "#Terrorist_Select")) return PLUGIN_HANDLED;

    if(equal(szArg4, "#Team_Select", 12) || equal(szArg4, "#IG_Team_Select", 15) || equal(szArg4, "#IG_VIP_Team_Select", 19))

    {

        set_pdata_int(iReceiver, 205, 0);

        ShowMenu(iReceiver);

        return PLUGIN_HANDLED;

    }

    return PLUGIN_CONTINUE;

}

 

[fantom]

Вы используете ReHLDS?

 

[Andrey]

fantom, Нет HLDS 6153