Смена типа патронов у оружия

[Minni]

Я конечно не из разряда глупых людей, которые при открытии дверцы холодильника не понимают откуда холодом тянет, но чёт не могу понять, можно ли вообще сменить тип патронов оружию. Пытался сделать для USP использование патронов 50AE, которые у Deagle, но всё четно. Ham_Item_GetItemInfo не дал ожидаемых результатов, как и использование ItemInfo_pszAmmo1 в rg_set_iteminfo().

 

[fantom]

Minni, тебе сам урон от этих патронов или иконку и количество?

 

[fl0wer]

Minni, в AddToPlayer сет m_Weapon_iPrimaryAmmoType. Ну ещё веапонлист послать с таким же аммо индексом.

 

[Minni]

Пробовал очевидные методы:

public plugin_init() {
    RegisterHam(Ham_Item_GetItemInfo, "weapon_usp", "hamfwd_GetItemInfo_Post", .Post = true);
}

public hamfwd_GetItemInfo_Post(pWeapon, iteminfo) {
    SetHamItemInfo(iteminfo, Ham_ItemInfo_pszAmmo1, "50AE");
}

public hack_u_ass(pPlayer) {
    new pWeapon = rg_give_custom_item(pPlayer, "weapon_usp", GT_DROP_AND_REPLACE, 43622);

    if(is_entity(pWeapon)) {
        rg_set_iteminfo(pWeapon, ItemInfo_pszAmmo1, "50AE");
        rg_set_iteminfo(pWeapon, ItemInfo_iMaxAmmo1, 50);
    }
}

27 Апр 2020

Minni, тебе сам урон от этих патронов или иконку и количество?

Да урон я сам тыкаю через rg_fire_bullets3, иконок нет))

 

[fantom]

public hamfwd_GetItemInfo_Post(pWeapon, iteminfo) { SetHamItemInfo(iteminfo, Ham_ItemInfo_pszAmmo1, "50AE"); }

хукать не имеет смысла.

rg_set_iteminfo(pWeapon, ItemInfo_pszAmmo1, "50AE");

это отвечает за выдачу аммо, и его учет. отправляй WeaponList (если меняешь всегда и у всех можно в MSG_INIT единожды отправить). Ну и про m_Weapon_iPrimaryAmmoType не стоит забыть. Хотя если от дигла, и сменить имя аммо до самой выдачи, то оно само заполнится нужным индексом.

 

[Minni]

Допустим... Индекс сменился, но патрончиков-то нет в запасе. В пре и пост пробовал.

public hamfwd_AddToPlayer_Post(pWeapon, pPlayer) {
    set_member(pWeapon, m_Weapon_iPrimaryAmmoType, 8);
    rg_set_iteminfo(pWeapon, ItemInfo_pszAmmo1, "50AE");
    rg_set_user_bpammo(pPlayer, WEAPON_DEAGLE, 50);
   
    message_begin(MSG_ONE, g_iMsgWeaponList, .player = pPlayer);
    write_string(WEAPON_HUD);
    write_byte(8);
    write_byte(50);
    write_byte(-1);
    write_byte(-1);
    write_byte(1);
    write_byte(4);
    write_byte(any:WEAPON_USP);
    write_byte(0);
    message_end();
}

 

[BalbuR]

Аммо айди в веапонлисте тоже укажи
Я думаю патроны тебе выдались , но веапонлист не отображает значение, и.к. айди другой

 

[Minni]

BalbuR, указан ведь)
write_byte(8);

 

[BalbuR]

"50AE"

попробуй "50ae"



конечно не гарант., но все же

раз индекс сменился, значит дело в чем-то другом

stock weaponlist

Спойлер: weaponlist

stock reShowWeaponList(pPlayer, pItem)
{
    new szWeaponName[32];
    //get_entvar(pItem, var_classname, szWeaponName, charsmax(szWeaponName));
    rg_get_iteminfo(pItem, ItemInfo_pszName, szWeaponName, charsmax(szWeaponName));

    new iPriAmmoType = get_member(pItem, m_Weapon_iPrimaryAmmoType);
    new iMaxPriAmmo = rg_get_iteminfo(pItem, ItemInfo_iMaxAmmo1);
    new iSecAmmoType = get_member(pItem, m_Weapon_iSecondaryAmmoType);
    new iMaxSecAmmo = rg_get_iteminfo(pItem, ItemInfo_iMaxAmmo2);
    new iSlot = rg_get_iteminfo(pItem, ItemInfo_iSlot);
    new iPosition = rg_get_iteminfo(pItem, ItemInfo_iPosition);
    new iId = rg_get_iteminfo(pItem, ItemInfo_iId);
    new iFlags = rg_get_iteminfo(pItem, ItemInfo_iFlags);

    static msgWeaponList;

    if (!msgWeaponList) msgWeaponList = get_user_msgid("WeaponList");

    message_begin(MSG_ONE, msgWeaponList, _, pPlayer);
    write_string(szWeaponName)
    write_byte(iPriAmmoType)
    write_byte(iMaxPriAmmo)
    write_byte(iSecAmmoType)
    write_byte(iMaxSecAmmo)
    write_byte(iSlot)
    write_byte(iPosition)
    write_byte(iId)
    write_byte(iFlags)
    message_end()
}

 

[Minni]

попробуй "50ae"

https://github.com/s1lentq/ReGameDLL_CS/blob/master/regamedll/dlls/wpn_shared/wpn_deagle.cpp#L47


И да, ничего не изменилось.

 

