Помогите поправить код в aes_informer

Статус
В этой теме нельзя размещать новые ответы.
Сообщения
14
Реакции
-1
Ошибка
Нет ошибок в логах
ОС
Linux
Amx Mod X
AMX Mod X 1.9.0.5294 (http://www.amxmodx.org)
Authors:
David "BAILOPAN" Anderson, Pavol "PM OnoTo" Marko
Felix "SniperBeamer" Geyer, Jonny "Got His Gun" Bergstrom
Lukasz "SidLuke" Wlasinski, Christian "Basic-Master" Hammacher
Borja "faluco" Ferrer, Scott "DS" Ehlert
Compiled: Dec 3 2021 15:54:56
Built from: https://github.com/alliedmodders/amxmodx/commit/363871a
Build ID: 5294:363871a
Core mode: JIT+ASM32
Билд
Protocol version 48
Exe version 1.1.2.7/Stdio (cstrike)
ReHLDS version: 3.11.0.767-dev
Build date: 03:13:55 Oct 25 2021 (2753)
Build from: https://github.com/dreamstalker/rehlds/commit/471158b
ReGamedll
ReGameDLL version: 5.21.0.540-dev
Build date: 17:33:16 Oct 25 2021
Build from: https://github.com/s1lentq/ReGameDLL_CS/commit/b9cccc6
Версия Metamod
Metamod-r v1.3.0.128, API (5:13)
Metamod-r build: 17:47:54 Aug 24 2018
Metamod-r from: https://github.com/theAsmodai/metamod-r/commit/0cf2f70
Список метамодулей
description      stat pend  file                      vers             src  load  unload
[ 1] Reunion RUN - reunion.so v0.1.92d ini Start Never
[ 2] VoiceTranscoder RUN - VoiceTranscoder.so v2017RC5 ini ANY ANY
[ 3] AMX Mod X RUN - amxmodx.so v1.9.0.5294 ini Start ANY
[ 4] ReAuthCheck RUN - reauthcheck.so v0.1.6 ini Start Never
[ 5] Rechecker RUN - rechecker.so v2.7 ini Chlvl ANY
[ 6] ReSemiclip RUN - resemiclip.so v2.3.9 ini Chlvl ANY
[ 7] ReSRDetector RUN - resrdetector.so v0.1.0 ini Chlvl ANY
[ 8] SafeNameAndChat RUN - SafeNameAndChat.so v1.1 ini ANY ANY
[ 9] WHBlocker RUN - whblocker.so v1.5.697 ini Chlvl ANY
[10] YaPB RUN - yapb.so v4.2.598 ini Chlvl ANY
[11] CStrike RUN - cstrike_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[12] CSX RUN - csx_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[13] MySQL RUN - mysql_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[14] SQLite RUN - sqlite_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[15] ReAPI RUN - reapi_amxx_i386.so v5.21.0.248-dev pl3 ANY Never
[16] FakeMeta RUN - fakemeta_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[17] Ham Sandwich RUN - hamsandwich_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[18] Fun RUN - fun_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
[19] Engine RUN - engine_amxx_i386.so v1.9.0.5294 pl3 ANY ANY
19 plugins, 19 running
Список плагинов
[  1] GameCMS_GagManager      2.2.7 ReAp  zhorzh78          gamecms_gagmana  running
[ 2] GameCMS_API 5.5.3 zhorzh78 gamecms_api.amx running
[ 3] CSStatsX SQL 0.7.4+2 serfreeman1337 aes_csstatsx_sq running
[ 4] WebHS 0.1 kanagava fb_web_online.a running
[ 5] FreshBans 1.4.5b kanagava fresh_bans.amxx running
[ 6] Admin Commands 1.9.0.5294 AMXX Dev Team admincmd.amxx running
[ 7] Slots Reservation 1.9.0.5294 AMXX Dev Team adminslots.amxx running
[ 8] Menus Front-End 1.9.0.5294 AMXX Dev Team menufront.amxx running
[ 9] Commands Menu 1.9.0.5294 AMXX Dev Team cmdmenu.amxx running
[ 10] Players Menu 1.9.0.5271 AMXX Dev Team plmenu.amxx running
[ 11] Maps Menu 1.0 O.Hooligan mapsmenu.amxx running
[ 12] Plugin Menu 1.9.0.5294 AMXX Dev Team pluginmenu.amxx running
[ 13] Admin Chat 1.9.0.5294 AMXX Dev Team adminchat.amxx running
[ 14] Scrolling Message 1.9.0.5294 AMXX Dev Team scrollmsg.amxx running
[ 15] Info. Messages 1.9.0.5294 AMXX Dev Team imessage.amxx running
[ 16] Admin Votes 1.9.0.5294 AMXX Dev Team adminvote.amxx running
[ 17] TimeLeft 1.9.0.5294 AMXX Dev Team timeleft.amxx running
[ 18] Pause Plugins 1.9.0.5294 AMXX Dev Team pausecfg.amxx running
[ 19] Stats Configuration 1.9.0.5294 AMXX Dev Team statscfg.amxx running
[ 20] AES: StatsX 0.5.9 [REA serfreeman1337/s aes_statsx.amxx running
[ 21] StatsX 1.9.0.5294 AMXX Dev Team statsx.amxx running
[ 22] GameCMS_VipTest 3.8.1 zhorzh78 gamecms_viptest running
[ 23] GameCMS BonusSystem 1.1 +- DUKKHAZ0R gamecms_bonus.a running
[ 24] [GameCMS] Real Money R 1.0 InKay gamecms_bets.am running
[ 25] Hooligan VoteBan 1.4 O.Hooligan hooligan_voteba running
[ 26] Kill Assist 1.17 O.Hooligan hooligan_kill_a running
[ 27] Hooligan Vampire 1.2 O.Hooligan hooligan_vampir running
[ 28] Ping Control 1.31 O.Hooligan hooligan_ping.a running
[ 29] Lite Translit 2.8 neygomon hooligan_transl running
[ 30] Knife Duel 1.2 O.Hooligan hooligan_duel.a running
[ 31] Nice Voice 2.0 R sector hooligan_voice. running
[ 32] Advanced MapChooser 1.1.1 O.Hooligan hooligan_map_ch running
[ 33] VIP 1.5 O.Hooligan hooligan_vipmen running
[ 34] Menu 1.0 O.Hooligan hooligan_menu.a running
[ 35] Menu 1.0 O.Hooligan hooligan_cabine running
[ 36] Menu 1.0 O.Hooligan hooligan_menupr running
[ 37] AmxModMenu 1.2 O.Hooligan hooligan_adminm running
[ 38] Knife Manager 0.3 O.Hooligan hooligan_knife_ running
[ 39] unknown unknown unknown hooligan_teamba bad load
[ 40] Warn Menu 0.1 O.Hooligan hooligan_warn_m running
[ 41] GreetingMenu 1.0 O.Hooligan hooligan_ng.amx running
[ 42] Random Weapons WarmUP 2.4.1 O.Hooligan hooligan_razmin running
[ 43] Damager 0.0.5 steelzzz hooligan_damage running
[ 44] Free ammo 1.4 O.Hooligan hooligan_ammo.a running
[ 45] coin 1.0 O.Hooligan hooligan_coin.a running
[ 46] Flags 1.1 O.Hooligan hooligan_flags. running
[ 47] CMS_GM_Sorry_Addon 1.0 sorry.amxx running
[ 48] Reset Score 0.2 Silenttt / CepeH rs.amxx running
[ 49] Parachute 1.0 maeStro parachute.amxx running
[ 50] lite screen fade 1.0 AcE lite_screen_fad running
[ 51] kill_knife_money 1.0 IntelCom knife_kill_mone running
[ 52] [ReAPI] Healthnade 0.0.2 F@nt0M reapi_healthnad running
[ 53] Killa HP 1.6 jas0n killa_hp.amxx running
[ 54] User Connect 0.1.1 Jumper connect_priv.am running
[ 55] Ultimate KillStreak Ad 0.7 SAMURAI ut_killstreak_a running
[ 56] [190] AC Spectator ESP 20.06.06 SKAJIbnEJIb & Ko ac_esp.amxx running
[ 57] Autoresponder/Advertis 0.5 MaximusBrood reklama_in_chat running
[ 58] Block Name Spam 0.1 s1lent block_name_spam running
[ 59] XMAS Skybox 1.0 SeMax xmas_sky.amxx running
[ 60] [ReAPI] AWPoff 1.4.3 PAffAEJIkA :3 awp_off.amxx running
[ 61] [ReAPI] No Team Flash 0.0.2 Vaqtincha no_team_flash.a running
[ 62] Afk Control 0.5.1 neygomon afk_control.amx running
[ 63] AES: StatsX Info Rank 0.1 serfreeman1337 aes_statsx_info running
[ 64] AES: Status Info 0.1 serfreeman1337 aes_status_info running
[ 65] DemoRecoder 1.1 neygomon demka.amxx running
[ 66] SITE 1.0 O.Hooligan site.amxx running
[ 67] Block grande info 1.0 O.Hooligan BlockGrenadeInf running
[ 68] Top Round Damage 1.0.4 ReAP Dager* *.* -G- top_damage.amxx running
[ 69] [ReAPI] Custom Models 1.6.1 neugomon custom_models.a running
[ 70] Santa Hat + Snow 1.3 xPaw SantaHat.amxx running
[ 71] CSS Bomb 0.0.1 Vaqtincha c4_ng.amxx running
[ 72] NY Kill Sprite 1.0 O.Hooligan ng_sprite.amxx running
[ 73] Advanced Experience Sy 0.5.9 [REA serfreeman1337/s aes_main.amxx running
[ 74] AES: CStrike Addon 0.5.9 [REA serfreeman1337/s aes_exp_cstrike running
[ 75] AES: Informer 0.5 Vega serfreeman1337 aes_informer.am running
[ 76] AES: Admin Tools 0.5.9 [REA serfreeman1337/s aes_exp_editor. running
[ 77] AES: Bonus System 0.5.9 Vega serfreeman1337/s aes_bonus_syste running
[ 78] AES: Bonus CSTRIKE 0.5.9.1 [R serfreeman1337/s aes_bonus_cstri running
78 plugins, 77 running
Автор плагина
serfreeman1337
Версия плагина
0.5 Vega
Исходный код
#include <amxmodx>
#include <amxmisc>

#include <engine>

#if AMXX_VERSION_NUM < 183
#include <colorchat>

#define print_team_default DontChange
#define print_team_grey Grey
#define print_team_red Red
#define print_team_blue Blue

#define MAX_NAME_LENGTH 32
#define MAX_PLAYERS 32

#define client_disconnected client_disconnect
#endif

#include <aes_v>
#include <csstatsx_sql>

#define PLUGIN "AES: Informer"
#define VERSION "0.5 Vega"
#define AUTHOR "serfreeman1337"

#define PLAYER_HUD_OFFSET 86444

/* - CVARS - */

enum _:cvars_num {
CVAR_HUD_UPDATE,
CVAR_HUD_INFO_DEFAULT,
CVAR_HUD_INFO_TYPE,
CVAR_HUD_INFO_COLOR,
CVAR_HUD_INFO_POS,
CVAR_HUD_INFO_TYPE_D,
CVAR_HUD_INFO_COLOR_D,
CVAR_HUD_INFO_POS_D,
CVAR_TPL_MODE,
CVAR_HUD_ANEW_TYPE,
CVAR_HUD_ANEW_POS,
CVAR_HUD_ANEW_COLOR,
CVAR_CHAT_NEW_LEVEL
}
new const g_skill_letters[][] = {
"L-",
"L",
"L+",
"M-",
"M",
"M+",
"H-",
"H",
"H+",
"P-",
"P",
"P+",
"G"
}
new Float:g_skill_opt[sizeof g_skill_letters]

new g_cvar_skill

new cvar[cvars_num]

/* - CACHED VALUES - */

// кеш от души
new Float:hudUpdateInterval
new bool:hudInfoOn, Float:hudInfoxPos,Float:hudInfoyPos,hudInfoColor[3],bool:hudInfoColorRandom
new bool:hudDeadOn, Float:hudDeadxPos, Float:hudDeadyPos,hudDeadColor[3],bool:hudDeadColorRandom
new bool:hudaNewOn, Float:hudaNewxPos,Float:hudaNewyPos,hudaNewColor[3]
new chatLvlUpStyle,bonusEnabledPointer,bool:isTplMode,aesMaxLevel,g_trackmode
new playerLevel[33][64],playerWatchLevel[33]

/* - SYNC HUD OBJ - */
new informerSyncObj,aNewSyncObj

/* - FILE STORAGE - */

new Trie:g_DisabledInformer

#if AMXX_VERSION_NUM < 183
new Array:g_ADisabledInformer
#endif

enum _:tplInfo {
INF_EXP,
INF_LEVELEXP,
INF_NEEDEXP,
INF_LEVEL,
INF_MAXLEVEL,
INF_RANK,
INF_NAME,
INF_STEAMID,
INF_BONUS,

INF_EXF,
INF_LXF,
INF_NXF
}

new const tplKeys[tplInfo][] = {
"<exp>",
"<levelexp>",
"<needexp>",
"<level>",
"<maxlevel>",
"<rank>",
"<name>",
"<steamid>",
"<bonus>",

"<exf>",
"<lxf>",
"<nxf>"
}

enum _:tplVario {
TPL_INF,
TPL_INF_D,
TPL_UP,
TPL_UP_ALL
}

new tplBitSum[tplVario]

new const teamColor[] = {
print_team_grey,
print_team_red,
print_team_blue
}

public plugin_init(){
register_plugin(PLUGIN, VERSION, AUTHOR)

cvar[CVAR_TPL_MODE] = register_cvar("aes_informer_tpl","0")
cvar[CVAR_HUD_UPDATE] = register_cvar("aes_hud_update","1.5")
cvar[CVAR_HUD_INFO_DEFAULT] = register_cvar("aes_hud_info_default","1")
cvar[CVAR_HUD_INFO_TYPE] = register_cvar("aes_hud_info_type","1")
cvar[CVAR_HUD_INFO_COLOR] = register_cvar("aes_hud_info_color","100 100 100")
cvar[CVAR_HUD_INFO_POS] = register_cvar("aes_hud_info_pos","0.01 0.13")
cvar[CVAR_HUD_ANEW_TYPE] = register_cvar("aes_hud_anew_type","1")
cvar[CVAR_HUD_ANEW_COLOR] = register_cvar("aes_hud_anew_color","100 100 100")
cvar[CVAR_HUD_ANEW_POS] = register_cvar("aes_hud_anew_pos","-1.0 0.90")
cvar[CVAR_CHAT_NEW_LEVEL] = register_cvar("aes_newlevel_chat","2")

cvar[CVAR_HUD_INFO_TYPE_D] = register_cvar("aes_hud_info_default_d","1")
cvar[CVAR_HUD_INFO_COLOR_D] = register_cvar("aes_hud_info_color_d","60 60 60")
cvar[CVAR_HUD_INFO_POS_D] = register_cvar("aes_hud_info_pos_d","0.01 0.15")

g_cvar_skill = register_cvar("aes_statsx_skill","60.0 75.0 85.0 100.0 115.0 130.0 140.0 150.0 165.0 180.0 195.0 210.0")

register_clcmd("say /aenable","Informer_Switch",0,"- switch experience informer on/off")
}

public plugin_cfg(){
new levelString[512], stPos, ePos, rawPoint[20], cnt
get_pcvar_string(g_cvar_skill, levelString, charsmax(levelString))

// парсер значений для скилла
do {
ePos = strfind(levelString[stPos], " ")

formatex(rawPoint, ePos, levelString[stPos])
g_skill_opt[cnt] = str_to_float(rawPoint)

stPos += ePos + 1

cnt++

// narkoman wole suka
if(cnt > charsmax(g_skill_letters))
break
} while (ePos != -1)

bonusEnabledPointer = get_cvar_pointer("aes_bonus_enable")

hudUpdateInterval = get_pcvar_float(cvar[CVAR_HUD_UPDATE])
hudInfoOn = get_pcvar_num(cvar[CVAR_HUD_INFO_DEFAULT]) > 0 ? true : false
hudDeadOn = get_pcvar_num(cvar[CVAR_HUD_INFO_TYPE_D]) > 0 ? true : false
hudaNewOn = get_pcvar_num(cvar[CVAR_HUD_ANEW_TYPE]) > 0 ? true : false
chatLvlUpStyle = get_pcvar_num(cvar[CVAR_CHAT_NEW_LEVEL])
isTplMode = get_pcvar_num(cvar[CVAR_TPL_MODE]) > 0 ? true : false

if(!bonusEnabledPointer)
hudaNewOn = false

new temp[15],sColor[3][6]

if(hudInfoOn){
get_pcvar_string(cvar[CVAR_HUD_INFO_COLOR],temp,14)

if(strcmp(temp,"random") != 0){
parse(temp,sColor[0],3,sColor[1],3,sColor[2],3)

hudInfoColor[0] = str_to_num(sColor[0])
hudInfoColor[1] = str_to_num(sColor[1])
hudInfoColor[2] = str_to_num(sColor[2])
}else
hudInfoColorRandom = true

get_pcvar_string(cvar[CVAR_HUD_INFO_POS],temp,14)
parse(temp,sColor[0],5,sColor[1],5)

hudInfoxPos = str_to_float(sColor[0])
hudInfoyPos = str_to_float(sColor[1])

informerSyncObj = CreateHudSyncObj()

if(isTplMode){ // sum
new tplString[256]
formatex(tplString,charsmax(tplString),"%L",LANG_SERVER,"AES_HUD_TPL")

for(new i ; i < tplInfo ; i++){
if(contain(tplString,tplKeys[i]) != -1)
tplBitSum[TPL_INF] |= (1<<i)
}
}
}

if(hudDeadOn){
get_pcvar_string(cvar[CVAR_HUD_INFO_COLOR_D],temp,14)

if(strcmp(temp,"random") != 0){
parse(temp,sColor[0],3,sColor[1],3,sColor[2],3)

hudDeadColor[0] = str_to_num(sColor[0])
hudDeadColor[1] = str_to_num(sColor[1])
hudDeadColor[2] = str_to_num(sColor[2])
}else
hudDeadColorRandom = true

get_pcvar_string(cvar[CVAR_HUD_INFO_POS_D],temp,14)
parse(temp,sColor[0],5,sColor[1],5)

hudDeadxPos = str_to_float(sColor[0])
hudDeadyPos = str_to_float(sColor[1])

if(!informerSyncObj)
informerSyncObj = CreateHudSyncObj()

if(isTplMode){ // sum
new tplString[256]
formatex(tplString,charsmax(tplString),"%L",LANG_SERVER,"AES_HUD_TPL_D")

for(new i ; i < tplInfo ; i++){
if(contain(tplString,tplKeys[i]) != -1)
tplBitSum[TPL_INF_D] |= (1<<i)
}
}
}

if(isTplMode){ // bit sum for chat notify messages
switch(chatLvlUpStyle ){
case 1:{
new tplString[256]
formatex(tplString,charsmax(tplString),"%L",LANG_SERVER,"AES_NEWLEVEL_TPL")

for(new i ; i < tplInfo ; i++){
if(contain(tplString,tplKeys[i]) != -1)
tplBitSum[TPL_UP] |= (1<<i)
}

}
case 2:{
new tplString[256]
formatex(tplString,charsmax(tplString),"%L",LANG_SERVER,"AES_NEWLEVEL_TPL")

for(new i ; i < tplInfo ; i++){
if(contain(tplString,tplKeys[i]) != -1)
tplBitSum[TPL_UP] |= (1<<i)
}

formatex(tplString,charsmax(tplString),"%L",LANG_SERVER,"AES_NEWLEVEL_ALL_TPL")

for(new i ; i < tplInfo ; i++){
if(contain(tplString,tplKeys[i]) != -1)
tplBitSum[TPL_UP_ALL] |= (1<<i)
}
}
}
}

if(hudaNewOn){
get_pcvar_string(cvar[CVAR_HUD_ANEW_COLOR],temp,14)
parse(temp,sColor[0],3,sColor[1],3,sColor[2],3)

hudaNewColor[0] = str_to_num(sColor[0])
hudaNewColor[1] = str_to_num(sColor[1])
hudaNewColor[2] = str_to_num(sColor[2])

get_pcvar_string(cvar[CVAR_HUD_ANEW_POS],temp,14)
parse(temp,sColor[0],5,sColor[1],5)

hudaNewxPos = str_to_float(sColor[0])
hudaNewyPos = str_to_float(sColor[1])

aNewSyncObj = CreateHudSyncObj()
}

aesMaxLevel = aes_get_max_level() - 1

g_trackmode = get_cvar_num("aes_track_mode")
g_DisabledInformer = TrieCreate()

#if AMXX_VERSION_NUM < 183
g_ADisabledInformer = ArrayCreate(36)
#endif

new fPath[256],len

// TODO: directory autocreate
len += get_datadir(fPath,charsmax(fPath))
len += formatex(fPath[len],charsmax(fPath) - len,"/aes/informer.ini")

new f = fopen(fPath,"r")

if(f){
new buffer[512]

while(!feof(f)){
fgets(f,buffer,511)
trim(buffer)

if(!strlen(buffer) || buffer[0] == ';')
continue

remove_quotes(buffer)

TrieSetCell(g_DisabledInformer,buffer,true)

#if AMXX_VERSION_NUM < 183
ArrayPushString(g_ADisabledInformer,buffer)
#endif
}

fclose(f)

}
}

public plugin_end(){
new fPath[256],len
len += get_datadir(fPath,charsmax(fPath))
len += formatex(fPath[len],charsmax(fPath) - len,"/aes/informer.ini")

#if AMXX_VERSION_NUM < 183
if(ArraySize(g_ADisabledInformer)){
new f = fopen(fPath,"w+")

fprintf(f,"; %s^n; by %s^n^n; Disable informer for SteamID^n",PLUGIN,AUTHOR)

new trackId[36]

for(new i ; i < ArraySize(g_ADisabledInformer) ; ++i){
ArrayGetString(g_ADisabledInformer,i,trackId,35)

if(!TrieKeyExists(g_DisabledInformer,trackId))
continue

fprintf(f,"^n^"%s^"",trackId)
}

fclose(f)
}
#else
new Snapshot:trieIterator = TrieSnapshotCreate(g_DisabledInformer)

if(TrieSnapshotLength(trieIterator)){
new f = fopen(fPath,"w+")
fprintf(f,"; %s^n; by %s^n^n; Disable informer for SteamID^n",PLUGIN,AUTHOR)

new trackId[36]

for(new i,trieSize = TrieSnapshotLength(trieIterator) ; i < trieSize ; i++){
TrieSnapshotGetKey(trieIterator,i,trackId,charsmax(trackId))
fprintf(f,"^n^"%s^"",trackId)
}

fclose(f)
}
#endif

else{
if(file_exists(fPath))
delete_file(fPath)
}

#if AMXX_VERSION_NUM >= 183
TrieSnapshotDestroy(trieIterator)
#endif
}

public Informer_Switch(id){
if(!hudInfoOn && !hudDeadOn)
return 0

new trackId[36]

if(!get_player_trackid(id,trackId,charsmax(trackId)))
return 0

if(!TrieKeyExists(g_DisabledInformer,trackId)){
TrieSetCell(g_DisabledInformer,trackId,1)

#if AMXX_VERSION_NUM < 183
if(!CheckStringInArray(g_ADisabledInformer,trackId))
ArrayPushArray(g_ADisabledInformer,trackId)
#endif

client_print_color(id,print_team_red,"%L %L",
id,"AES_TAG",id,"AES_INFORMER_DISABLED")

remove_task(PLAYER_HUD_OFFSET + id)
}else{
TrieDeleteKey(g_DisabledInformer,trackId)
set_task(hudUpdateInterval,"Show_Hud_Informer",PLAYER_HUD_OFFSET + id,.flags="b")

client_print_color(id,print_team_blue,"%L %L",
id,"AES_TAG",id,"AES_INFORMER_ENABLED")
}

return 0
}

#if AMXX_VERSION_NUM < 183
CheckStringInArray(Array:which,string[]){
new str[64]

for(new i,arrSize = ArraySize(which) ; i < arrSize ; ++i){
ArrayGetString(which,i,str,charsmax(str))

if(strcmp(string,str) == 0)
return true
}

return false
}
#endif

public client_putinserver(id){
if((hudInfoOn || hudaNewOn) && !is_user_bot(id)){
new trackId[36]
get_player_trackid(id,trackId,charsmax(trackId))

if(!TrieKeyExists(g_DisabledInformer,trackId))
set_task(hudUpdateInterval,"Show_Hud_Informer",PLAYER_HUD_OFFSET + id,.flags="b")
}
}

public client_disconnected(id){
if((hudInfoOn || hudaNewOn) &&!is_user_bot(id)){
remove_task(PLAYER_HUD_OFFSET + id)
}
}

public aes_player_levelup(id,newlevel,oldlevel){
new levelName[64]

switch(chatLvlUpStyle){
case 1: {
aes_get_level_name(newlevel,levelName,charsmax(levelName),id)

if(!isTplMode){
client_print_color(id,print_team_default,"%L %L",id,"AES_TAG",id,"AES_NEWLEVEL_ID",levelName)
}else{
new msg[191],len
tplFormatNewLevel(id,msg,len,"AES_NEWLEVEL_TPL",id,TPL_UP)

client_print_color(id,print_team_default,msg)
}
}
case 2:{
new pls[32],pnum,name[32]
get_players(pls,pnum,"c")
get_user_name(id,name,charsmax(name))

new upTeam = get_user_team(id)

if(!(0 <= upTeam < sizeof teamColor))
upTeam = 0

for(new i,player; i < pnum ; ++i){
player = pls[i]

aes_get_level_name(newlevel,levelName,charsmax(levelName),player)

if(player != id){
if(!isTplMode){
client_print_color(player,teamColor[upTeam],"%L %L",player,"AES_TAG",player,"AES_NEWLEVEL_ALL",name,levelName)
}else{
new msg[191],len
tplFormatNewLevel(id,msg,len,"AES_NEWLEVEL_ALL_TPL",player,TPL_UP_ALL)

client_print_color(player,teamColor[upTeam],msg)
}
}else{
if(!isTplMode){
client_print_color(id,teamColor[upTeam],"%L %L",id,"AES_TAG",id,"AES_NEWLEVEL_ID",levelName)
}else{
new msg[191],len
tplFormatNewLevel(id,msg,len,"AES_NEWLEVEL_TPL",id,TPL_UP)

client_print_color(id,teamColor[upTeam],msg)
}
}
}
}
default: return
}
}

public tplFormatNewLevel(id,msg[],len,tplKey[],idLang,tplType){
new Float:player_exp = aes_get_player_exp(id)
new Float:player_reqexp = aes_get_player_reqexp(id)
new player_level = aes_get_player_level(id)
new player_bonus = aes_get_player_bonus(id)

len = formatex(msg[len],190-len,"%L ",idLang,"AES_TAG")

len += parse_informer_tpl(
id,id,msg,len,190,tplKey,tplType,idLang,

player_exp,
player_level,
player_reqexp,
player_bonus
)

return len
}

public Show_Hud_Informer(taskId){
new id = taskId - PLAYER_HUD_OFFSET
new watchId = id
new isAlive = is_user_alive(id)

if(informerSyncObj != 0)
ClearSyncHud(id,informerSyncObj)

if(!isAlive){
watchId = entity_get_int(id,EV_INT_iuser2)

if(!watchId)
return
}

new hudMessage[256],len

new Float:player_exp = aes_get_player_exp(watchId)
new Float:player_reqexp = aes_get_player_reqexp(watchId)
new player_level = aes_get_player_level(watchId)
new player_bonus = aes_get_player_bonus(watchId)


new bool:status = true

if(player_exp == -1.0)
{
status = false
}

if(hudInfoOn){
ClearSyncHud(id,informerSyncObj)

if(status){
if(!isTplMode){
if(playerWatchLevel[id] != player_level || !playerLevel[id][0]){
aes_get_level_name(player_level,playerLevel[id],charsmax(playerLevel[]),id)
playerWatchLevel[id] = player_level
}

if(watchId != id){
new watchName[32]
get_user_name(watchId,watchName,charsmax(watchName))

len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L^n",id,"AES_INFORMER0",watchName)
}

len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L^n",id,"AES_INFORMER1",playerLevel[id])
if(player_reqexp != -1.0){
len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L",id,"AES_INFORMER2",player_exp,player_reqexp)
}else
len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L",id,"AES_PLAYER_XP_MAX")
}else{
if(isAlive)
{
len += parse_informer_tpl(
id,watchId,
hudMessage,len,charsmax(hudMessage),"AES_HUD_TPL",TPL_INF,id,

player_exp,
player_level,
player_reqexp,
player_bonus
)
}
else if(!isAlive && hudDeadOn)
{
len += parse_informer_tpl(
id,watchId,
hudMessage,len,charsmax(hudMessage),"AES_HUD_TPL_D",TPL_INF_D,id,

player_exp,
player_level,
player_reqexp,
player_bonus
)
}
}
new skill[10]
statsx_get_user_skill_name(id, skill, charsmax(skill))
len+= formatex(hudMessage[len],charsmax(hudMessage) - len, "%L" ,id,"SKILL" , skill)

}
else
len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L",id,"AES_INFORMER_FAIL")

if(isAlive){
if(hudInfoColorRandom){
// рандом такой рандом
hudInfoColor[0] = random(25500) / 100
hudInfoColor[1] = random(25500) / 100
hudInfoColor[2] = random(25500) / 100
}

set_hudmessage(hudInfoColor[0], hudInfoColor[1], hudInfoColor[2], hudInfoxPos , hudInfoyPos,.holdtime = hudUpdateInterval,.channel = 3)
}else if(!isAlive && hudDeadOn){
if(hudDeadColorRandom){
hudDeadColor[0] = random(25500) / 100
hudDeadColor[1] = random(25500) / 100
hudDeadColor[2] = random(25500) / 100
}

set_hudmessage(hudDeadColor[0],hudDeadColor[1],hudDeadColor[2],hudDeadxPos,hudDeadyPos,0,.holdtime = hudUpdateInterval,.channel = 3)
}

replace_all(hudMessage,charsmax(hudMessage),"\n","^n")
ShowSyncHudMsg(id,informerSyncObj,hudMessage)

len = 0
hudMessage[0] = 0
}

if(hudaNewOn && get_pcvar_num(bonusEnabledPointer) == 1 && player_bonus > 0 && watchId == id){
ClearSyncHud(id,aNewSyncObj)

len += formatex(hudMessage[len],charsmax(hudMessage) - len,"%L",id,"AES_ANEW_HUD",player_bonus)
replace_all(hudMessage,charsmax(hudMessage),"\n","^n")

set_hudmessage(hudaNewColor[0],hudaNewColor[1],hudaNewColor[2],hudaNewxPos,hudaNewyPos,0,.holdtime = hudUpdateInterval)
ShowSyncHudMsg(id,aNewSyncObj,hudMessage)
}
}

public parse_informer_tpl(id,watchId,string[],len,maxLen,tplKey[],tplType,idLang,Float:player_exp,player_level,Float:player_reqexp,player_bonus){
static tpl[256],tmp[32],i

tpl[0] = 0
tmp[0] = 0

formatex(tpl,charsmax(tpl),"%L",idLang,tplKey)

player_exp = _:player_exp >= 0 ? player_exp + 0.005 : player_exp - 0.005
player_reqexp = _:player_reqexp >= 0 ? player_reqexp + 0.005 : player_reqexp - 0.005

for(i = 0; i < tplInfo ; i++){
if(tplBitSum[tplType] & (1 << i)){
tmp[0] = 0

switch(i){
case INF_EXP: formatex(tmp,charsmax(tmp),"%.0f",player_exp)
case INF_LEVELEXP: formatex(tmp,charsmax(tmp),"%.0f",player_reqexp)
case INF_NEEDEXP: formatex(tmp,charsmax(tmp),"%.0f",player_reqexp - player_exp)
case INF_LEVEL: formatex(tmp,charsmax(tmp),"%d",player_level + 1)
case INF_MAXLEVEL: formatex(tmp,charsmax(tmp),"%d",aesMaxLevel)
case INF_RANK: {
if(playerWatchLevel[id] != player_level || !playerLevel[id][0]){
aes_get_level_name(player_level,playerLevel[id],charsmax(playerLevel[]),idLang)
playerWatchLevel[id] = player_level
}

copy(tmp,charsmax(tmp),playerLevel[id])
}
case INF_NAME: get_user_name(watchId,tmp,charsmax(tmp))
case INF_STEAMID: get_user_authid(watchId,tmp,charsmax(tmp))
case INF_BONUS: formatex(tmp,charsmax(tmp),"%d",player_bonus)
case INF_EXF: formatex(tmp,charsmax(tmp),"%.2f",player_exp)
case INF_LXF: formatex(tmp,charsmax(tmp),"%.2f",player_reqexp)
case INF_NXF: formatex(tmp,charsmax(tmp),"%.2f",player_reqexp - player_exp)
}

if(tmp[0])
replace(tpl,charsmax(tpl),tplKeys[i],tmp)
}
}

len += formatex(string[len],maxLen-len,tpl)

return len
}

get_player_trackid(id,trackId[],trackLen){
switch(g_trackmode){
case 0: get_user_name(id,trackId,trackLen)
case 1: {
get_user_authid(id,trackId,trackLen)

if(!strcmp(trackId,"STEAM_ID_LAN") || !strcmp(trackId,"VALVE_ID_LAN") || !strcmp(trackId,"BOT")
|| !strcmp(trackId,"HLTV"))
return 0
}
case 2: get_user_ip(id,trackId,trackLen,1)
}

return 1
}

statsx_get_user_skill_name(id, name[], len)
{
new Float:skill
get_user_skill(id, skill)

new skill_id = statsx_get_skill_id(skill)
copy(name, len, g_skill_letters[skill_id])
}

statsx_get_skill_id(Float:skill)
{
for(new i = 0; i < sizeof(g_skill_opt); i++)
{
if(skill < g_skill_opt[i])
return i
}
return charsmax(g_skill_opt)
}
Помогите поправить код
не правильно выводит скилл в худ
то есть когда сам играешь все норм а когда смотришь за кем то показывает твой скилл а не игрока помогите исправить чтоб покзывало игрока силл
 
В этой теме было размещено решение! Перейти к решению.

Вложения

Сообщения
451
Реакции
254
Помог
9 раз(а)
Код:
-statsx_get_user_skill_name(id, skill, charsmax(skill))
+statsx_get_user_skill_name(watchId, skill, charsmax(skill))
 
Сообщения
14
Реакции
-1
malniata, А как сделать чтоб не ток букву скилла выводила а еще и цыфры ?
 
Статус
В этой теме нельзя размещать новые ответы.

Пользователи, просматривающие эту тему

Сейчас на форуме нет ни одного пользователя.
Сверху Снизу