poll.amxx ошибки с SQL

Nordic Warrior · 12 Июн 2019

Код:

#include <amxmodx>
#include <reapi>
#include <util_parser>
#include <sqlx>

#define PLUGIN  "Poll"
#define VERSION "1.1"
#define AUTHOR  "Nunfy"

#define MYSQL_HOSTNAME    ""
#define MYSQL_USERNAME    ""
#define MYSQL_PASSWORD    ""
#define MYSQL_DATABASE    ""
#define MYSQL_TABLE        "table_name"

#define MAX_MENU_SIZE            512        // Максимальный размер меню
#define MAX_ITEM_LENGHT            200     // Максимальный длинна пункта меню
#define MAX_POLLS                5        // Максимальное количество опросов
#define MAX_NICKNAME_LENGHT        30         // Максимальная длинна никнейма
#define MAX_STEAM_ID_LENGHT        35         // Максимальная длинна стим ид
#define MAX_MAP_LENGHT            30         // Максимальная длинна названия карты

#define register_menu(%0,%1,%2) register_menucmd(register_menuid(%0), %1, %2)

enum user_data
{
    bool: uMenu,
    uPoll,
    bool: uAnswered
};

static     config_file_dir[] = "addons/amxmodx/configs/poll.ini"; // путь к ini файлу
new polls[MAX_POLLS][5][MAX_ITEM_LENGHT],
    polls_items[MAX_POLLS],
    ud[MAX_PLAYERS + 1][user_data];

new Handle: mysql_turple;
new Handle: mysql_connection;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    RegisterHookChain(RG_CBasePlayer_Killed, "user_killed", true);
    RegisterHookChain(RG_CSGameRules_RestartRound, "restart_round", true);
    register_menu("\r[\wОпрос\r]", 1023, "main_menu_handler");
    new file_id = UTIL_ParserLoadFile(config_file_dir);
    for(new p; p < MAX_POLLS; p++)
    {
        new string[10];
        format(string, charsmax(string), "[POLL_%d]", p);
        console_print(0, "%s", string);
        for(new i; i < UTIL_ParserGetLines(file_id, string); i++)
        {
            UTIL_ParserGetContent(file_id, i, polls[p][i], MAX_ITEM_LENGHT + 1, string);
            polls_items[p] = i;
            console_print(0, "%s", polls[p][i]);
        }
    }
    mysql_connect();
    new Handle: query = SQL_PrepareQuery(mysql_connection, "UPDATE %s SET map = ''", MYSQL_TABLE);
    if(!SQL_Execute(query))
    {
        new error[512];
        SQL_QueryError(query, error, charsmax(error));
        set_fail_state(error);
    }
    SQL_FreeHandle(query);
}

public client_putinserver(id)
{
    load_data(id);
}

public client_disconnected(id, bool:drop, message[], maxlen)
{
    ud[id][uMenu] = false;
    ud[id][uPoll] = 0;
    ud[id][uAnswered] = false;
}

public user_killed(const this, pevAttacker, iGib)
{
    if(ud[this][uAnswered] == true)
        return;

    new string[MAX_MENU_SIZE], keys = MENU_KEY_7;
    switch(polls_items[ud[this][uPoll]])
    {
        case 1:
        {
            format(string, charsmax(string), "\r[\wОпрос\r]\
            ^n^n%s\
            ^n^n\r7. \w%s",
            polls[ud[this][uPoll]][0],
            polls[ud[this][uPoll]][1]);
            keys = MENU_KEY_7;
        }
        case 2:
        {
            format(string, charsmax(string), "\r[\wОпрос\r]\
            ^n^n%s\
            ^n^n\r7. \w%s\
            ^n\r8. \w%s",
            polls[ud[this][uPoll]][0],
            polls[ud[this][uPoll]][1],
            polls[ud[this][uPoll]][2]);
            keys = MENU_KEY_7|MENU_KEY_8;
        }
        case 3:
        {
            format(string, charsmax(string), "\r[\wОпрос\r]\
            ^n^n%s\
            ^n^n\r7. \w%s\
            ^n\r8. \w%s\
            ^n\r9. \w%s",
            polls[ud[this][uPoll]][0],
            polls[ud[this][uPoll]][1],
            polls[ud[this][uPoll]][2],
            polls[ud[this][uPoll]][3]);
            keys = MENU_KEY_7|MENU_KEY_8|MENU_KEY_9;
        }
        case 4:
        {
            format(string, charsmax(string), "\r[\wОпрос\r]\
            ^n^n%s\
            ^n^n\r7. \w%s\
            ^n\r8. \w%s\
            ^n\r9. \w%s\
            ^n\r0. \w%s",
            polls[ud[this][uPoll]][0],
            polls[ud[this][uPoll]][1],
            polls[ud[this][uPoll]][2],
            polls[ud[this][uPoll]][3],
            polls[ud[this][uPoll]][4]);
            keys = MENU_KEY_7|MENU_KEY_8|MENU_KEY_9|MENU_KEY_0;
        }
    }
    ud[this][uMenu] = true;
    show_menu(this, keys, string);
}

