Killa Hp

Mizer · 30 Авг 2022

Плагин работает криво, место брони он показывает сколько осталось жизни как его исправить.

b0t. · 30 Авг 2022

Код:

#include <amxmodx>
#include <reapi> 
//#define NOT_ALIVE    // Использовать /me может только МЕРТВЫЙ игрок. Чтобы разрешить всем пользоваться, закомментируйте;)
#define INFO_KILLER    // Информация /me и /hp после смерти игрока
//#define NO_ROUND    // Поддержка бесконечного раунда.
enum _:info
{
    damage,
    lasthit,
    killerid,
    killername[32],
    Float:hpkiller,
    Float:apkiller,
    Float:distance
}
new g_iPlayerData[MAX_PLAYERS+1][info];
new g_iVOrigin[3], g_iKOrigin[3];
new const g_szHitPlaces[][] = { "-", "голову", "грудь", "живот", "левую руку", "правую руку", "левую ногу", "правую ногу" };
public plugin_init()
{
    register_plugin("Say me and Say hp", "1.4", "neygomon");    
    register_event("Damage", "eventDamage", "b", "2!0");    
#if defined NO_ROUND
    RegisterHookChain(RG_CBasePlayer_Spawn, "fwdPlayerSpawn", true) 
#else
    register_event("HLTV",     "eventRoundStart", "a", "1=0", "2=0");
#endif
    RegisterHookChain(RG_CBasePlayer_Killed, "fwdPlayerKilled", true) 
    register_clcmd("say /me",     "ClCmdSayMe");
    register_clcmd("say_team /me",     "ClCmdSayMe");
    register_clcmd("say /hp",     "ClCmdSayHp");
    register_clcmd("say_team /hp",     "ClCmdSayHp");
}
public client_putinserver(id)
{
    arrayset(g_iPlayerData[id], 0, info);  
}
#if defined NO_ROUND
public fwdPlayerSpawn(const id)
{
    arrayset(g_iPlayerData[id], 0, info);
}
#else
public eventRoundStart()
{
    for(new i = 1; i <= MAX_PLAYERS; i++)
    {
        arrayset(g_iPlayerData[i], 0, info);   
    }
}
#endif
public eventDamage(id)
{
    static attacker, hit; attacker = get_user_attacker(id, 0, hit);
    if(id != attacker && 1 <= attacker <= MAX_PLAYERS)
    {
        g_iPlayerData[attacker][damage] += read_data(2);
        g_iPlayerData[attacker][lasthit] = hit;
    }    
}
public fwdPlayerKilled(pVictim, pKiller)
{
    if(pVictim == pKiller || !is_user_connected(pKiller) || !is_user_connected(pVictim))
        return;
    
    get_user_origin(pVictim, g_iVOrigin);
    get_user_origin(pKiller, g_iKOrigin);   
                               
    g_iPlayerData[pVictim][hpkiller] = get_entvar(pKiller, var_health);
    g_iPlayerData[pVictim][apkiller] = get_entvar(pKiller, var_armorvalue);
    g_iPlayerData[pVictim][distance] = get_distance(g_iKOrigin, g_iVOrigin) * 0.0254;
 
    g_iPlayerData[pVictim][killerid] = pKiller;
    get_user_name(pKiller, g_iPlayerData[pVictim][killername], charsmax(g_iPlayerData[][killername]));
#if defined INFO_KILLER
    new pKilledByBomb = get_member(pVictim, m_bKilledByBomb);
    if(g_iPlayerData[pVictim][killerid] != 0 && !pKilledByBomb)
        ClCmdSayHp(pVictim);
    if(g_iPlayerData[pVictim][damage] != 0)
        ClCmdSayMe(pVictim);
#endif 
}
public ClCmdSayMe(id)
{
#if defined NOT_ALIVE
    if(is_user_alive(id))
    {
        client_print_color(id, -2, "^4*^1Данная функция ^1доступна ^1только ^1мертвым игрокам^1!"); 
        return PLUGIN_HANDLED;                 
    }    
#endif
    switch(g_iPlayerData[id][damage])
    {
        case 0:client_print_color(id, -2, "^4*^1Вы ни в кого ^1не попали^1.");
        default:client_print_color(id, -2, "^4*^1Вы нанесли ^4%d]^1 урона. Последнее попадание в ^4%s^1.", g_iPlayerData[id][damage], g_szHitPlaces[g_iPlayerData[id][lasthit]]);
    }    
    return PLUGIN_HANDLED;    
}
public ClCmdSayHp(id)
{
    switch(g_iPlayerData[id][killerid])
    {
        case 0:client_print_color(id, -2, "^4*^1Вас ^1никто ^1не убивал^1.");     
        default:client_print_color(id, -2, "^4*^1Вас убил: ^1[^4%s^1]^1 [^4%.0f^1HP, ^4%.0f^1AP^1] ^1с расстояния ^1%.0f^1 метров^1.", g_iPlayerData[id][killername],g_iPlayerData[id][hpkiller], g_iPlayerData[id][apkiller],g_iPlayerData[id][distance]);     
    }
    return PLUGIN_HANDLED;
}

Killa Hp

Mizer

Вложения

b0t.

Вложения

Пользователи, просматривающие эту тему