Мигает DHUD

Kioo · 26 Июл 2023

Всем привет. Мигает DHUD на сервере. Поискал решение и в основном предполагают, что ошибка может заключаться в забитом канале. Но у меня на сервере также стоит плагин с похожим функционалом и он работает отлично. Статично выводит сообщение, без каких либо мерцаний (естественно, при включении первого (не рабочего), я его отключал, чтобы не было конфликта).
Уже ставил в конце set_dhudmessage "-1", "false" и т.д. В решении проблемы это не помогло.
Предполагаю, что дело в способе, каким выводить. Пытался сделать вывод по примеру рабочего плагина, но были ошибки в компиляции или сервер просто крашился и я отбросил эту затею.
Для сравнения прикреплю ниже плагин с dhud, который прекрасно работает.

Albertio · 26 Июл 2023

Плагин полное дерьмище(про кодстайл вообще молчу). Используется DHUD который я лично бы не советовал использовать, так еще и вдобавок не очищаются каналы. Есть классный синхронизированный HUD, используйте его и не будете знать бед.

Kioo · 26 Июл 2023

Albertio, дело в том, что я искал плагин, который мне нужен был для конкретной цели. По функциям тот плагин подошел и я попытался "что-то" с ним сделать и как-то его использовать.
Если бы я точно знал, как сделать классный худ, который будет отображать то, что мне нужно, то не прибегал бы к этому, но это уже другая история. А так, я понимаю, какой это древний плагин, ведь брал я его с бородатых тем форумов)
В общем, смысла что-то намудрить с ним - нет от слова совсем, я понял, спасибо)

Albertio · 26 Июл 2023

Kioo, накидал на скорую руку

Код:

#include <amxmodx>
#include <reapi>

#define TS_TASK_ID 123321

new g_iHudSyncObj;

public plugin_init() {
    register_plugin("Team Score", "0.0.1", "Albertio");

    g_iHudSyncObj = CreateHudSyncObj();

    set_task(1.0, "ShowScoreHud", TS_TASK_ID, .flags = "b");
}

public ShowScoreHud(id) {
    static iAliveTTs, iAliveCTs;
    rg_initialize_player_counts(iAliveTTs, iAliveCTs);

    new szHudText[64];
    formatex(szHudText, charsmax(szHudText),
        "TT(%d): %d | Round: %d | CT(%d): %d",
        iAliveTTs, get_member_game(m_iNumTerroristWins),
        get_member_game(m_iTotalRoundsPlayed) + 1,
        iAliveCTs, get_member_game(m_iNumCTWins)
    );

    set_hudmessage(255, 255, 255, -1.0, 0.02, .holdtime = 1.0);

    for(new iPlayer = 1; iPlayer <= MaxClients; iPlayer++)
        if(is_user_connected(iPlayer))
            ShowSyncHudMsg(iPlayer, g_iHudSyncObj, szHudText);
}

ufame · 26 Июл 2023

Albertio, почему дхуд не советуешь?)

26 Июл 2023

Albertio,
m_iNumTerroristWins
M_iNumCtWins

medusa · 26 Июл 2023

Код:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <cstrike>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "RevCrew"

#define is_player(%0) ( 1<=%0<=32 && is_user_connected(%0))

static const LIMIT = 400;

new g_tt_kills = 0;
new g_ct_kills = 0;


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event( "DeathMsg", "Event_DeathMsg", "a" );
  
    set_task(1.0, "DisplayDhud", 13131, _, _, "b")
}

public DisplayDhud()
{
    new p[32],c;
    get_players(p,c,"ch")

    ClearDHUDMessages()
  
    set_dhudmessage(255, 255, 255, -1.0, 0.01, 0, 0.05, 1.0, 0.05, true)
    show_dhudmessage(0, "TE %d [%d] %d CT",g_tt_kills, LIMIT, g_ct_kills) 

  
}

public Event_DeathMsg()
{
    new killer = read_data(1);
    new victim = read_data(2);
  
    if( killer == victim || !is_player(killer) || !is_player(victim))
        return;
      
    switch (cs_get_user_team(killer))
    {
        case CS_TEAM_T: g_tt_kills ++;
        case CS_TEAM_CT: g_ct_kills ++;
    }

}

stock ClearDHUDMessages(iClear = 8)
        for (new iDHUD = 0; iDHUD < iClear; iDHUD++)
                show_dhudmessage(0, "");

Albertio · 26 Июл 2023

После беседы с ТС'ом, был доделан плагин.

Код:

#include <amxmodx>
#include <reapi>

#define TS_TASK_ID 123321

enum ScoreData {
    TT_KILLS,
    CT_KILLS
};

new g_eScoreData[ScoreData];

new g_iHudSyncObj;

public plugin_init() {
    register_plugin("Team Score", "0.0.1", "Albertio");

    RegisterHookChain(RG_RoundEnd, "RG_RoundEnd_Post", true);
    RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", true);

    g_iHudSyncObj = CreateHudSyncObj();

    set_task(1.0, "ShowScoreHud", TS_TASK_ID, .flags = "b");
}

public RG_RoundEnd_Post(WinStatus:eStatus, ScenarioEventEndRound:eEvent) {
    if(eEvent == ROUND_GAME_RESTART)
        g_eScoreData[CT_KILLS] = g_eScoreData[TT_KILLS] = 0;
}

public CSGameRules_PlayerKilled_Post(const iVictim, const iKiller, const iInflictor) {
    if(iInflictor <= 0)
        return;

    switch(TeamName:get_member(iVictim, m_iTeam)) {
        case TEAM_TERRORIST: { g_eScoreData[CT_KILLS]++; }
        case TEAM_CT: { g_eScoreData[TT_KILLS]++; }
    }
}

public ShowScoreHud(id) {
    static iAliveTTs, iAliveCTs;
    rg_initialize_player_counts(iAliveTTs, iAliveCTs);

    new szHudText[128];
    formatex(szHudText, charsmax(szHudText),
        "TT(%d): %d | Total Round: %d | CT(%d): %d^nTT Kills: %d | CT Kills: %d",
        iAliveTTs, get_member_game(m_iNumTerroristWins),
        get_member_game(m_iTotalRoundsPlayed) + 1,
        iAliveCTs, get_member_game(m_iNumCTWins),
        g_eScoreData[TT_KILLS], g_eScoreData[CT_KILLS]
    );

    set_hudmessage(255, 255, 255, -1.0, 0.02, .holdtime = 1.0);

    for(new iPlayer = 1; iPlayer <= MaxClients; iPlayer++)
        if(is_user_connected(iPlayer))
            ShowSyncHudMsg(iPlayer, g_iHudSyncObj, szHudText);
}

Kioo · 26 Июл 2023

Всем спасибо! Решение найдено

Nordic Warrior · 26 Июл 2023

Albertio, а почему версия была 0.0.1 и в следующей версии так и осталась?

fl0wer · 27 Июл 2023

Albertio, m_iNumTerroristRoundKilled, m_iNumCTRoundKilled ?

Albertio · 27 Июл 2023

fl0wer, у меня не за раунд, а общее кол-во убийств + каждый раз дергать мемберы, когда надо сразу же в худ записывать убийства такое се, проще после каждого убийства в переменную прибавлять 1

Мигает DHUD

Kioo

Вложения

Albertio

Kioo

Albertio

ufame

medusa

Albertio

Kioo

Nordic Warrior

fl0wer

Albertio

Пользователи, просматривающие эту тему