public restart_round()
{
    new users_ids[MAX_PLAYERS], users_num;
    get_players(users_ids, users_num, "h");
    for(new i; i < users_num; i++)
    {
        if(ud[users_ids[i]][uMenu] == true)
        {
            show_menu(users_ids[i], MENU_KEY_0, "^n", 1);
        }
    }
}

public main_menu_handler(id, key)
{
    switch(key)
    {
        case 6..9:
        {
            ud[id][uAnswered] = true;
            new nickname[MAX_NICKNAME_LENGHT + 1], steam_id[MAX_STEAM_ID_LENGHT + 1], map[MAX_MAP_LENGHT + 1];
            get_user_name(id, nickname, charsmax(nickname));
            get_user_authid(id, steam_id, charsmax(steam_id));
            get_mapname(map, charsmax(map));
            new Handle: query = SQL_PrepareQuery(mysql_connection, "INSERT INTO %s (nickname, steam_id, question, answer, next_poll_id, map) \
            VALUES ('%s', '%s', '%s', '%s', '%d', '%s')",
            MYSQL_TABLE,
            nickname,
            steam_id,
            polls[ud[id][uPoll]][0],
            polls[ud[id][uPoll]][key - 5],
            ud[id][uPoll] + 1,
            map);
            if(!SQL_Execute(query))
            {
                new error[512];
                SQL_QueryError(query, error, charsmax(error));
                set_fail_state(error);
            }
            SQL_FreeHandle(query);
        }
    }
}

stock mysql_connect()
{
    new error, string[512];
    mysql_turple = SQL_MakeDbTuple(MYSQL_HOSTNAME, MYSQL_USERNAME, MYSQL_PASSWORD, MYSQL_DATABASE);
    SQL_SetCharset(mysql_turple, "utf8");
    mysql_connection = SQL_Connect(mysql_turple, error, string, charsmax(string));
    if(mysql_connection == Empty_Handle)
    {
        set_fail_state(string);
    }
}

stock load_data(id)
{
    new steam_id[MAX_STEAM_ID_LENGHT + 1];
    get_user_authid(id, steam_id, charsmax(steam_id));
    new Handle: query = SQL_PrepareQuery(mysql_connection, "SELECT * FROM %s WHERE steam_id = '%s' AND next_poll_id = (SELECT MAX(next_poll_id) FROM %s) LIMIT 1",
    MYSQL_TABLE,
    steam_id,
    MYSQL_TABLE);
    if(!SQL_Execute(query))
    {
        new error[512];
        SQL_QueryError(query, error, charsmax(error));
        set_fail_state(error);
    }
    else if(SQL_NumResults(query))
    {
        ud[id][uPoll] = SQL_ReadResult(query, 5);
        new map[MAX_MAP_LENGHT + 1];
        get_mapname(map, charsmax(map));
        query = SQL_PrepareQuery(mysql_connection, "SELECT * FROM %s WHERE steam_id = '%s' AND map = '%s' LIMIT 1",
        MYSQL_TABLE,
        steam_id,
        map);
        if(!SQL_Execute(query))
        {
            new error[512];
            SQL_QueryError(query, error, charsmax(error));
            set_fail_state(error);
        }
        else if(SQL_NumResults(query))
        {
            ud[id][uAnswered] = true;
        }
    }
    SQL_FreeHandle(query);
}

Код:

[POLL_0]
На каком разрешении экрана вы играете?
640x480
800x600
1024x768
Больше, чем эти
[POLL_1]
Как Вы узнали о нашем сервере?
От друзей
С мониторингов
Во вкладке интернет

Nordic Warrior · 13 Июн 2019

Ещё заметил, что не работает функция запоминания игрока, то есть один вопрос задается всем игрокам каждый раз

Limbooc · 13 Июн 2019

Я так понимаю таблица не создается автоматический? вышли структуру таблицы, возможно у вас некорректно создалась таблица, и на будущее, лучше запрос открывать в начале запуска карты и закрывать при смене карты, то есть SQL_Result хранить в ячейки, и дальше по ним работать

13 Июн 2019

попробуй в ручную вписать данные



$sql="INSERT INTO table_name (nickname, steam_id, question, answer, next_poll_id, map) VALUES ('Иванов', 'STEAM_123123', 'Вопрос', 'Ответ', '1', 'de_dust2')";

Nordic Warrior · 13 Июн 2019

Limbooc написал(а):
Я так понимаю таблица не создается автоматический?

нет. в описании к плагину сказано создать её вручную, что я и сделал

Sonyx · 13 Июн 2019

Нет экранирования спецсимволов в данных перед вставкой. Оттуда и ноги растут.

fantom · 13 Июн 2019

Limbooc написал(а):
будущее, лучше запрос открывать в начале запуска карты и закрывать при смене карты

Фигню советуете.

13 Июн 2019

sbelov020, нужно экранировать все.

Nordic Warrior · 13 Июн 2019

fantom, Sonyx, что именно нужно экранировать?

Denzer · 13 Июн 2019

sbelov020, запросы в БД

Nordic Warrior · 17 Июн 2019

Всем спасибо, проблема решена экранированием запросов.