[BalbuR]

rg set user bpammo крутит цикл по инвентарю, насколько я помню
У тебя нет дигла

 

[Minni]

rg set user bpammo

Заменил на set_member(pPlayer, m_rgAmmo, 50, 8);. Результат пока неизменный. Стабильно ничего ?

 

[BalbuR]

ExecuteHamB(Ham_GiveAmmo, id, rg_get_iteminfo(iWeapon, ItemInfo_iMaxClip), "50ae", rg_get_iteminfo(iWeapon, ItemInfo_iMaxAmmo1));

 

[Minni]

ExecuteHamB(Ham_GiveAmmo, id, rg_get_iteminfo(iWeapon, ItemInfo_iMaxClip), "50ae", rg_get_iteminfo(iWeapon, ItemInfo_iMaxAmmo1));

Не знаю, что должно было изменится, использовав я такую конструкцию, но она тоже не решила проблему.

 

[BalbuR]

покажи весь код
не понятно что у тебя там вообще

 

[Minni]

BalbuR, типо, это и есть весь код, который отвечает за выдачу оружия и управлением патронами.

public plugin_init() {
    RegisterHam(Ham_Item_AddToPlayer, "weapon_usp", "hamfwd_AddToPlayer_Pre", .Post = false);
}

public hack_u_ass(pPlayer) {
    rg_give_custom_item(pPlayer, "weapon_usp", GT_DROP_AND_REPLACE, 43622);
}

public hamfwd_AddToPlayer_Pre(pWeapon, pPlayer) {
    set_member(pWeapon, m_Weapon_iPrimaryAmmoType, 8);
    rg_set_iteminfo(pWeapon, ItemInfo_pszAmmo1, "50ae");
    ExecuteHamB(Ham_GiveAmmo, pPlayer, 50, "50ae", 50);

    message_begin(MSG_ONE, g_iMsgWeaponList, .player = pPlayer);
    write_string(WEAPON_HUD);
    write_byte(8);
    write_byte(50);
    write_byte(-1);
    write_byte(-1);
    write_byte(1);
    write_byte(4);
    write_byte(any:WEAPON_USP);
    write_byte(0);
    message_end();
}

 

[fl0wer]

Minni, и зачем пре?

 

[Minni]

fl0wer, писал же выше, что пробую в пре и пост.

 

[fl0wer]

Minni, оно перезаписывается в аддтуплаере (не конкретно там, но когда подбираешь). Поэтому нужен пост. И достаточно поменять m_Weapon_iPrimaryAmmoType, выдать игроку патроны в m_rgAmmo, и послать веапонлист для отображения их.

 

[fl0wer]

#pragma semicolon 1

#include <amxmodx>
#include <hamsandwich>
#include <reapi>

public plugin_init()
{
    register_clcmd("weapon_deagle", "@Command_WeaponDeagle");

    RegisterHookChain(RG_CBasePlayer_GiveAmmo, "@CBasePlayer_GiveAmmo_Pre", false);

    RegisterHam(Ham_Spawn, "weapon_usp", "@CUSP_Spawn_Post", true);
    RegisterHam(Ham_Item_AddToPlayer, "weapon_usp", "@CUSP_AddToPlayer_Post", true);
    RegisterHam(Ham_Weapon_Reload, "weapon_usp", "@CUSP_Reload_Pre", false);
}

@Command_WeaponDeagle(id)
{
    engclient_cmd(id, "weapon_usp");
    return PLUGIN_HANDLED;
}

@CBasePlayer_GiveAmmo_Pre(id, amount, name[], max)
{
    // usp check
    SetHookChainArg(3, ATYPE_STRING, "50AE");
}

@CUSP_Spawn_Post(id)
{
    rg_set_iteminfo(id, ItemInfo_pszAmmo1, "50AE");
    rg_set_iteminfo(id, ItemInfo_iMaxAmmo1, 35);
    rg_set_iteminfo(id, ItemInfo_iMaxClip, 7);
}

@CUSP_AddToPlayer_Post(id, player)
{
    SendWeaponList
    (
        player,
        "weapon_deagle",
        get_member(id, m_Weapon_iPrimaryAmmoType),
        rg_get_iteminfo(id, ItemInfo_iMaxAmmo1),
        -1,
        -1,
        1,
        4,
        get_member(id, m_iId),
        0
    );
}

@CUSP_Reload_Pre(id)
{
    new player = get_member(id, m_pPlayer);

    // Avoid the check
    // https://github.com/s1lentq/ReGameDLL_CS/blob/master/regamedll/dlls/wpn_shared/wpn_usp.cpp#L248
    set_member(player, ammo_45acp, 1);
}

SendWeaponList(id, const name[], ammo1, maxAmmo1, ammo2, maxAmmo2, slot, position, any:weaponId, flags)
{
    static msg;

    if (!msg)
        msg = get_user_msgid("WeaponList");

    message_begin(MSG_ONE, msg, _, id);
    write_string(name);
    write_byte(ammo1);
    write_byte(maxAmmo1);
    write_byte(ammo2);
    write_byte(maxAmmo2);
    write_byte(slot);
    write_byte(position);
    write_byte(weaponId);
    write_byte(flags);
    message_end();
}

Меняет патроны юспа на патроны дигла.
Избегает проверку наличия патронов в хуке перезарядки.
Заменяет WeaponList для корректного отображения.
Меняет максимальное кол-во патронов (+ в запасе).
Позволяет для юсп покупать патроны дигла.