DropPlayerItem

[PurposeLess]

Hello guys,
I am trying to block dropping a weapon. I try to use reapi instead of register_clcmd("drop"
But I see that this plugin doesn't see the name of weapon.

RegisterHookChain(RG_CBasePlayer_DropPlayerItem, "@CBasePlayer_DropPlayerItem", .post=false);

@CBasePlayer_DropPlayerItem(const id, const itemname[])
{
    client_print_color(0, 0, itemname);
}

It shows my nickname everytime. Where is the mistake?

 

[Ayk]

PurposeLess, item name can be empty:

// DropPlayerItem - drop the named item, or if no name, the active item.
CBaseEntity *EXT_FUNC CBasePlayer::__API_HOOK(DropPlayerItem)(const char *pszItemName)

 

[PurposeLess]

Ayk, so how can i make them stop dropping a weapon?
I just want to block one weapon, not all of 'em

 

[Ayk]

PurposeLess, if itemname[] is not empty then just use it, otherwise check active item.

 

[PurposeLess]

Ayk, itemname is empty except c4 drops. I will try to check active item.

 

[SergeyShorokhov]

the plugin doesn't see the name of the weapon

https://github.com/s1lentq/ReGameDL...ba3d248f4cd82/regamedll/dlls/client.cpp#L3400
https://github.com/s1lentq/ReGameDL...493a8b9/regamedll/dlls/player.cpp#L7855-L7860

I just want to block one weapon, not all of 'em

GLOCK18 example (weapon will be removed after drop)

#include <amxmodx>
#include <reapi>

public plugin_init() {
    RegisterHookChain(RG_CBasePlayer_DropPlayerItem, "CBasePlayer_DropPlayerItem", .post = true);
}

public CBasePlayer_DropPlayerItem(const id, const itemname[])
{
    new pWeaponBox = GetHookChainReturn(ATYPE_INTEGER);
    if (is_nullent(pWeaponBox))
        return;

   // https://github.com/s1lentq/ReGameDLL_CS/blob/3878f46678049201fb35f00168c9f9e1f493a8b9/regamedll/dlls/player.cpp#L1282-L1283
    if (findWeaponInWeaponBox(pWeaponBox, WEAPON_GLOCK18))
        set_entvar(pWeaponBox, var_nextthink, 0.0);
}

bool: findWeaponInWeaponBox(const pWeaponBox, const WeaponIdType:weaponID) {
    for (new i = 0, weapon; i < MAX_ITEM_TYPES; i++) {
        weapon = get_member(pWeaponBox, m_WeaponBox_rgpPlayerItems, i);
        if(is_nullent(weapon))
            continue;

        new WeaponIdType:wid = get_member(weapon, m_iId);
        if (wid == weaponID)
            return true;
    }

    return false;
}

 

[PurposeLess]

The weapon has been deleted when I drop. Can't I make it not to be deleted with that command? It should work like that

register_clcmd("drop", "drop");

public drop(id)
{
    return (get_user_weapon(id) == CSW_GLOCK18) ? 1 : 0;
}

+

#include <amxmodx>
#include <reapi>

public plugin_init() {
    RegisterHookChain(RG_CBasePlayer_DropPlayerItem, "CBasePlayer_DropPlayerItem", .post = false);
}

public CBasePlayer_DropPlayerItem(const id, const itemname[])
{
    if(get_user_weapon(id) == CSW_GLOCK18)
    {
        SetHookChainReturn(ATYPE_INTEGER, false);
        return HC_SUPERCEDE;
    }

    return HC_CONTINUE;
}

 

[Ruby]

Ham_CS_Item_CanDrop

RegisterHam( Ham_CS_Item_CanDrop, "weapon_glock18", "CWeapon__CanDrop_Post", true );

public CWeapon__CanDrop_Post( const pItem )
{
    SetHamReturnInteger( 0 );
    return  HAM_SUPERCEDE;
}

 

[BlackSignature]

Ham_CS_Item_CanDrop ?

 

[fantom]

BlackSignature, Да. И именно его нужно использовать

 

[Ayk]

Ham_CS_Item_CanDrop

RegisterHam( Ham_CS_Item_CanDrop, "weapon_glock18", "CWeapon__CanDrop_Post", true );

public CWeapon__CanDrop_Post( const pItem )
{
    SetHamReturnInteger( 0 );
    return HAM_SUPERCEDE;
}

Supercede in the POST hook? Ok.

 

[PurposeLess]

Supercede in the POST hook? Ok.

It is working very good even if there is supercede in the Post hook.
I think Ham_CS_Item_CanDrop is fine. Thank you everybody who helps me.

 

[Ruby]

Ayk, ну ладно HAM_OVERRIDE, разницы-то

 

[Ayk]

It is working very good even if there is supercede in the Post hook.

Any return in POST hook has no effect.

 

[Ruby]

Ayk, мб ты попробуешь без ретурна и потом напишешь?
Можно и pre использовать

 

[Ayk]

мб ты попробуешь без ретурна и потом напишешь?

Что тебе надо от меня? Сиди на своём уровне если нравится и не трогай меня.
ПОСТ функции уже не обращаются к движку. Значение ретурна им уже побоку.

 

[Minni]

Ruby, так-то он прав. Или ты умеешь блокировать выполнение того, что уже было выполнено?! Если так, то ты ведьма и тебя нужно сжечь. ?