Увеличить урон при попадании в голову

[XyLiGaN]

Javekson, Ну по поводу попаданий, чисто в голову, то это чисто только так.

#include <amxmodx>
#include <fakemeta>
#include <reapi>

public plugin_init()
{
    register_plugin("Only HS", "0.1", "unnamed")
    RegisterHookChain(RG_CBasePlayer_TraceAttack, "CBasePlayer_TraceAttack_Pre")
}

public CBasePlayer_TraceAttack_Pre(victim, attacker, Float:dmg, Float:dir[3], tr, dmgbit)
{
    return (get_tr2(tr, TR_iHitgroup) != HIT_HEAD) ? HC_BREAK : HC_CONTINUE
}

 

[DEVV]

Я пробовал

Спойлер: так

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN      "DAMAGE FACTOR"
#define VERSION     "0.2"
#define AUTHOR      "DEVV"

public plugin_init()
{
        register_plugin(PLUGIN, VERSION, AUTHOR);
        RegisterHam(Ham_TraceAttack, "player", "Forward_TraceAttack");
}

public Forward_TraceAttack(id, attacker, Float:dmg, Float:dir[3], tr, dmgbit)
{
        if(get_tr2(tr, TR_iHitgroup) == HIT_HEAD)
            if(get_user_weapon(attacker) == CSW_KNIFE)
                SetHamParamFloat(4, dmg * 6);
}

в том числе и варианты с выше. Есть какой ни будь другой способ изменить демедж?

 

[bizon]

DEVV, в чём проблемы с двумя предоставленными вариантами?

 

[DEVV]

bizon

в чём проблемы с двумя предоставленными вариантами?

ваши варианты оба работают, но урон не могу увеличить

 

[bizon]

DEVV, касательно этого кода:

public Forward_TraceAttack(id, attacker, Float:dmg, Float:dir[3], tr, dmgbit)
{
        if(get_tr2(tr, TR_iHitgroup) == HIT_HEAD)
            if(get_user_weapon(attacker) == CSW_KNIFE)
                SetHamParamFloat(4, dmg * 6);
}

Здесь урон - 3 аргумент функции, а не 4.

SetHamParamFloat(4, dmg * 6);

->

SetHamParamFloat(3, dmg * 6);

 

[ImmortalAmxx]

#include <AmxModX>
#include <ReAPI>

public plugin_init() {
    RegisterHookChain(RG_CBasePlayer_TakeDamage, "@CBasePlayer_TakeDamage_Pre", .post = false);
}

@CBasePlayer_TakeDamage_Pre(pVictim, iIflictor, pAttacker, Float:flDamage, iBits) {
    new iActiveItem = get_member(pAttacker, m_pActiveItem);
        
    if(get_member(pVictim, m_LastHitGroup) == HIT_HEAD && get_member(iActiveItem, m_iId) == CSW_KNIFE) {
        SetHookChainArg(4, ATYPE_FLOAT, flDamage * 10.0);
    }
}

Держи, все работает как нужно, проверял.

 

[DEVV]

Спасибо огромное bizon ImmortalAmxx Komap и другим участникам форума которые помогли. Проблема решена.

DEVV, касательно этого кода:

public Forward_TraceAttack(id, attacker, Float:dmg, Float:dir[3], tr, dmgbit)
{
        if(get_tr2(tr, TR_iHitgroup) == HIT_HEAD)
            if(get_user_weapon(attacker) == CSW_KNIFE)
                SetHamParamFloat(4, dmg * 6);
}

Здесь урон - 3 аргумент функции, а не 4.

SetHamParamFloat(4, dmg * 6);

->

SetHamParamFloat(3, dmg * 6);

Действительно, после этого всё заработало. Спасибо!

#include <AmxModX>
#include <ReAPI>

public plugin_init() {
    RegisterHookChain(RG_CBasePlayer_TakeDamage, "@CBasePlayer_TakeDamage_Pre", .post = false);
}

@CBasePlayer_TakeDamage_Pre(pVictim, iIflictor, pAttacker, Float:flDamage, iBits) {
    new iActiveItem = get_member(pAttacker, m_pActiveItem);
     
    if(get_member(pVictim, m_LastHitGroup) == HIT_HEAD && get_member(iActiveItem, m_iId) == CSW_KNIFE) {
        SetHookChainArg(4, ATYPE_FLOAT, flDamage * 10.0);
    }
}

Держи, все работает как нужно, проверял.

Пробовал тоже, всё работает. Спасибо!