Плагин refill_weapon_on_kill выдает ошибку.

Incubus · 20 Янв 2019

В консоле сервера постоянно пишет ошибку работы плагина:
L 01/19/2019 - 22:53:46: [ReAPI] rg_get_iteminfo: invalid entity index -1 [arg_index]
L 01/19/2019 - 22:53:46: [AMXX] Displaying debug trace (plugin "refill_weapon_on_kill.amxx", version "0.2")
L 01/19/2019 - 22:53:46: [AMXX] Run time error 10: native error (native "rg_get_iteminfo")
L 01/19/2019 - 22:53:46: [AMXX] [0] refill_weapon_on_kill.sma::ReloadWeapons (line 65)
L 01/19/2019 - 22:53:46: [AMXX] [1] refill_weapon_on_kill.sma::CSGameRules_DeathNotice (line 53)

Компилировал последним компилятором, локально. Не пойму в чем проблема.
Но плагин все равно работает, только на сервере постоянно эту ошибку выдает.

fantom · 21 Янв 2019

Код:

// Copyright 2019 Vaqtincha

/**■■■■■■■■■■■■■■■■■■■■■■■■■■■■ CONFIG START ■■■■■■■■■■■■■■■■■■■■■■■■■■■■*/

// Рас/Комментировать чтобы вкл/выкл нужный функционал.

#define HEADSHOT_KILL_REFILL_ALL // Перезаряжать все оружие при убийстве хедшотом.
#define GRENADE_KILL_REFILL_ALL // Перезаряжать все оружие при убийстве гранатой.

#define ONLY_ACTIVE_WEAPON // Перезаряжать только активного оружие которого совершено убийство.
#define ONLY_REFILL_CLIP // Перезаряжать только магазин (или магазин+запасы.)

/**■■■■■■■■■■■■■■■■■■■■■■■■■■■■■ CONFIG END ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■*/

#define PL_VERSION     "0.2"

#include <amxmodx>
#include <reapi>

public plugin_init()
{
    register_plugin("Refill Weapon On Kill", PL_VERSION, "Vaqtincha")
    RegisterHookChain(RG_CSGameRules_DeathNotice, "CSGameRules_DeathNotice", .post = true)
}

public CSGameRules_DeathNotice(const pPlayer, const pKiller, pevInflictor)
{
    if (pPlayer == pKiller || !is_user_alive(pKiller))
        return HC_CONTINUE

    if (pKiller == pevInflictor)
    {
#if defined HEADSHOT_KILL_REFILL_ALL
        if (get_member(pPlayer, m_bHeadshotKilled))
        {
            ReloadWeapons(pKiller, pevInflictor)
            return HC_CONTINUE
        }
#endif
#if defined ONLY_ACTIVE_WEAPON
        pevInflictor = get_member(pKiller, m_pActiveItem)

        if (!is_nullent(pevInflictor))
            ReloadWeapons(pKiller, pevInflictor)
#else
        ReloadWeapons(pKiller)
#endif
        return HC_CONTINUE
    }
#if defined GRENADE_KILL_REFILL_ALL
    else if (FClassnameIs(pevInflictor, "grenade"))
    {
        ReloadWeapons(pKiller)
    }
#endif
    return HC_CONTINUE
}


ReloadWeapons(const pPlayer, const pWeapon = NULLENT)
{
    if (pWeapon == NULLENT)
    {
#if defined ONLY_REFILL_CLIP
        for (new InventorySlotType:i = PRIMARY_WEAPON_SLOT, pItem; i <= PISTOL_SLOT; i++)
        {
            pItem = get_member(pPlayer, m_rgpPlayerItems, i)

            while (!is_nullent(pItem))
            {
                set_member(pItem, m_Weapon_iClip, rg_get_iteminfo(pItem, ItemInfo_iMaxClip))
        
                pItem = get_member(pItem, m_pNext)
            }
        }
#else
        rg_instant_reload_weapons(pPlayer)
#endif
    }
    else
    {
#if defined ONLY_REFILL_CLIP
        set_member(pWeapon, m_Weapon_iClip, rg_get_iteminfo(pWeapon, ItemInfo_iMaxClip))
#else       
        rg_instant_reload_weapons(pPlayer, pWeapon)
#endif
    }
}

Incubus · 21 Янв 2019

Спасибо! Еще подскажите пожалуйста, в консоле сервера постоянно высвечивается надпись:
MasterRequestRestart
Your server needs to be restarted in order to receive the latest update.

Хотя все последнее установлено. Как решить подскажите пожалуйста.

Tranquillity · 21 Янв 2019

Incubus, одна тема = одна проблема/вопрос.

Плагин refill_weapon_on_kill выдает ошибку.

Incubus

fantom

Incubus

Tranquillity

Пользователи, просматривающие эту тему