Плагин Admin Gift

RedGamer · 2 Апр 2023

Какой то массив выходит за границы, при выходе из меню.. но где и как исправить?

Javekson · 2 Апр 2023

Строка 278 - ты открываешь меню, смещая позицию страницы назад, но в самом Show_PlayerMenu тебе надо учесть, что страница, она же позиция не может быть отрицательной, в этом случае просто не продолжать код. Сможешь сам?

RedGamer · 2 Апр 2023

Javekson,

C++:

public Handle_PlayerMenu(id, iKey)
{
    if(ShowPlayerMenu(id, g_iMenuPosition[id] = -1)
    return PLUGIN_HANDLED;
}
    switch(iKey)
    {
        case 8: return Show_PlayerMenu(id, ++g_iMenuPosition[id]);
        case 9: return Show_PlayerMenu(id, --g_iMenuPosition[id]);
        default:
        {

?

2 Апр 2023

Код реально сложный для меня, всё-таки скажу это, автор плагина накуралесил так, что нихера не понял

Javekson · 2 Апр 2023

Код:

#include <amxmodx>
#include <amxmisc>

// -> Инфо о плагине <- //{
new g_Plugin[] = "[AMXX] Admin Gift";
new g_Version[] = "02.01.2018";
new g_Author[] = "Number One";
// -> Инфо о плагине <- //}

const PLAYERS_PER_PAGE = 8; // Игроков на одной странице (9 - далее | 0 - выход)
const RIGHT_PER_PAGE = 7;

new g_iMenuPlayers[33][32], g_iMenuPosition[33];
new Admin[32], Player[32];
new Password[64];
new szPassword[33][64];
new g_iRight[33], g_iTake[33], Target[33];

// Список администраторов
enum _:DATA_ADMIN_LIST { RIGHT[64], FLAGS[64] }
new Array:g_aAdminList;
new g_iAdminListSize;

// Users
new g_LoadList[81]
new szParse[128]
new szParseUser[64]
new szLine, szNum
new szBlock[512];

new flags_admin_right, flags_admin_take, type_admin_right, type_admin_take;

// Срок
new g_Time[33];
new const g_szTime[] = { 1, 7, 15, 30, 90 };

public plugin_init()
{
    register_plugin(g_Plugin, g_Version, g_Author);

    register_menucmd(register_menuid("Show_MainMenu"), (1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9), "Handle_MainMenu");
    register_menucmd(register_menuid("Show_PlayerMenu"), (1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9), "Handle_PlayerMenu");
    register_menucmd(register_menuid("Show_ConfirmMenu"), (1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9), "Handle_ConfirmMenu");

    register_clcmd("admin_right", "ClientCmd");
    register_clcmd("write_reason", "Command_WriteReason");
    
    flags_admin_right = register_cvar("gp_admin_right", "l"); // Флаг админа, который может выдать привилегии
    flags_admin_take = register_cvar("gp_admin_take", "l"); // Флаг админа, который может забрать привилегии
    type_admin_right = register_cvar("gp_type_admin_right", "1"); // Привилегию в users.ini [ 1 - Записывать | 0 - выдать на карту ]
    type_admin_take = register_cvar("gp_type_admin_take", "1"); // Привилегию в users.ini [ 1 - Отключать навсегда | 0 - выключить на карту ]
    server_cmd("exec addons/amxmodx/configs/OnlineRight/main.cfg");
    register_dictionary("right_key_menu.txt");
    admin_remove();
}

public plugin_precache()
{
    new szCfgDir[64], szCfgFile[128];
    get_localinfo("amxx_configsdir", szCfgDir, charsmax(szCfgDir));
// Получаем список Привилегий
    formatex(szCfgFile, charsmax(szCfgFile), "%s/OnlineRight/privilege.ini", szCfgDir);
    switch(file_exists(szCfgFile))
    {
        case 0:
        {
            write_file(szCfgFile, "; ^"Название привилегии^" ^"флаг^"");
        }
        case 1:
        {
            new aDataAdminLIST[DATA_ADMIN_LIST], szBuffer[128], iLine, iLen;
            g_aAdminList = ArrayCreate(DATA_ADMIN_LIST);
            while(read_file(szCfgFile, iLine++, szBuffer, charsmax(szBuffer), iLen))
            {
                if(!iLen || szBuffer[0] == ';') continue;
                parse
                (
                    szBuffer,
                    aDataAdminLIST[RIGHT], charsmax(aDataAdminLIST[RIGHT]),
                    aDataAdminLIST[FLAGS], charsmax(aDataAdminLIST[FLAGS])
                );
                ArrayPushArray(g_aAdminList, aDataAdminLIST);
            }
            g_iAdminListSize = ArraySize(g_aAdminList);
        }
    }
// Получаем список админов
    new g_LoadDir[81]
    get_configsdir(g_LoadDir, charsmax(g_LoadDir))

    formatex(g_LoadList, charsmax(g_LoadList), "%s/users.ini", g_LoadDir)
 
    if(!file_exists(g_LoadList))
    {
        write_file(g_LoadList, "; Список Администраторов");
    }
}

public admin_remove()
{
    new text_s[256], m_date[12], line, len
    read_file("/addons/amxmodx/configs/users.ini", line, text_s, charsmax(text_s), len)
    trim(text_s)
        
    get_time("%Y.%m.%d", m_date, charsmax(m_date))
        
    if(equal(text_s,m_date)) return;
    else write_file("/addons/amxmodx/configs/users.ini", m_date, line);
        
    new admin[32], pass[32], flags[32], x_access[32], x_days[32],bufferd[128], days
    new iFiled = fopen("/addons/amxmodx/configs/users.ini","r");
        
    while(!feof(iFiled))
    {
        fgets(iFiled,bufferd,255)
        trim(bufferd)
        
        if(bufferd[0]=='"')
        {
            parse(bufferd, admin, 31, pass, 31, flags, 31, x_access, 31, x_days, 31)

            days=str_to_num(x_days)-1
        
            if(days) formatex(text_s, charsmax(text_s), "^"%s^" ^"%s^" ^"%s^" ^"%s^" ^"%d^"", admin,  pass, flags, x_access, days)
            else formatex(text_s, charsmax(text_s), ";^"%s^" ^"%s^" ^"%s^" ^"%s^" ^"%d^"", admin,  pass, flags, x_access, days)
        
            if(line) write_file("/addons/amxmodx/configs/users.ini", text_s, line)
        }
        line++
    }

    fclose(iFiled)
    server_cmd("amx_reloadadmins");
}

public Command_WriteReason(id)
{
    read_argv(1, Password, charsmax(Password));
    if(!equal(Password, ""))
    {
        copy(szPassword[id], charsmax(szPassword[]), Password);
        return Show_ConfirmMenu(id);
    }
    else
    {
        ColorChat(id, "%L!y Пароль не может быть пустой!.", id, "PREFIX_CHAT");
        client_cmd(id, "messagemode ^"write_reason^"");
    }

    return PLUGIN_HANDLED;
}

public ClientCmd(id)
{
    g_iRight[id] = 0;
    g_iTake[id] = 0;
    Target[id] = 0;
    Show_MainMenu(id, g_iMenuPosition[id] = 0);
}

Show_MainMenu(id, iPos)
{
    if (iPos == -1) {
        return PLUGIN_CONTINUE;
    }
    
    new g_szFlagsRight[64], g_szFlagsTake[64]
    get_pcvar_string(flags_admin_right, g_szFlagsRight, charsmax(g_szFlagsRight));
    get_pcvar_string(flags_admin_take, g_szFlagsTake, charsmax(g_szFlagsTake));
    if(iPos < 0) return PLUGIN_HANDLED;
    new iStart = iPos * RIGHT_PER_PAGE;
    if(iStart > g_iAdminListSize) iStart = g_iAdminListSize;
    iStart = iStart - (iStart % RIGHT_PER_PAGE);
    g_iMenuPosition[id] = iStart / RIGHT_PER_PAGE;
    new iEnd = iStart + RIGHT_PER_PAGE;
    if(iEnd > g_iAdminListSize) iEnd = g_iAdminListSize;
    new szMenu[512], iLen, iPagesNum = (g_iAdminListSize / RIGHT_PER_PAGE + ((g_iAdminListSize % RIGHT_PER_PAGE) ? 1 : 0));
    new iKeys = (1<<9), b;
    if(get_user_flags(id) & read_flags(g_szFlagsRight)) iLen = formatex(szMenu, charsmax(szMenu), "\yМеню Выдачи Привилегий^n^n", iPos + 1, iPagesNum);
    else iLen = formatex(szMenu, charsmax(szMenu), "\yМеню Выдачи Привилегий^n\dВыдача для \y[Создателя]\w^n^n", iPos + 1, iPagesNum);
    for(new a = iStart; a < iEnd; a++)
    {
        new aDataAdminLIST[DATA_ADMIN_LIST];
        ArrayGetArray(g_aAdminList, a, aDataAdminLIST);
        if(get_user_flags(id) & read_flags(g_szFlagsRight))
        {
            iKeys |= (1<<b);
            iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Выдать %s^n", id, "MENU_KEY_DEFAULT", ++b, aDataAdminLIST[RIGHT]);
        }
        else iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\d Выдать %s^n", id, "MENU_KEY_DEFAULT", ++b, aDataAdminLIST[RIGHT]);
    }
    for(new i = b; i < RIGHT_PER_PAGE; i++) iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n");
    if(get_user_flags(id) & read_flags(g_szFlagsTake))
    {
        iKeys |= (1<<7);
        iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Забрать привилегии^n", id, "MENU_KEY_8");
    }
    else iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\d Забрать привилегии^n", id, "MENU_KEY_CLOSE");
    if(iEnd < g_iAdminListSize)
    {
        iKeys |= (1<<8);
        formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n%L \wДальше^n%L \w%s", id, "MENU_KEY_9", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    }
    else formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n^n%L \w%s", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    /*formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n^n\r[\y0\r] \w%s", iPos ? "Назад" : "Выход");*/
    return show_menu(id, iKeys, szMenu, -1, "Show_MainMenu");
}

public Handle_MainMenu(id, iKey)
{
    switch(iKey)
    {
        case 7:
        {
            g_iTake[id] = true;
            return Show_PlayerMenu(id, g_iMenuPosition[id] = 0);
        }
        case 8: return Show_MainMenu(id, ++g_iMenuPosition[id]);
        case 9: return Show_MainMenu(id, --g_iMenuPosition[id]);
        default:
        {
            g_iRight[id] = g_iMenuPosition[id] * RIGHT_PER_PAGE + iKey;
            return Show_PlayerMenu(id, g_iMenuPosition[id] = 0);
        }
    }
    return Show_MainMenu(id, g_iMenuPosition[id]);
}

Show_PlayerMenu(id, iPos)
{
    if (iPos == -1) {
        return PLUGIN_CONTINUE;
    }
    
    new iPlayersNum;
    for(new i = 1; i <= get_maxplayers(); i++)
    {
        if(!is_user_connected(i))
            continue;
        
        g_iMenuPlayers[id][iPlayersNum++] = i;
    }
    new iStart = iPos * PLAYERS_PER_PAGE;
    if(iStart > iPlayersNum) iStart = iPlayersNum;
    iStart = iStart - (iStart % PLAYERS_PER_PAGE);
    g_iMenuPosition[id] = iStart / PLAYERS_PER_PAGE;
    new iEnd = iStart + PLAYERS_PER_PAGE;
    if(iEnd > iPlayersNum) iEnd = iPlayersNum;
    new szMenu[512], iLen, iPagesNum = (iPlayersNum / PLAYERS_PER_PAGE + ((iPlayersNum % PLAYERS_PER_PAGE) ? 1 : 0));
    switch(iPagesNum)
    {
        case 0:
        {
            ColorChat(id, "%L!y Нету игроков!", id, "PREFIX_CHAT");
            return PLUGIN_HANDLED;
        }
        default: iLen = formatex(szMenu, charsmax(szMenu), "\yВыберите игрока^n^n", iPos + 1, iPagesNum);
    }
    new szName[32], i, iKeys = (1<<9), b;
    for(new a = iStart; a < iEnd; a++)
    {
        i = g_iMenuPlayers[id][a];
        get_user_name(i, szName, charsmax(szName));
        if(i != id)
        {
            iKeys |= (1<<b);
            iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L \w%s^n", id, "MENU_KEY_DEFAULT", ++b, szName);
        }
        else iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L \d%s \r[\yЭто вы\r]^n", id, "MENU_KEY_DEFAULT", ++b, szName);
    }
    for(new i = b; i < 8; i++) iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n");
    if(iEnd < iPlayersNum)
    {
        iKeys |= (1<<8);
        formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n%L \wДальше^n%L \w%s", id, "MENU_KEY_9", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    }
    else formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n^n%L \w%s", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    return show_menu(id, iKeys, szMenu, -1, "Show_PlayerMenu");
}

public Handle_PlayerMenu(id, iKey)
{
    switch(iKey)
    {
        case 8: return Show_PlayerMenu(id, ++g_iMenuPosition[id]);
        case 9: return Show_PlayerMenu(id, --g_iMenuPosition[id]);
        default:
        {
            Target[id] = g_iMenuPlayers[id][g_iMenuPosition[id] * PLAYERS_PER_PAGE + iKey];
            new aDataAdminLIST[DATA_ADMIN_LIST];
            ArrayGetArray(g_aAdminList, g_iRight[id], aDataAdminLIST);
            get_user_name(id, Admin, charsmax(Admin));
            get_user_name(Target[id], Player, charsmax(Player));
            if(g_iTake[id])
            {
                if(get_pcvar_num(type_admin_take) == 1)
                {
                    set_user_flags(Target[id], read_flags("z"));
                    remove_user_flags(Target[id],  read_flags("abcdefghijklmnopqrstu"));
                    for(szLine = 0; read_file(g_LoadList, szLine, szParse, charsmax( szParse ), szNum); szLine++)
                    {
                        if(szNum > 0 && szParse[0] != ';')
                        {
                            parse(szParse, szParseUser, charsmax(szParseUser));
                            if(equal(Player, szParseUser))
                            {
                                formatex(szBlock, charsmax(szBlock), ";%s", szParse);
                                write_file(g_LoadList, szBlock, szLine);
                                server_cmd("amx_reloadadmins");
                                break;
                            }
                        }
                    }
                }
                else
                {
                    set_user_flags(Target[id], read_flags("z"));
                    remove_user_flags(Target[id],  read_flags("abcdefghijklmnopqrstu"));
                }
                ColorChat(0,"%L!y Создатель !t%s !yзабрал у !t%s!y -!gвсе привилегии!y.", id, "PREFIX_CHAT", Admin, Player);
                return PLUGIN_HANDLED;
            }
            else
            {
                if(get_pcvar_num(type_admin_right) == 0)
                {
                    remove_user_flags(Target[id], read_flags("abcdefghijklmnopqrstuz"));
                    set_user_flags(Target[id], read_flags(aDataAdminLIST[FLAGS]));
                    ColorChat(0, "%L!y Создатель !t%s !yвыдал игроку!t %s!y -!g%s!y.", id, "PREFIX_CHAT", Admin, Player, aDataAdminLIST[RIGHT]);
                    return PLUGIN_HANDLED;
                }
                else
                {
                    client_cmd(id, "messagemode ^"write_reason^"");
                    ColorChat(id, "%L!y Введите пароль для игрока.", id, "PREFIX_CHAT");
                }
            }
        }
    }
    return Show_PlayerMenu(id, g_iMenuPosition[id] = 0);
}

Show_ConfirmMenu(id)
{
    new aDataAdminLIST[DATA_ADMIN_LIST];
    ArrayGetArray(g_aAdminList, g_iRight[id], aDataAdminLIST);
    get_user_name(Target[id], Player, charsmax(Player));
    new szMenu[512], iLen = 0, iKeys = (1<<2|1<<3|1<<4|1<<9);

    iLen = formatex(szMenu, charsmax(szMenu), "\yМеню Выдачи Привилегий \r[\dПодтверждение\r]^n\r[\y#\r]\w Ник:\y%s^n", Player);
    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Привилегия:\y%s^n", id, "MENU_KEY_1", aDataAdminLIST[RIGHT]);
    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Пароль:\r %s^n", id, "MENU_KEY_2", szPassword[id]);
    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Срок:\y%d дней^n^n", id, "MENU_KEY_3", g_szTime[g_Time[id]]);
    
    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Подтвердить^n", id, "MENU_KEY_4");
    iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L\w Отменить^n", id, "MENU_KEY_5");
    formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n%L\w Выход", id, "MENU_KEY_0");
    return show_menu(id, iKeys, szMenu, -1, "Show_ConfirmMenu");
}

public Handle_ConfirmMenu(id, iKey)
{
    new aDataAdminLIST[DATA_ADMIN_LIST];
    ArrayGetArray(g_aAdminList, g_iRight[id], aDataAdminLIST);
    get_user_name(id, Admin, charsmax(Admin));
    get_user_name(Target[id], Player, charsmax(Player));
    switch(iKey)
    {
        case 2:
        {
            ++g_Time[id]
            if(g_Time[id] >= 5) g_Time[id] = 0
            return Show_ConfirmMenu(id);
        }
        case 3:
        {
            if(get_pcvar_num(type_admin_right) == 1)
            {
                for(szLine = 0; read_file(g_LoadList, szLine, szParse, charsmax( szParse ), szNum); szLine++)
                {
                    if(szNum > 0 && szParse[0] != ';')
                    {
                        parse(szParse, szParseUser, charsmax(szParseUser));
                        if(equal(Player, szParseUser))
                        {
                            formatex(szBlock, charsmax(szBlock), ";%s", szParse);
                            write_file(g_LoadList, szBlock, szLine);
                        }
                    }
                }
                
                remove_user_flags(Target[id], read_flags("abcdefghijklmnopqrstuz"));
                set_user_flags(Target[id], read_flags(aDataAdminLIST[FLAGS]));
                formatex(szBlock, charsmax(szBlock), "^"%s^" ^"%s^" ^"%s^" ^"a^" ^"%d^"", Admin, szPassword[id], aDataAdminLIST[FLAGS], g_szTime[g_Time[id]])
                write_file(g_LoadList, szBlock, -1);
                server_cmd("amx_reloadadmins");
                ColorChat(0, "%L!y Создатель !t%s !yвыдал игроку!t %s!y -!g %s!y.", id, "PREFIX_CHAT", Admin, Player, aDataAdminLIST[RIGHT]);
            }
        }
        case 4: return PLUGIN_HANDLED;
    }
    return PLUGIN_HANDLED;
}

stock ColorChat(const id, const input[], any:...)
{
    new count = 1, players[32]
    static msg[191]
    vformat(msg, 190, input, 3)
    
    replace_all(msg, 190, "!g", "^4")
    replace_all(msg, 190, "!y", "^1")
    replace_all(msg, 190, "!t", "^3")
    
    if(id) players[0] = id; else get_players(players, count, "ch")
    {
        for (new i = 0; i < count; i++)
        {
            if (is_user_connected(players[i]))
            {
                message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i]);
                write_byte(players[i]);
                write_string(msg);
                message_end();
            }
        }
    }
}

RedGamer · 2 Апр 2023

C++:

Show_PlayerMenu(id, iPos)
{
    if (iPos == -1) {
        return PLUGIN_CONTINUE;
    }
    
    new iPlayersNum;
    for(new i = 1; i <= get_maxplayers(); i++)
    {
        if(!is_user_connected(i))
            continue;
        
        g_iMenuPlayers[id][iPlayersNum++] = i;
    }
    new iStart = iPos * PLAYERS_PER_PAGE;
    if(iStart > iPlayersNum) iStart = iPlayersNum;
    iStart = iStart - (iStart % PLAYERS_PER_PAGE);
    g_iMenuPosition[id] = iStart / PLAYERS_PER_PAGE;
    new iEnd = iStart + PLAYERS_PER_PAGE;
    if(iEnd > iPlayersNum) iEnd = iPlayersNum;
    new szMenu[512], iLen, iPagesNum = (iPlayersNum / PLAYERS_PER_PAGE + ((iPlayersNum % PLAYERS_PER_PAGE) ? 1 : 0));
    switch(iPagesNum)
    {
        case 0:
        {
            ColorChat(id, "%L!y Нету игроков!", id, "PREFIX_CHAT");
            return PLUGIN_HANDLED;
        }
        default: iLen = formatex(szMenu, charsmax(szMenu), "\yВыберите игрока^n^n", iPos + 1, iPagesNum);
    }
    new szName[32], i, iKeys = (1<<9), b;
    for(new a = iStart; a < iEnd; a++)
    {
        i = g_iMenuPlayers[id][a];
        get_user_name(i, szName, charsmax(szName));
        if(i != id)
        {
            iKeys |= (1<<b);
            iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L \w%s^n", id, "MENU_KEY_DEFAULT", ++b, szName);
        }
        else iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "%L \d%s \r[\yЭто вы\r]^n", id, "MENU_KEY_DEFAULT", ++b, szName);
    }
    for(new i = b; i < 8; i++) iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n");
    if(iEnd < iPlayersNum)
    {
        iKeys |= (1<<8);
        formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n%L \wДальше^n%L \w%s", id, "MENU_KEY_9", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    }
    else formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n^n%L \w%s", id, "MENU_KEY_0", iPos ? "Назад" : "Выход");
    return show_menu(id, iKeys, szMenu, -1, "Show_PlayerMenu");
}

if (iPos == -1) {
return PLUGIN_CONTINUE;
}

Спасибо, Javekson )))

Алексеич · 3 Апр 2023

RedGamer, а решение вопроса отметил свой пост с чужим кодом? Нормально))))

Плагин Admin Gift

RedGamer

Javekson

RedGamer

Javekson

RedGamer

Алексеич

Пользователи, просматривающие эту тему