Банк с подключением в бд

SanSannech · 21 Апр 2022

Помогите решить в чем проблема почему такое иногда бывает!

Код:

L 04/18/2022 - 19:10:23: [MySQL] Invalid info tuple handle: 0
L 04/18/2022 - 19:10:23: [AMXX] Displaying debug trace (plugin "test.amxx", version "1.2")
L 04/18/2022 - 19:10:23: [AMXX] Run time error 10: native error (native "SQL_ThreadQuery")
L 04/18/2022 - 19:10:23: [AMXX]    [0] test.sma::Save_Money (line 165)
L 04/18/2022 - 19:10:23: [AMXX]    [1] test.sma::client_disconnected (line 35)

Nordic Warrior · 21 Апр 2022

Скрытое содержимое для пользователей: SanSannech

Nordic Warrior · 21 Апр 2022

Предоставьте верный исходник.

L 04/18/2022 - 19:10:23: [AMXX] Run time error 10: native error (native "SQL_ThreadQuery")
L 04/18/2022 - 19:10:23: [AMXX] [0] test.sma::Save_Money (line 165)

На этой строке в исходнике нет указанной функции.

SanSannech · 21 Апр 2022

Nordic Warrior,Я вам дал тот что и сам использую

21 Апр 2022

Nordic Warrior,

Код:

#include <amxmodx>
#include <cstrike>
#include <sqlx>

enum _:ques { INSTALL_PLUGIN, LOAD_MONEY, SAVE_MONEY, INSERT_MONEY };
new Handle:g_sql, data[2], szQuery[512];

enum DATA { STATUSLOAD, STEAMID[24], MONEY };
new g_iPlayerData[33][DATA];
new bool:g_bIgnoreClient[33];

new g_iRoundCount;

public plugin_init()
{
#define VERSION "1.2"
    register_plugin("CS Bank", VERSION, "neygomon");
    register_cvar("bk_neygomon", VERSION, FCVAR_SERVER | FCVAR_SPONLY);
    
    register_event("TextMsg", "eRestart", "a", "2&#Game_C", "2&#Game_w");
    register_event("HLTV", "eRoundStart", "a", "1=0", "2=0");
    
    set_task(3.0, "ShowMoney", .flags = "b");
    set_task(1.5, "SQL_Init");
}

public client_putinserver(id)
{
    if(is_user_bot(id) || is_user_hltv(id))
        return g_bIgnoreClient[id] = true;
    
    g_iPlayerData[id][MONEY] = 0;
    return Load_Money(id);
}

public client_disconnect(id)
{
    if(!g_bIgnoreClient[id])
        Save_Money(id);
}

public eRestart()
    g_iRoundCount = 0;

public eRoundStart()
    g_iRoundCount++;   

public ShowMoney()
{
    if(g_iRoundCount < 3)
        return;
    
    static id, iMoney[33], players[32], pnum;
    get_players(players, pnum, "ach");
    for(new i; i < pnum; i++)
    {
        id = players[i]; iMoney[id] = cs_get_user_money(id);
        if(iMoney[id] > 10000)
        {
            new InBank = iMoney[id] - 10000;
            g_iPlayerData[id][MONEY] += InBank;
            cs_set_user_money(id, 10000);
        }
        else
        {
            if(g_iPlayerData[id][MONEY] < 10000 - iMoney[id])
            {
                cs_set_user_money(id, iMoney[id] + g_iPlayerData[id][MONEY]);
                g_iPlayerData[id][MONEY] = 0;
            }
            else
            {
                g_iPlayerData[id][MONEY] -= 10000 - iMoney[id];
                cs_set_user_money(id, 10000);
            }
        }
        set_hudmessage(0, 255, 0, 0.7, 0.87, 0, 6.0, 3.1, 0.1, 0.2, -1)
        show_hudmessage(id, "В Вашем банке %d $", g_iPlayerData[id][MONEY])
    }
}

public SQL_Init()
{   
    new g_SqlHost[32], g_SqlUser[32], g_SqlPass[32], g_SqlDb[32];
    get_cvar_string("amx_sql_host", g_SqlHost, charsmax(g_SqlHost));
    get_cvar_string("amx_sql_user", g_SqlUser, charsmax(g_SqlUser));
    get_cvar_string("amx_sql_pass", g_SqlPass, charsmax(g_SqlPass));
    get_cvar_string("amx_sql_db", g_SqlDb, charsmax(g_SqlDb));
    
    g_sql = SQL_MakeDbTuple(g_SqlHost, g_SqlUser, g_SqlPass, g_SqlDb);
    
    if(g_sql == Empty_Handle)
        set_fail_state("unable to create SQL handler");
        
    new err, error[256];
    new Handle:g_checksql = SQL_Connect(g_sql, err, error, 255);
    
    if(g_checksql == Empty_Handle)
    {
        log_amx("failed to connect to MySQL database");
        log_amx("[ %d ] %s", err, error);
        
        set_fail_state("mysql connection failed");
    }
    SQL_FreeHandle(g_checksql);
    InstallPlugin();
}

