reapi module gmx GM-X Player Preferences 0.1.83-alpha

#include <amxmodx>
#include <reapi>
#include <gmx_player_preferences>

new const PLUGIN_NAME[] = "[GMX PP] Save Money";
new const PLUGIN_VERSION[] = "1.0.0";
new const PLUGIN_AUTHOR[] = "w0w";

/****************************************************************************************
****************************************************************************************/

new const g_szKey[] = "money";

new bool:g_bLoaded[MAX_PLAYERS + 1];

public plugin_init()
{
    register_plugin(
        .plugin_name = PLUGIN_NAME,
        .version = PLUGIN_VERSION,
        .author = PLUGIN_AUTHOR);

    RegisterHookChain(RG_CBasePlayer_AddAccount, "refwd_PlayerAddAccount_Post", true);
    RegisterHookChain(RH_SV_DropClient, "refwd_DropClient_Post", true);
}

public GMX_PP_PlayerLoaded(const id)
{
    g_bLoaded[id] = true;

    new iMoney = GMX_PP_GetNumber(id, g_szKey);
    rg_add_account(id, iMoney, AS_SET);
}

public refwd_PlayerAddAccount_Post(const id, iAmount, RewardType:iType, bool:bTrackChange)
{
    if(g_bLoaded[id] && iAmount)
        GMX_PP_SetNumber(id, g_szKey, get_member(id, m_iAccount));
}

public refwd_DropClient_Post(const id)
{
    g_bLoaded[id] = false;
}