Only Your Info on DeathMsg 1.3

[Yek'-ta]

Yek'-ta submitted a new resource:

Only Your Info on DeathMsg - DeathMsg only for you

Read more about this resource...

 

[Yek'-ta]

Resource Only Your Info on DeathMsg has been updated:

1.1

Click on this link for update details

 

[Lunky]

Так и не понял,зачем оно надобно...

 

[Алексеич]

Lunky, Когда кто-то убивает врага, пишет вверху справа. Но если вы хотите видеть только свою информацию об убийстве и не хотите видеть информацию об убийстве других людей, вы можете использовать этот плагин.

 

[ssx]

На кс только разве что на ксдм ффа полезно где очень много игроков.

У меня много лет было так на Half-Life DM сервере, пока не перешёл на rehlds

 

[Mistrick]

#include <amxmodx>

#define PLUGIN  "Only Your Info on DM"
#define VERSION "0.1"
#define AUTHOR  "Dev-cs.ru"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_message(get_user_msgid("DeathMsg"), "msg_deathMsg")
}
public msg_deathMsg(msgid, dest, receiver)
{
    enum { arg_killer = 1, arg_victim };
    
    new killer = get_msg_arg_int(arg_killer);
    new victim = get_msg_arg_int(arg_victim);
    
    if(killer == receiver || victim == receiver) {
        return PLUGIN_CONTINUE;
    }
    
    return PLUGIN_HANDLED;
}

 

[serfreeman1337]

Mistrick, MSG_ALL (to all, receiver is 0)

 

[SergeyShorokhov]

serfreeman1337, поэтому, я сделал такой вариант.

 

[serfreeman1337]

wopox1337, nice. только зачем там цикл по игрокам, когда можно отправить всего 2 DeathMsg: для убийцы и жертвы.

 

[Mistrick]

#include <amxmodx>

#define PLUGIN  "Only Your Info on DM"
#define VERSION "0.2"
#define AUTHOR  "Dev-cs.ru"

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_message(get_user_msgid("DeathMsg"), "msg_deathMsg")
}
public msg_deathMsg(msgid, dest, receiver)
{
    enum { arg_killer = 1, arg_victim, arg_headshot, arg_weapon_name };
    
    new killer = get_msg_arg_int(arg_killer);
    new victim = get_msg_arg_int(arg_victim);
    new headshot = get_msg_arg_int(arg_headshot);
    new weapon_name[64];
    get_msg_arg_string(arg_weapon_name, weapon_name, charsmax(weapon_name));
    
    if(killer) {
        send_deathmsg(msgid, MSG_ONE, killer, killer, victim, headshot, weapon_name);
    }
    if(victim != killer) {
        send_deathmsg(msgid, MSG_ONE, victim, killer, victim, headshot, weapon_name);
    }
    return PLUGIN_HANDLED;
}

stock send_deathmsg(msgid, dest, receiver, killer, victim, headshot, weapon_name[])
{
    message_begin(dest, msgid, _, receiver);
    write_byte(killer);
    write_byte(victim);
    write_byte(headshot);
    write_string(weapon_name);
    message_end();
}

 

[Yek'-ta]

Mistrick, I tried your plugin, it is not working. Plugin doesn't write to top right.

] rcon game version
ReGameDLL version: 5.7.0.322-dev
Build date: 11:41:14 Jan 13 2019
Build from: https://github.com/s1lentq/ReGameDLL_CS/commit/7398bb7

I didn't try latest plugin.

 

[Yek'-ta]

Resource Only Your Info on DeathMsg has been updated:

Revised

Click on this link for update details

 

[Kobra]

Great plugin but could you add a command for the players to toggle the utility on / off?

 

[Noob_with_cheats]

Согласен с коброй. Плагин хороший, но возможность вкл/выкл этой функции для себя не помешало бы. Застрял на моменте отправки сообщения игрокам у которых KillFeed==false...

 

[SergeyShorokhov]

зачем там цикл по игрокам, когда можно отправить всего 2 DeathMsg: для убийцы и жертвы.

для возможности регулировки игроком индивидуально

 

[Noob_with_cheats]

Пробовал циклом и был краш. Проверка для is_user_connected() не сделал xD

для возможности регулировки игроком индивидуально

#include <amxmodx>
new KillFeed[33], plnum;
public plugin_init()
{
    register_plugin("KillFeed","1.4.0","Dev-cs.ru")
    register_message(get_user_msgid("DeathMsg"), "Message_DeathMsg")
    register_clcmd("say /kf","kill_feed");
    register_clcmd("say_team /kf","kill_feed");
}
public client_putinserver(id)
{
    KillFeed[id]=0;
}
public client_disconnected(id)
{
    KillFeed[id]=0;
}
public kill_feed(id)
{
    switch(KillFeed[id])
    {
        case 0: 
        {
            KillFeed[id]=1
            client_print_color(id, print_team_red,"[^3KillFeed^1] ^4ON")
        }
        case 1:
        {
            KillFeed[id]=2
            client_print_color(id, print_team_red,"[^3KillFeed^1] ^4OFF ALL")
        }
        case 2:
        {
            KillFeed[id]=0
            client_print_color(id, print_team_red,"[^3KillFeed^1] ^4OFF")
        }
    }
}
public Message_DeathMsg(msgid, dest, receiver)
{
    enum {arg_killer = 1, arg_victim, arg_headshot, arg_weapon_name };
    new killer = get_msg_arg_int(arg_killer);
    new victim = get_msg_arg_int(arg_victim);
    new headshot = get_msg_arg_int(arg_headshot);
    new weapon_name[64];
    get_msg_arg_string(arg_weapon_name, weapon_name, charsmax(weapon_name));
    
    if(killer && KillFeed[killer] == 1)
        send_deathmsg(msgid, MSG_ONE, killer, killer, victim, headshot, weapon_name)
    if(victim != killer && KillFeed[victim] == 1)
        send_deathmsg(msgid, MSG_ONE, victim, killer, victim, headshot, weapon_name)
    plnum = get_playersnum(0)
    for(new id=1; id <= plnum; id++)
    {
        if(is_user_connected(id))
        {
            if(KillFeed[id]==0)
                send_deathmsg(msgid, MSG_ONE, id, killer, victim, headshot, weapon_name)
        }
    }
    return PLUGIN_HANDLED;
}
stock send_deathmsg(msgid, dest, receiver, killer, victim, headshot, weapon_name[])
{
    message_begin(dest, msgid, _, receiver);
    write_byte(killer);
    write_byte(victim);
    write_byte(headshot);
    write_string(weapon_name);
    message_end();
}