Models AK not show

Статус
В этой теме нельзя размещать новые ответы.
T

trendafili

Сообщения
43
Реакции
0
Hello im using one plugin for skins but when i write and i change AK47 skin. The skin not show directly but i need to go in knife or in grenade and to back again in weapons to see new skin witch i choose. Do you know anybody how can i fixed when i choose new skin ak47 to show directly?

Код: 
#include <amxmodx>
#include <cstrike>
#include <cromchat>

new const PLUGIN[] = "Ak47 Menu";
new const VERSION[] = "1.2.1";
new const AUTHOR[] = "RevCrew";

new const AKModels[][] =
{
    "models/v_ak47.mdl",
    "models/mpgskins/mpg-ak47/version1/v_ak47.mdl",
    "models/mpgskins/mpg-ak47/version2/v_ak47.mdl",
    "models/mpgskins/mpg-ak47/version3/v_ak47.mdl",
    "models/mpgskins/mpg-ak47/version4/v_ak47.mdl"
};

new const AKMenuNames[][] =
{
    "Ak47 [DEFAUT]",
    "Ak47 Rat Rod",
    "Ak47 Fade",
    "Ak47 Fuel Injector",
    "Ak47 Ice Coaled"
};

new AK[33];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("say /ak","AkMenu");
    register_event("CurWeapon", "CurentWeapon", "be", "1=1");
}

public plugin_precache()
{
    for(new i; i < sizeof AKModels; i++)
    {
        precache_model(AKModels[i]);
    }
}

public MenuAk(id)
{
    new menu = menu_create("\yMPG Skin \rAk47 Menu", "AkCase")
    
    menu_additem(menu, "Ak47 \r[DEFAUT]^n", "1", 0)
    menu_additem(menu, "\wAk47 \yRat Rod", "2", 0)
    menu_additem(menu, "\wAk47 \yFade", "3", 0)
    menu_additem(menu, "\wAk47 \yFuel Injector", "4", 0)
    menu_additem(menu, "\wAk47 \yIce Coaled", "5", 0)
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
    menu_display(id, menu, 0 );
    
    return 1;
}

public AkCase(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        return 1;
    }
    new nick[33]; get_user_name(id, nick, 32);
    AK[id] = item;
    CC_SendMessage(id, "&x04%s &x01Ju zgjodhet &x04%s &x01si AK47 tuaj!", nick, AKMenuNames[item]);
    
    menu_destroy (menu);
    return 1;
}

public CurentWeapon(id)
{
    if(get_user_weapon(id) == CSW_AK47)
    {
        set_pev(id, pev_viewmodel2, AKModels[AK[id]]);
    }
}

public AkMenu(id)
{
    if(is_user_alive(id))
    {
        MenuAk(id);
    }else{
        MenuAk(id);
    }
}
 
Code_0xABC

Code_0xABC

Сообщения
1,082
Реакции
58
Помог
11 раз(а)
Код: 
/*add*/#include <hamsandwich>
/*add*/#include <reapi>

public AkCase(const id, const menu, const item)
{
    /*add*/menu_destroy (menu);

    if(item != MENU_EXIT) {
        AK[id] = item;

        CC_SendMessage(id, "&x04%n &x01Ju zgjodhet &x04%s &x01si AK47 tuaj!", id, AKMenuNames[item]);
        /*add*/rg_give_item(id, "weapon_ak47", GT_REPLACE);
        /*add*/set_pev(id, pev_viewmodel2, AKModels[item]);
    }

    return PLUGIN_HANDLED;
}
И наверное всё-таки так надо
Код: 
public AkMenu(const id)
{
    if(is_user_alive(id))
        MenuAk(id);
}
 
Последнее редактирование:
T

trendafili

Сообщения
43
Реакции
0
Code_0xABC написал(а):
Код: 
/*add*/#include <hamsandwich>
/*add*/#include <reapi>

public AkCase(const id, const menu, const item)
{
    /*add*/menu_destroy (menu);

    if(item != MENU_EXIT) {
        AK[id] = item;

        CC_SendMessage(id, "&x04%n &x01You got &x04%s &x01you got AK47!", id, AKMenuNames[item]);
        /*add*/rg_give_item(id, "weapon_ak47", GT_REPLACE);
        /*add*/set_pev(id, pev_viewmodel2, AKModels[item]);
    }

    return PLUGIN_HANDLED;
}
And it’s probably still necessary
Код: 
public AkMenu(const id)
{
    if(is_user_alive(id))
        Menus(id);
}
Нажмите для раскрытия...
Hey bro, if you can edit all because its very complicated. And i tell you i use and one other plugin to show menu this is for ak47
 
Code_0xABC

Code_0xABC

Сообщения
1,082
Реакции
58
Помог
11 раз(а)
trendafili,
Код: 
#include <amxmodx>
#include <hamsandwich>
#include <reapi>

enum any:DATA {MODEL[64], NAME[64]};

