Выдаются стим бонусы только первые 2 раунда

Алексеич · 5 Дек 2017

flexcorejzzz, попробуй другой плагин с бОльшим функционалом и работает стабильно. https://dev-cs.ru/threads/159/
Либо жди, когда появится свободный скриптер и, возможно, посмотрит твой старенький плагин )

flexcorejzzz · 5 Дек 2017

Алексеич, у меня конфликт с statscfg_rbs.amxx, с большинство стим бонусов , сервер идёт в краш, но твой плагин попробую , но если честно Хочу свой )))

WILL_BE · 5 Дек 2017

Если так принципиален этот плагин, тестируй

Код:

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>
#include <dhudmessage>
#include <colorchat>
#include <fakemeta_util>

#define PLUGIN   "Steam Bonus"
#define VERSION   "1.2.1b"
#define AUTHOR   "by damir4ik.n"
#define PREFIX   "STEAM"

#define get_bit(%1,%2)   (%1 & (1 << (%2 & 31)))
#define set_bit(%1,%2)   (%1 |= (1 << (%2 & 31)))
#define reset_bit(%1,%2)   (%1 &= ~(1 << (%2 & 31)))

#define IGNORE_FLAGS "a"

#define STEAMBONUSROUND 3

// Цвет DHUD сообщения
#define COLOR_RED   random(255)   // Количество красного цвета
#define COLOR_GREEN   random(25) // Количество зелёного цвета
#define COLOR_BLUE   random(255)   // Количество синего цвета

#define TIME   5.0   // Время показа

new g_bIsConnected;
new g_bIsSteam;
new g_bProcedure;
new g_RoundCount;
new pistols[6] = {CSW_USP, CSW_GLOCK18, CSW_ELITE, CSW_FIVESEVEN, CSW_P228, CSW_DEAGLE} //
public plugin_init()
{
    new sPref[][] = {"awp_", "aim_", "35hp", "fy_"};
    new map[32]; get_mapname(map, charsmax(map));
    for(new i; i < sizeof sPref; i++)
    {
        if(containi(map, sPref[i]) != -1)
        {
            pause("ad");
            return;
        }
    }
  
    register_plugin(PLUGIN, VERSION, AUTHOR);

    RegisterHam(Ham_CS_RoundRespawn, "player", "fw_CS_RoundRespawn_Post", true);
    register_event("TextMsg", "eRestart", "a", "2&#Game_C", "2&#Game_w");
    register_event("HLTV","eRoundStart","a","1=0","2=0");
}

public eRestart()
{
    g_RoundCount = 0;
}

public eRoundStart()
{
    g_RoundCount++;
}

public client_putinserver(id)
{
    set_bit(g_bIsConnected, id);

    if(is_user_steam(id))
    {
        set_bit(g_bIsSteam, id);
        reset_bit(g_bProcedure, id);
        set_task(3.0, "WelcomeMessage", id);
    }
    else
        reset_bit(g_bIsSteam, id);
}

public client_disconnect(id)
    reset_bit(g_bIsConnected, id);

public WelcomeMessage(id)
{
    if(get_bit(g_bIsConnected, id))
    {
        static szName[32];
        get_user_name(id, szName, charsmax(szName));

        set_dhudmessage(COLOR_RED, COLOR_GREEN, COLOR_BLUE, -1.0, 0.5, 0, 0.0, TIME);
        show_dhudmessage(id, "Привет, %s!", szName);
        set_dhudmessage(COLOR_RED, COLOR_GREEN, COLOR_BLUE, -1.0, 0.55, 0, 0.0, TIME);
        show_dhudmessage(id, "У Вас Steam, поэтому каждый раунд Вы будете получать бонусы");
    }
}

