Ошибка в плагине Kills Rarity

newcs · 12 Мар 2020

Просьба помочь с ошибками!

RockTheStreet · 12 Мар 2020

memory access

newcs · 12 Мар 2020

Вот оригинальный код плагина.

C++:

#include <amxmodx>
#include <reapi>
#include <fakemeta>
#include <xs>

#define IsSuicide(%1,%2)    bool:(%1 == %2)
#define IsPlayer(%1)        bool:(%1 && %1 <= MAX_PLAYERS)

new bool:g_bDamaged[MAX_PLAYERS + 1][MAX_PLAYERS + 1];

enum _:KillRarity_s (<<=1)
{
    kill_NoScope = 1,
    kill_AirShot,
    kill_OneShot,
    kill_Penetrated,
    kill_HeadShot
}

public plugin_init()
{
    register_plugin("Kills Rarity", "0.0.1", "wopox1337");
    RegisterHookChain(RG_CBasePlayer_TakeDamage, "CBasePlayer_TakeDamage", .post = true);
    RegisterHookChain(RG_CBasePlayer_Killed, "CBasePlayer_Killed", .post = true);
    RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound", .post = true);
}

public CBasePlayer_TakeDamage(id, iInflictor, iAttacker, Float:fDamage, bitsDamageType)
{
    if(id == iAttacker || !is_user_connected(iAttacker) || !rg_is_player_can_takedamage(id, iAttacker))
        return;

    g_bDamaged[iAttacker][id] = true;
}

public CBasePlayer_Killed(id, iKiller, iGib)
{
    if(IsSuicide(id, iKiller) || !IsPlayer(iKiller))
        return;

    _AnnounceToPlayers(iKiller, _Get_RareKill(id, iKiller));
}

public CSGameRules_RestartRound()
{
    for(new id = 1; id <= MaxClients; id++)
        arrayset(g_bDamaged[id], 0, sizeof g_bDamaged[]);
}

_Get_RareKill(id, iKiller)
{
    const DEFAULT_FOV = 90;
    #define __GetItem_ID(%1)     get_member(get_member(%1, m_pActiveItem), m_iId)

    new bitKillRarity;
    new bitsActiveItem = 1 << __GetItem_ID(iKiller);

    if(get_member(id, m_bHeadshotKilled)) // Headshot kill
    {
        bitKillRarity |= kill_HeadShot;
    }

    if(bitsActiveItem & (1 << CSW_HEGRENADE | 1 << CSW_KNIFE)) // HEGrenade or Knife kill
    {
        return bitKillRarity;
    }

    if(bitsActiveItem & (1 << CSW_AWP | 1 << CSW_SCOUT | 1 << CSW_G3SG1 | 1 << CSW_SG550)) // Sniper Kill
    {
        if(get_member(iKiller, m_iClientFOV) == DEFAULT_FOV) // NoScope
        {
            bitKillRarity |= kill_NoScope;
        }
    }

    static Float:fvecVelocity[3];
    get_entvar(iKiller, var_velocity, fvecVelocity);
    if(fvecVelocity[2] != 0.0 && (fvecVelocity[2] < -1.0 || fvecVelocity[2] > 1.0)) // JumpShot or AirShot kill (same as !FL_ONGROUND?)
    {
        bitKillRarity |= kill_AirShot;
    }

    if(!(bitsActiveItem & (1 << CSW_AWP))
    && !g_bDamaged[iKiller][id]
    ) // OneShot kill
    {
        bitKillRarity |= kill_OneShot;
    }

    if(bIsPenetrated(id, iKiller)) // Wallbang kill
    {
        bitKillRarity |= kill_Penetrated;
    }

    return bitKillRarity;
}

_AnnounceToPlayers(iKiller, bitKillRarity)
{
    if(!bitKillRarity)
    {
        return;
    }

    new szRareKillBuffer[64];

    if(bitKillRarity & kill_NoScope)        strcat(szRareKillBuffer, "NoScope ",    16);
    if(bitKillRarity & kill_AirShot)        strcat(szRareKillBuffer, "AirShot ",    16);
    if(bitKillRarity & kill_OneShot)        strcat(szRareKillBuffer, "OneShot ",    16);
    if(bitKillRarity & kill_Penetrated)        strcat(szRareKillBuffer, "Wallbang ",    16);
    // if(bitKillRarity & kill_HeadShot)        strcat(szRareKillBuffer, "Headshot ",    16); // Don't need it!?

    trim(szRareKillBuffer);

    client_print_color(0, print_team_red, "Игрок %n совершил необычное убийство! (^3%s^1)", iKiller, szRareKillBuffer);
}