new const g_eModel[5][DATA] = {
    {"",                                             "Ak47 [DEFAUT]"},
    {"models/mpgskins/mpg-ak47/version1/v_ak47.mdl", "Ak47 Rat Rod"},
    {"models/mpgskins/mpg-ak47/version2/v_ak47.mdl", "Ak47 Fade"},
    {"models/mpgskins/mpg-ak47/version3/v_ak47.mdl", "Ak47 Fuel Injector"},
    {"models/mpgskins/mpg-ak47/version4/v_ak47.mdl", "Ak47 Ice Coaled"}
};

new
    g_pMenu,
    g_pAk[MAX_PLAYERS +1];

public plugin_init() {
    register_plugin("Ak47 Menu", "1.2.2", "RevCrew");

    register_clcmd("say /ak", "DISPLAY_Menu");
    RegisterHam(Ham_Item_Deploy, "weapon_ak47", "Ham_Item_Deploy_Post", true);

    CREATE_Menu();
}

public plugin_precache() {
    for(new i = 1; i < sizeof g_eModel; ++i)
        precache_model(g_eModel[i][MODEL]);
}

public client_disconnected(id)
    g_pAk[id] = 0;

CREATE_Menu() {
    g_pMenu = menu_create("\yMPG Skin \rAk47 Menu", "HANDLER_Menu");

    for(new i; i < sizeof g_eModel; ++i)
        menu_additem(g_pMenu, g_eModel[i][NAME], fmt("%i", i +1));

    menu_setprop(g_pMenu, MPROP_EXITNAME, "Exit");
}

public DISPLAY_Menu(const id) {
    menu_display(id, g_pMenu);

    return PLUGIN_HANDLED;
}

public HANDLER_Menu(const id, const pMenu, const item){
    if(item != MENU_EXIT) {
        if(is_user_alive(id)) {
            rg_give_item(id, "weapon_ak47", GT_REPLACE);
            set_entvar(id, var_viewmodel, g_eModel[item][MODEL]);
        }

        client_print_color(id, id, "^4%n ^1Ju zgjodhet ^4%s ^1si AK47 tuaj!", id, AKMenuNames[item]);
        g_pAk[id] = item;
    }
}

public Ham_Item_Deploy_Post(const entWeapon) { 
    new id = get_member(entWeapon, m_pPlayer);

    if (id < 1 || id > MaxClients) 
        return HAM_IGNORED;
    
    if(get_user_weapon(id) != CSW_AK47)
        return HAM_IGNORED;

    new pAk = g_pAk[id];

    if(pAk)
        set_entvar(id, var_viewmodel, g_eModel[pAk][MODEL]);

    return HAM_IGNORED;
}
 
Последнее редактирование:
T

trendafili

Сообщения
43
Реакции
0
Code_0xABC написал(а):
trendafili,
Код: 
#include <amxmodx>
#include <hamsandwich>
#include <reapi>

enum any:DATA {MODEL[64], NAME[64]};

new const g_eModel[5][DATA] = {
    {"models/v_ak47.mdl",                            "Ak47 [DEFAUT]"},
    {"models/mpgskins/mpg-ak47/version1/v_ak47.mdl", "Ak47 Rat Rod"},
    {"models/mpgskins/mpg-ak47/version2/v_ak47.mdl", "Ak47 Fade"},
    {"models/mpgskins/mpg-ak47/version3/v_ak47.mdl", "Ak47 Fuel Injector"},
    {"models/mpgskins/mpg-ak47/version4/v_ak47.mdl", "Ak47 Ice Coaled"}
};

new
    g_pMenu,
    g_pAk[MAX_PLAYERS +1];

public plugin_init() {
    register_plugin("Ak47 Menu", "1.2.2", "RevCrew");

    register_clcmd("say /ak", "DISPLAY_Menu");
    RegisterHam(Ham_Item_Deploy, "weapon_ak47", "Ham_Item_Deploy_Post", true);

    CREATE_Menu();
}

public plugin_precache() {
    for(new i = 1; i < sizeof g_eModel; ++i)
        precache_model(g_eModel[i][MODEL]);
}

public client_disconnected(id)
    g_pAk[id] = 0;

CREATE_Menu() {
    g_pMenu = menu_create("\yMPG Skin \rAk47 Menu", "HANDLER_Menu");

    for(new i; i < sizeof g_eModel; ++i)
        menu_additem(g_pMenu, g_eModel[i][NAME], fmt("%i", i +1));

    menu_setprop(g_pMenu, MPROP_EXITNAME, "Exit");
}

public DISPLAY_Menu(const id) {
    menu_display(id, g_pMenu);

    return PLUGIN_HANDLED;
}

public HANDLER_Menu(const id, const pMenu, const item){
    if(item != MENU_EXIT) {
        if(is_user_alive(id)) {
            rg_give_item(id, "weapon_ak47", GT_REPLACE);
            set_entvar(id, var_viewmodel, g_eModel[item][MODEL]);
        }

        client_print_color(id, id, "^4%n ^1Ju zgjodhet ^4%s ^1si AK47 tuaj!", id, AKMenuNames[item]);
        g_pAk[id] = item;
    }
}