public SQL_Handler(failstate, Handle:que, err[], errcode, data[], datasize)
{
    switch(failstate)
    {
        case TQUERY_CONNECT_FAILED:
        {
            log_amx("MySQL connection failed");
            log_amx("[ %d ] %s",errcode, err);
            log_amx("Query state: %d", data[0]);
            return PLUGIN_CONTINUE;
        }
        case TQUERY_QUERY_FAILED:
        {
            log_amx("MySQL query failed");
            log_amx("[ %d ] %s", errcode, err);
            log_amx("Query state: %d", data[0]);
            return PLUGIN_CONTINUE;
        }
    }
    new id = data[1];
    switch(data[0])
    {
        case INSTALL_PLUGIN: { }
        case LOAD_MONEY:
        {
            if(SQL_NumResults(que) <= 0)
            {
                g_iPlayerData[id][STATUSLOAD] = 2;
                return PLUGIN_CONTINUE;
            }
            g_iPlayerData[id][MONEY] = SQL_ReadResult(que, 0);
            g_iPlayerData[id][STATUSLOAD] = 1;
        }
        case INSERT_MONEY:
        {
            if(SQL_AffectedRows(que) > 0)
                g_iPlayerData[id][STATUSLOAD] = 1;
        }
        case SAVE_MONEY: { }
    }
    return PLUGIN_CONTINUE;
}

InstallPlugin()
{
    data[0] = INSTALL_PLUGIN;
    formatex(szQuery, 511, "CREATE TABLE IF NOT EXISTS `cs_bank` ( `steamid` varchar(24) DEFAULT NULL, `cash` int(10) DEFAULT NULL ) ENGINE=InnoDB DEFAULT CHARSET=utf8;");
    SQL_ThreadQuery(g_sql, "SQL_Handler", szQuery, data, 2);
}   

Load_Money(id)
{
    data[0] = LOAD_MONEY; data[1] = id;
    get_user_authid(id, g_iPlayerData[id][STEAMID], charsmax(g_iPlayerData[][STEAMID]));
    
    formatex(szQuery, 511, "SELECT `cash` FROM `cs_bank` WHERE `steamid` = '%s'", g_iPlayerData[id][STEAMID]);
    return SQL_ThreadQuery(g_sql, "SQL_Handler", szQuery, data, 2);
}

Save_Money(id)
{
    switch(g_iPlayerData[id][STATUSLOAD])
    {
        case 1:
        {
            data[0] = SAVE_MONEY;
            formatex(szQuery, 511, "UPDATE `cs_bank` SET `cash` = '%d' WHERE `steamid` = '%s'", g_iPlayerData[id][MONEY], g_iPlayerData[id][STEAMID]);
        }
        case 2:
        {
            data[0] = INSERT_MONEY;
            formatex(szQuery, 511, "INSERT INTO `cs_bank` (`steamid`, `cash`) VALUES('%s', '%d')", g_iPlayerData[id][STEAMID], g_iPlayerData[id][MONEY]);
        }
    }
    data[1] = id; SQL_ThreadQuery(g_sql, "SQL_Handler", szQuery, data, 2);
}

TehGaia · 21 Апр 2022

Всё там на месте, разве что смущает client_disconnect в коде, и client_disconnected в логе. Видимо компилятор сам подменяет, выругивая предупреждение.

Код:

Invalid info tuple handle: 0

вот тут проблема, которая говорит что соединение было, но запрос не прошел по какой-то причине. Можно попробовать к

Код:

SELECT `cash` FROM `cs_bank` WHERE `steamid` = '%s'

дописать LIMIT 1, чтобы исключить дубли, но нет гарантий что это поможет)

SanSannech · 25 Апр 2022

@TehGaia,Я не совсем понял про LIMIT 1, как это?

ImmortalAmxx · 16 Май 2022

SanSannech, LIMIT выводит указанное кол-во строк, к примеру
SELECT * FROM Tabel.Name LIMIT 2, выводит из указанной таблицы 2 первых ячейки.

Limbooc · 19 Май 2022

покажите саму таблицу или задампите его сюда

SanSannech · 20 Окт 2023

можно закрывать

Алексеич · 20 Окт 2023

SanSannech, решение....?

SanSannech · 20 Окт 2023

@Алексеич,Решение тут нет, нашел другой способ.

kto-to · 20 Окт 2023

SanSannech, Дак поделись решением то с другими, раз нашёл.

SanSannech · 20 Окт 2023

kto-to,тема уже не актуальна, уже всё заменил на другое.

mlibre · 21 Окт 2023

SanSannech, и у этой вещи есть имя или нет

SanSannech · 22 Окт 2023

@Алексеич,Решение было в

Код:

public SQL_Init()
{
    то что оставил.
    g_sql = SQL_MakeDbTuple("localhost", "bazame", "passme", "bazame", MaxClients);

ну и конечно ост код после g_sql
  
}

Я просто указал соединение к бд сразу, а не через amx sql которая

Банк с подключением в бд

SanSannech

Вложения

Nordic Warrior

Nordic Warrior

SanSannech

TehGaia

SanSannech

ImmortalAmxx

Limbooc

SanSannech

Алексеич

SanSannech

kto-to

SanSannech

mlibre

SanSannech

Пользователи, просматривающие эту тему