public fw_CS_RoundRespawn_Post(id)
{
    new ignore_flags = read_flags(IGNORE_FLAGS);

    if(get_user_flags(id) & ignore_flags == ignore_flags)
        return;

    if(get_bit(g_bIsConnected, id) && get_bit(g_bIsSteam, id) && g_RoundCount > 2)
    {
        if(!get_bit(g_bProcedure, id))
        {
            new player_name[32];
            get_user_name(id, player_name, charsmax(player_name));

            ColorChat(0, RED, "^1[^4%s^1] ^3%s ^4получил бонус за стим.", PREFIX, player_name);

            switch(random_num(0, 4))
            {
                case 0:
                {
                    new TmpMoney = random_num(100, 3000);
                    cs_set_user_money(id, cs_get_user_money(id) + TmpMoney, 1);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'%d$'", PREFIX, TmpMoney);
                    set_bit(g_bProcedure, id);
                }
                case 1:
                {
                    give_item(id, "weapon_hegrenade");
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Боевая граната'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 2:
                {
                    give_item(id, "weapon_flashbang");
                    cs_set_user_bpammo(id, CSW_FLASHBANG, 2);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Слеповая граната'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 3:
                {
                    give_item(id, "item_assaultsuit");
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Броня'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 4:
                {
                    for(new i = 0; i < 6; i++) // Получаем все пистолеты из pistols[6]
                 {
                    fm_strip_user_gun(id, pistols[i]) // Отобрали пистолет
                 }
                    give_item(id, "weapon_deagle");
                    cs_set_user_bpammo(id, CSW_DEAGLE, 14);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Deagle'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
            }
        }
    }
}

stock bool:is_user_steam(id)
{
    // Author Sh0oter
    static dp_pointer
    if(dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
    {
        server_cmd("dp_clientinfo %d", id)
        server_exec()
        return (get_pcvar_num(dp_pointer) == 2) ? true : false
    }
    return true
}

Dager · 5 Дек 2017

flexcorejzzz, попробуй этого код, переписал на скорую руку, избавился от модулей лишних, только не затестил рандомную выдачу денег

C++:

#include <amxmodx>
#include <reapi>
#include <colorchat>

#define PLUGIN   "[ReAPI] Steam Bonus"
#define VERSION   "1.2.2"
#define AUTHOR   "by damir4ik.n, Dager* *.* -G-"
#define PREFIX   "STEAM"

#define get_bit(%1,%2)   (%1 & (1 << (%2 & 31)))
#define set_bit(%1,%2)   (%1 |= (1 << (%2 & 31)))
#define reset_bit(%1,%2)   (%1 &= ~(1 << (%2 & 31)))

#define IGNORE_FLAGS "a"

// Цвет DHUD сообщения
#define COLOR_RED   random(255)   // Количество красного цвета
#define COLOR_GREEN   random(25) // Количество зелёного цвета
#define COLOR_BLUE   random(255)   // Количество синего цвета

#define TIME   5.0   // Время показа
#define GIVE_ROUND   3  // с какого раунда давать бонус

new g_bIsConnected;
new g_bIsSteam;
new g_bProcedure;
new g_RoundCount;

public plugin_init()
{
    new sPref[][] = {"awp_", "aim_", "35hp", "fy_"};
    new map[32];
    rh_get_mapname(map, charsmax(map));
    for(new i; i < sizeof sPref; i++)
    {
        if(containi(map, sPref[i]) != -1)
        {
            pause("ad");
            return;
        }
    }
  
    register_plugin(PLUGIN, VERSION, AUTHOR);

    RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn", true);
    RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Pre", false);
}

public CSGameRules_RestartRound_Pre()
{
    if (get_member_game(m_bCompleteReset))
        g_RoundCount = 0;

    g_RoundCount++;
}

public client_putinserver(id)
{
    set_bit(g_bIsConnected, id);

    if(is_user_steam(id))
    {
        set_bit(g_bIsSteam, id);
        reset_bit(g_bProcedure, id);
        set_task(3.0, "WelcomeMessage", id);
    }
    else
        reset_bit(g_bIsSteam, id);
}

public client_disconnect(id)
    reset_bit(g_bIsConnected, id);

public WelcomeMessage(id)
{
    if(get_bit(g_bIsConnected, id))
    {
        static szName[32];
        get_user_name(id, szName, charsmax(szName));

        set_hudmessage(COLOR_RED, COLOR_GREEN, COLOR_BLUE, -1.0, 0.55, 0, 0.0, TIME);
        show_hudmessage(id, "Привет, %s!^nУ Вас Steam, поэтому каждый раунд Вы будете получать бонусы", szName);
    }
}

public CBasePlayer_Spawn(id)
{
    new ignore_flags = read_flags(IGNORE_FLAGS);

    if(get_user_flags(id) & ignore_flags == ignore_flags)
        return;

    if(get_bit(g_bIsConnected, id) && get_bit(g_bIsSteam, id) && g_RoundCount >= GIVE_ROUND)
    {
        if(!get_bit(g_bProcedure, id))
        {
            new player_name[32];
            get_user_name(id, player_name, charsmax(player_name));

            ColorChat(0, RED, "^1[^4%s^1] ^3%s ^4получил бонус за стим.", PREFIX, player_name);

            switch(random_num(0, 4))
            {
                case 0:
                {
                    new TmpMoney = random_num(100, 3000);
                    rg_add_account(id, TmpMoney, AS_ADD, true);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'%d$'", PREFIX, TmpMoney);
                    set_bit(g_bProcedure, id);
                }
                case 1:
                {
                    rg_give_item(id, "weapon_hegrenade", GT_APPEND);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Боевая граната'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 2:
                {
                    rg_give_item(id, "weapon_flashbang", GT_APPEND);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Слеповая граната'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 3:
                {
                    rg_set_user_armor(id, 100, ARMOR_VESTHELM);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Броня'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
                case 4:
                {
                    rg_give_item(id, "weapon_deagle", GT_REPLACE);
                    rg_set_user_bpammo(id, WEAPON_DEAGLE, 14);
                    ColorChat(id, RED, "^1[^4%s^1] ^3Бонус за steam : ^1'Deagle'", PREFIX);
                    reset_bit(g_bProcedure, id);
                }
            }
        }
    }
}

flexcorejzzz · 5 Дек 2017

Dager, WILL_BE, Ребят , большое спасибо За то что решили помочь , буду тестировать )

Minni · 5 Дек 2017

Я настолько отвык от них, что чуть не получил приступ, когда увидел...

#include <fun>
#include <cstrike>
#include <dhudmessage>
#include <colorchat>
#include <fakemeta_util>

Subb98 · 5 Дек 2017

Minni написал(а):
чуть не получил приступ, когда увидел

Здесь всё в порядке. Плохо будет, когда вы увидите в реальном проекте goto. :crazy:

flexcorejzzz · 5 Дек 2017

WILL_BE, проблема не решена , первые 3 раунда даются бонусы потом нет ..

5 Дек 2017

Dager, твой вариант не работает (

Алексеич · 5 Дек 2017

flexcorejzzz, мой вариант так и не попробовал?

Dager · 5 Дек 2017

flexcorejzzz, а знаешь почему не работает у тебя? потому что ты видимо один тестировал с админ правами, а в плагине флаг "а" игнорится, поэтому тебе ничего не дает, зайди со стима без прав и проверь еще раз. Только что проверил с ботами у меня всё работает)

flexcorejzzz · 5 Дек 2017

Dager, без админки тестировал)))

5 Дек 2017

Алексеич, вот сейчас проверяю , карта сменится)

Dager · 5 Дек 2017

flexcorejzzz, не поленился, включил сервер и проверил стоя на респе, ничего не покупая и без админ прав, скрины приложу

flexcorejzzz · 5 Дек 2017

Dager, У меня тоже админки нету , я ставлю твой плагин, в концоле пишит что плагин работает ,но на сервере никаких действий , сейчас опять поставил , карта смениться , отпишу ..

Dager · 5 Дек 2017

flexcorejzzz, поставь плагин Алексеича, он тебе дал ссылку во 2-м посте темы, думаю проблема твоя решится и функционал что выдавать там настраивается

flexcorejzzz · 5 Дек 2017

Dager, Алексеича плагин тоже не хочет работать у меня , твой плагин тоже не работает )))))