stock bool:bIsPenetrated(id, iKiller)
{
    static hTrace;
    if(!hTrace)
        hTrace = create_tr2();

    static Float:vfOrigin_Killer[3], Float:vfViewOfs[3];
    get_entvar(iKiller, var_origin, vfOrigin_Killer);
    get_entvar(iKiller, var_view_ofs, vfViewOfs);
    xs_vec_add(vfOrigin_Killer, vfViewOfs, vfOrigin_Killer);

    static Float:vfOrigin[3];
    get_entvar(id, var_origin, vfOrigin);
    get_entvar(id, var_view_ofs, vfViewOfs);
    xs_vec_add(vfOrigin, vfViewOfs, vfOrigin);
   
    engfunc(EngFunc_TraceLine, vfOrigin_Killer, vfOrigin, IGNORE_MONSTERS | IGNORE_GLASS, 0, hTrace);
   
    static Float:fFraction;
    get_tr2(hTrace, TR_flFraction, fFraction);

    return bool:(fFraction != 1.0);
}

12 Мар 2020

melfyk написал(а):
memory access

А что сделать надо? Я не совсем понял.

pro100iweb · 13 Мар 2020

newcs написал(а):
client_print_color(0, print_team_red, "Игрок %n совершил необычное убийство! (^3%s^1)", iKiller, szRareKillBuffer);

Попробуй так чтоль
client_print_color(0, print_team_red, "Игрок %i совершил необычное убийство! (^3%s^1)", iKiller, szRareKillBuffer);

newcs · 13 Мар 2020

pro100iweb,
Всё из лога, далее только повторение

Код:

L 03/12/2020 - 17:31:34: Start of error session.
L 03/12/2020 - 17:31:34: Info (map "awp_india") (file "addons/amxmodx/logs/error_20200312.log")
L 03/12/2020 - 17:31:34: Client index 179 is invalid
L 03/12/2020 - 17:31:34: [AMXX] Displaying debug trace (plugin "KillsRarity.amxx", version "0.0.1")
L 03/12/2020 - 17:31:34: [AMXX] Run time error 10: native error (native "client_print_color")
L 03/12/2020 - 17:31:34: [AMXX]    [0] KillsRarity.sma::_AnnounceToPlayers (line 115)
L 03/12/2020 - 17:31:34: [AMXX]    [1] KillsRarity.sma::CBasePlayer_Killed (line 41)

pro100iweb · 13 Мар 2020

newcs, ну вот же
Client index 179 is invalid
Сделай проверку
if( 1<= id <= 32 )

Minni · 13 Мар 2020

pro100iweb написал(а):
Попробуй так чтоль
client_print_color(0, print_team_red, "Игрок %i совершил необычное убийство! (^3%s^1)", iKiller, szRareKillBuffer);

И что получишь-то в итоге использовав %i ?!)))
Спецификатор формата %n там не от балды стоит. (https://github.com/alliedmodders/amxmodx/pull/93)

13 Мар 2020

pro100iweb написал(а):
newcs, ну вот же
Client index 179 is invalid
Сделай проверку
if( 1<= id <= 32 )

Уже есть на 38 строке проверка. Держу в курсе.

newcs · 13 Мар 2020

Minni, вот и я посмотрел только что... А в чем проблема тогда?

pro100iweb · 13 Мар 2020

newcs, тогда alive и connected проверяй :))) С такой ошибкой не сталкивался просто

Minni, на код как то не смотрел, что то не подумал об этом

Minni · 14 Мар 2020

newcs, у тебя размерность массива для записи строки 64 байта, а при записи у тебя указано 100.

14 Мар 2020

Замени везде 100 на charsmax(szRareKillBuffer) и саму размерность увеличь раза в 2, поскольку юзаешь кириллицу, да и ники могут быть длинные и так же на кириллице.

newcs · 14 Мар 2020

Minni, попробую и отпишусь

Ошибка в плагине Kills Rarity

newcs

RockTheStreet

Саппорт года

newcs

pro100iweb

newcs

pro100iweb

Minni

newcs

pro100iweb

Minni

newcs

Пользователи, просматривающие эту тему