set_entvar, var_health

[alabamaster1337]

Что не так с выдачей hp, вид на бок переворачивается и оставляет 1хп

#include <amxmodx>
#include <reapi>

#define FLAG_ACCESS ADMIN_LEVEL_H

#define GIVE_GRENADES // гранаты
#define GIVE_DEAGLE // дигл
#define GIVE_HEALTH // жизни
#define GIVE_ARMOR // броня
#define CUSTOM_MODELS // кастомные модели

#define HOW_HEALTH 228 // сколько жизней
#define HOW_ARMOR 228 // сколько брони

#if defined CUSTOM_MODELS
    #include <cstrike>

    new const MODEL_TT[] = "slum" // модель тт
    new const MODEL_CT[] = "slum" // модель кт

    public plugin_precache()
    {
        new szBuffer[128]
        formatex(szBuffer, charsmax(szBuffer), "models/player/%s/%s.mdl", MODEL_CT, MODEL_CT)
        precache_model(szBuffer)
        formatex(szBuffer, charsmax(szBuffer), "models/player/%s/%s.mdl", MODEL_TT, MODEL_TT)
        precache_model(szBuffer)
    }
#endif

public plugin_init() {   
    register_plugin("vip bonuses", "0.1", "alabamaster1337")

    RegisterHookChain(RG_CBasePlayer_Spawn, "HC_CBasePlayer_Spawn_Post", true)
}

public HC_CBasePlayer_Spawn_Post(id){
    if(is_user_bot(id) || is_user_hltv(id)){
        return
    }

    if(is_user_alive(id) && get_user_flags(id) & FLAG_ACCESS){
    #if defined GIVE_GRENADES
        rg_give_item(id, "weapon_flashbang")
        rg_give_item(id, "weapon_flashbang")
        rg_give_item(id, "weapon_hegrenade")
        rg_give_item(id, "weapon_smokegrenade")
    #endif
    #if defined GIVE_DEAGLE
        rg_give_item(id, "weapon_deagle", GT_REPLACE)
        rg_set_user_bpammo(id, WEAPON_DEAGLE, 35)
    #endif
    #if defined GIVE_HEALTH
        set_entvar(id, var_health, HOW_HEALTH)
    #endif
    #if defined GIVE_ARMOR
        rg_set_user_armor(id, HOW_ARMOR, ARMOR_VESTHELM)
    #endif
    #if defined CUSTOM_MODELS
        if(cs_get_user_team(id)==CS_TEAM_T)
        {
            rg_set_user_model(id, MODEL_TT)
        }
        if(cs_get_user_team(id)==CS_TEAM_CT)
        {
            rg_set_user_model(id, MODEL_CT)
        }
    #endif
    }
}

 

[Faktor]

    /*
    * Description:      -
    * Member type:      float
    * Get params:       Float:get_entvar(index, EntVars:var);
    * Set params:       set_entvar(index, EntVars:var, Float:value);
    */
    var_health,

var_health это дробное значение.
HOW_HEALTH 228==>228.0

 

[alabamaster1337]

Droads, действительно, спасибо