5 Дек 2017

не знаю в чём проблема у меня , знаю что стим бонусы не дружит у меня с statscfg_rbs@Dager,

Dager · 5 Дек 2017

flexcorejzzz, плагин не мой) я только чуть его переписал избавившись от модулей, а каркас плагина остался by damir4ik.n, странно почему у тебя он никак не пыхтит

Sonyx · 5 Дек 2017

если у вас оповещение о бонусе показывается, но нет самих бонусов - ищите плагин который блокирует/удаляет итемы.

flexcorejzzz · 5 Дек 2017

Sonyx, вообще нечего не происходит , почему не понятно , вот в концоле пишет плагин рабочий
[ 52] [ReAPI] Steam Bonus 1.2.2 by damir4ik.n, D steam.amxx running

Алексеич · 5 Дек 2017

flexcorejzzz, отключай все плагины, оставь один стим бонус.
потом добавляй по 10 и смотри. в итоге найдешь после нескольких смен карт плагин который влияет на выдачу бонусов

Выдаются стим бонусы только первые 2 раунда

flexcorejzzz

Вложения

Алексеич

flexcorejzzz

WILL_BE

Dager

flexcorejzzz

Minni

Subb98

flexcorejzzz

Алексеич

Dager

flexcorejzzz

Dager

Download all Attachments

flexcorejzzz

Dager

flexcorejzzz

Dager

Sonyx

flexcorejzzz

Алексеич

Пользователи, просматривающие эту тему