Лучший игрок раунда проблема :/

ulala · 27 Июл 2019

Добрый вечер , может найдется человек который разбирается в плагинах и поможет исправить данную проблему в плагине ,))

Суть плагина: Плагин выводит инфу в чат о лучшем игроке раунда.
Проблема: Урон каторый нанёс игрок выводется всегда [ 0 ] хотя допустим я набил 200 урона :/
P.S пробывал ставить плагин выше других.

Mistrick · 27 Июл 2019

Главная проблема, инициализация переменной в цикле с одинаковым именем глобальной.
Рандом никогда не выберет последний вариант бонуса.
Эвент Damage вызывается позже конца раунда, в итоге можно было пропустить урон.

Код:

// *************************************************************************************//
// Плагин загружен с  www.neugomon.ru                                                   //
// Автор: Neygomon  [ https://neugomon.ru/members/1/ ]                                  //
// Официальная тема поддержки: https://neugomon.ru/threads/276/                         //
// При копировании материала ссылка на сайт www.neugomon.ru ОБЯЗАТЕЛЬНА!                //
// *************************************************************************************//

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>

enum _:DATA { Bonus[32], Num }
new const g_aBonuses[][DATA] =
{
    { "weapon_ak47",     60 },    // оружие | патроны
    { "addarmor",         100 },    // броня | кол-во
    { "addhealth",         30 },    // хп | кол-во
    { "addmoney",         1000}    // деньги | кол-во
}

new g_iDamage[33];
new g_iBestDamage, g_iBestPlayer;
#if AMXX_VERSION_NUM < 183
    new MaxClients;
    #define client_disconnected client_disconnect
#endif

public plugin_init()
{
    register_plugin("BestPlayer", "1.3-fixed", "neygomon");

    register_event("HLTV", "LeRoundStart", "a", "1=0", "2=0");
    
    RegisterHam(Ham_Spawn, "player", "fwdPlayerSpawnPost", true);
    register_event("Damage", "eventDamage", "b", "2!0");
#if AMXX_VERSION_NUM  < 183   
    MaxClients = get_maxplayers();
#endif   
}

public client_disconnected(id)
{
    if(g_iBestPlayer == id)
        g_iBestPlayer = 0;
    
    g_iDamage[id] = 0;
}

public fwdPlayerSpawnPost(const pClient)
{
    if(g_iBestPlayer != pClient)
        return;
    if(!is_user_alive(pClient))
        return;
    
    new name[32]; get_user_name(pClient, name, charsmax(name));
    new bonus = random(sizeof(g_aBonuses));
    
    if(g_aBonuses[bonus][Bonus][0] == 'w' && g_aBonuses[bonus][Bonus][6] == '_')
    {
        give_item(pClient, g_aBonuses[bonus][Bonus]);
        if(g_aBonuses[bonus][Num] > 0) cs_set_user_bpammo(pClient, get_weaponid(g_aBonuses[bonus][Bonus]), g_aBonuses[bonus][Num]);
        
        ChatColor("^1[^4MVP^1] ^4Žaidėjas ^3%s ^4tapo ^3round ^4MVP! ^3(%d)^4dmg. Bonus ^1- ^3%s", name, g_iBestDamage, g_aBonuses[bonus][Bonus][7]);
    }
    else if(!strcmp(g_aBonuses[bonus][Bonus], "addarmor") && g_aBonuses[bonus][Num] > 0)
    {
        cs_set_user_armor(pClient, g_aBonuses[bonus][Num], CS_ARMOR_VESTHELM);
        ChatColor("^1[^4MVP^1] ^4Žaidėjas ^3%s ^4tapo ^3round ^4MVP! ^3(%d)^4dmg. Bonus ^1- ^3%d Armor", name, g_iBestDamage, g_aBonuses[bonus][Num]);
    }   
    else if(!strcmp(g_aBonuses[bonus][Bonus], "addhealth") && g_aBonuses[bonus][Num] > 0)
    {
        set_user_health(pClient, get_user_health(pClient) + g_aBonuses[bonus][Num]);
        ChatColor("^1[^4MVP^1] ^4Žaidėjas ^3%s ^4tapo ^3round ^4MVP! ^3(%d)^4dmg. Bonus ^1- ^3%d HP", name, g_iBestDamage, g_aBonuses[bonus][Num]);
    }
    else if(!strcmp(g_aBonuses[bonus][Bonus], "addmoney") && g_aBonuses[bonus][Num] > 0)
    {
        cs_set_user_money(pClient, cs_get_user_money(pClient) + g_aBonuses[bonus][Num]);
        ChatColor("^1[^4MVP^1] ^4Žaidėjas ^3%s ^4tapo ^3round ^4MVP! ^3(%d)^4dmg. Bonus ^1- ^3%d $", name, g_iBestDamage, g_aBonuses[bonus][Num]);
    }
    g_iBestPlayer = 0;
}

public eventDamage(id)
{
    static attacker; attacker = get_user_attacker(id);
    if(1 <= attacker <= MaxClients && id != attacker)
        g_iDamage[attacker] += read_data(2);
}

public LeRoundStart()
{
    new players[32], pnum; get_players(players, pnum, "h");
    g_iBestDamage = 0;
    for(new i; i < pnum; i++)
    {
        if(g_iDamage[players[i]] > g_iBestDamage)
        {
            g_iBestDamage = g_iDamage[players[i]];
            g_iBestPlayer = players[i];
        }
    }
    arrayset(g_iDamage, 0, sizeof g_iDamage);
}

stock ChatColor(const szMessage[], any:...)
{
    new szMsg[190];
    vformat(szMsg, charsmax(szMsg), szMessage, 2);
    message_begin(MSG_ALL, 76, .player = 0);
    write_byte(g_iBestPlayer);
    write_string(szMsg);
    message_end();
}

Лучший игрок раунда проблема :/

ulala

Mistrick

Пользователи, просматривающие эту тему