public Ham_Item_Deploy_Post(const entWeapon) {
    new id = get_member(entWeapon, m_pPlayer);

    if(get_user_weapon(id) != CSW_AK47)
        return HAM_IGNORED;

    new pAk = g_pAk[id];

    if(pAk)
        set_entvar(id, var_viewmodel, g_eModel[pAk][MODEL]);

    return HAM_IGNORED;
}
Нажмите для раскрытия...
Thank you very much bro, and one question its not problem or change anything here now with your update because this working together :
Код: 
#include <amxmodx>
#include <cstrike>

#pragma tabsize 0

new nightvisionOverrideActive[33];

public plugin_init()
{
    register_plugin("Skins", "1.0.2", "RevCrew")
    register_clcmd("say /skins", "GameMenu")
    register_clcmd("nightvision", "nightvision")
}
public nightvision(id)
{
    if (nightvisionOverrideActive[id])
    {
        GameMenu(id)
        return PLUGIN_HANDLED;
    }
    nightvisionOverrideActive[id] = true
    return PLUGIN_CONTINUE;
}
public client_putinserver(id)
{
    nightvisionOverrideActive[id] = true
}

public GameMenu(id)
{
    new menu = menu_create("\y© \rMPG \wSkin Menu", "menu_case")
    
    menu_additem(menu, "\yKnife \wMenu", "1", 0)
    menu_additem(menu, "\yAwp \wMenu", "2", 0)
    menu_additem(menu, "\yAk47 \wMenu", "3", 0)
    menu_additem(menu, "\yM4a1 \wMenu", "4", 0)
    menu_additem(menu, "\yDeagle \wMenu", "5", 0)
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
    menu_display(id, menu, 0)
}

public menu_case(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    new data[6], iName[64]
    new acces, callback
    menu_item_getinfo(menu, item, acces, data,5, iName, 63, callback)
    new key = str_to_num(data)
    
    switch(key){
    
    case 1: client_cmd(id,"say /knife")
    case 2: client_cmd(id,"say /awp")
    case 3: client_cmd(id,"say /ak")
    case 4: client_cmd(id,"say /m4")
    case 5: client_cmd(id,"say /dgl")
    }
    menu_destroy(menu)
    return PLUGIN_HANDLED
}
 
Code_0xABC

Code_0xABC

Сообщения
1,082
Реакции
58
Помог
11 раз(а)
trendafili, я немного подправил, убрал с кеширования стандартную модель. Изменения внёс в последнем моем посте.
'Ничего не изменит здесь сейчас с твоим обновлением?' - нет!
 
Code_0xABC

Code_0xABC

Сообщения
1,082
Реакции
58
Помог
11 раз(а)
trendafili, это уже тебе решать, плодить плагины или сделать всё в одном плагине, меняя в меню выбора оружия и например через форвард передать строку с именем нужного тебе оружия. Или получать аргумет введенной команды игроком и отталкиваться от этого, что ввел игрок.
 
Последнее редактирование:
T

trendafili

Сообщения
43
Реакции
0
Code_0xABC написал(а):
trendafili, это уже тебе решать, плодить плагины или сделать всё в одном плагине, меняя в меню выбора оружия и например через форвард передать строку с именем нужного тебе оружия.
Нажмите для раскрытия...
Я хотел использовать плагин, но не знаю, как это сделать, если бы это было возможно с 1 плагином, это идеально
У меня есть это оружие АК47, М4А1, НОЖ, AWP, ГАЛИЛ, ФАМАС, ДЕАГЛ,
 
Code_0xABC

Code_0xABC

Сообщения
1,082
Реакции
58
Помог
11 раз(а)
trendafili, нодо загуглить, если я не ошибаюсь реализаций такого типа валом и ты учти, данным сбособом ты меняешь модель игроку от первого лица, а если игрок смотрит, то будет отображаться стандартная модель, если модель лежит на земле, тоже стандартная модель. Напиши в поиске и должен найти я думаю много решений
 
T

trendafili

Сообщения
43
Реакции
0
Code_0xABC написал(а):
trendafili, нодо загуглить, если я не ошибаюсь реализаций такого типа валом и ты учти, данным сбособом ты меняешь модель игроку от первого лица, а если игрок смотрит, то будет отображаться стандартная модель, если модель лежит на земле, тоже стандартная модель. Напиши в поиске и должен найти я думаю много решений
Нажмите для раскрытия...
Пробовал в гугле но не могу найти решение, у меня есть модели v, p, w но в плагине только v
В любом случае, я вручную установлю все остальные плагины, которые вы отредактировали, мне делать нечего. Большое спасибо
 
Статус
В этой теме нельзя размещать новые ответы.

Пользователи, просматривающие эту тему

Сейчас на форуме нет ни одного пользователя.
Всего: 1 (пользователей: 0, гостей: 1)
Сверху Снизу