Поиск Плагин Damager+combo

[Krikkk]

Добрый день, помогите найти такой плагин, если конечно есть
Суть плагина: Показывает нанесенный урон по врагу + общую серию или комбо урона, нанесенного по врагам

 

[To_be_or_not_to_be]

Krikkk, в любой плагин для отображения урона добавляете переменную для каждого игрока и суммируете в неё каждый урон.
Вместе с обычным уроном также выводите значение этой переменной

ps Ну или у Виталия попросите плагин (владельца этого сервера)

 

[Krikkk]

Krikkk, в любой плагин для отображения урона добавляете переменную для каждого игрока и суммируете в неё каждый урон.
Вместе с обычным уроном также выводите значение этой переменной

ps Ну или у Виталия попросите плагин (владельца этого сервера)

если не сложно, можете сделать?) Заранее спасибо

 

[steelzzz]

Krikkk,

#include <amxmodx>
#include <reapi>

new const PLUGIN_NAME[] = "[ReAPI] Combo Damager";
new const PLUGIN_VERSION[] = "0.0.0";

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

new Float: g_fTotalDamage[MAX_PLAYERS+1];
new g_HudSyncMessage;

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, "AddAnyAuthor");

    RegisterHookChain(RG_CBasePlayer_TakeDamage, "CPlayer_TakeDamage_Post", .post = true);
    RegisterHookChain(RG_CSGameRules_PlayerKilled, "CPlayer_Killed_Post", .post = true);

    g_HudSyncMessage = CreateHudSyncObj();
}

public client_disconnected(iPlayer)
{
    g_fTotalDamage[iPlayer] = 0.0;
}

public CPlayer_Killed_Post(iVictim, iKiller, iInflictor)
{
    g_fTotalDamage[iVictim] = 0.0;
}

public CPlayer_TakeDamage_Post(iVictim, iInflictor, iAttacker, Float:flDamage, iBitsDamageType)
{
    if(!is_user_connected(iAttacker) || flDamage <= 0.0 || !rg_is_player_can_takedamage(iVictim, iAttacker) || iVictim == iAttacker)
    {
        return;
    }

    if(iBitsDamageType & DMG_BLAST)
    {
        return;
    }

    g_fTotalDamage[iAttacker] += flDamage;
    
    set_hudmessage(30, 114, 255, -1.0, 0.55, 0, 0.1, 2.5, 0.02, 0.02, -1);
    ShowSyncHudMsg(iAttacker, g_HudSyncMessage, "%.0f [Комбо: %.0f]", flDamage, g_fTotalDamage[iAttacker]);
}

Я не скриптер, но работать должно

 

[twisterniq]

steelzzz, почти. Комбо-то не сбрасывается если не стрелять. Но в принципе автор не говорил об этом но скорее всего ему именно это и нужно, если учесть что скрин сделан на сервере где так и сделано.

 

[Krikkk]

steelzzz, почти. Комбо-то не сбрасывается если не стрелять. Но в принципе автор не говорил об этом но скорее всего ему именно это и нужно, если учесть что скрин сделан на сервере где так и сделано.

Я это как раз забыл упомянуть(((( Надо чтобы сбрасывалось, а так все работает

 

[steelzzz]

Krikkk,

#include <amxmodx>
#include <reapi>

new const PLUGIN_NAME[] = "[ReAPI] Combo Damager";
new const PLUGIN_VERSION[] = "0.0.1";

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

#define COMBO_TIME 5.0

new Float: g_fTotalDamage[MAX_PLAYERS+1];
#if defined COMBO_TIME
    new Float: g_fDelayTime[MAX_PLAYERS+1];
#endif
new g_HudSyncMessage;

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, "AddAnyAuthor");

    RegisterHookChain(RG_CBasePlayer_TakeDamage, "CPlayer_TakeDamage_Post", .post = true);
    RegisterHookChain(RG_CSGameRules_PlayerKilled, "CPlayer_Killed_Post", .post = true);

    g_HudSyncMessage = CreateHudSyncObj();
}

public client_disconnected(iPlayer)
{
    g_fTotalDamage[iPlayer] = 0.0;
#if defined COMBO_TIME  
    g_fDelayTime[iPlayer] = 0.0;
#endif
}

public CPlayer_Killed_Post(iVictim, iKiller, iInflictor)
{
    g_fTotalDamage[iVictim] = 0.0;
#if defined COMBO_TIME
    g_fDelayTime[iVictim] = 0.0; // ?
#endif
}

public CPlayer_TakeDamage_Post(iVictim, iInflictor, iAttacker, Float:flDamage, iBitsDamageType)
{
    if(!is_user_connected(iAttacker) || flDamage <= 0.0 || !rg_is_player_can_takedamage(iVictim, iAttacker) || iVictim == iAttacker)
    {
        return;
    }

    if(iBitsDamageType & DMG_BLAST)
    {
        return;
    }

#if defined COMBO_TIME
    if(g_fDelayTime[iAttacker] <= get_gametime())
    {
        g_fDelayTime[iAttacker] = 0.0;
        g_fTotalDamage[iAttacker] = 0.0;
    }
#endif
    g_fTotalDamage[iAttacker] += flDamage;
   
    set_hudmessage(30, 114, 255, -1.0, 0.55, 0, 0.1, 2.5, 0.02, 0.02, -1);
    ShowSyncHudMsg(iAttacker, g_HudSyncMessage, "%.0f [Комбо: %.0f]", flDamage, g_fTotalDamage[iAttacker]);
#if defined COMBO_TIME
    g_fDelayTime[iAttacker] = get_gametime() + COMBO_TIME;
#endif
}

#define COMBO_TIME 5.0 - закомментируйте (//), если хотите выкл автообнуление через n-сек.
Насчет этого, я точно не уверен.

 

[twisterniq]

steelzzz, зачем 69 строка?

 

[steelzzz]

w0w, случайно

 

[Krikkk]

с@steelzzz, спасибо!!!!