Проблема с плагином "Buy Respawn"

Kioo · 17 Дек 2022

Приветствую всех, друзья!

Проблема с плагином возрождения, а именно в том, что при покупке респавна, в чат отправляются сообщения, по типу "[RESPAWN] Вы купили Возрождение" или "[RESPAWN] Вы купили максимум возрождений за этот раунд!". И вроде бы всё нормально, но загвоздка в том, что подобные оповещения в чате отправляются не конкретному игроку (как задумывалось самим плагином), а всем в общий чат. Пример: какой-то игрок на сервере хочет купить возрождение, а в общем чате ВСЕ игроки видят "[RESPAWN] Вы купили максимум возрождений за этот раунд!", хотя они даже не совершали этих действий .

Сам попытался решить эту проблему, но что-то не очень получилось. Изначально там везде, где сейчас стоит приставка "(id)" (заранее извиняюсь за неправильное название тех или иных функций), стояла (client). Я все это поменял и вроде бы некоторые сообщения перестали высвечиваться в общий чат, но оставшиеся все еще появляются в чате, что, естественно, неправильно.

Прошу помощи в решении данной проблемы, так как сам я и правда не понимаю в чем дело

* Заранее предупреждаю, что в поле "Ошибка" указал на предполагаемою мной строку с проблемой, но это может быть не так.

BiZaJe · 17 Дек 2022

вместо нуля индекс игрока пиши

Kioo · 17 Дек 2022

BiZaJe, все, прописал. Чуть позже отпишу сюда сработало или нет.
И могу ли я попросить хотя бы краткое пояснение к этому, если, конечно, не трудно. Вот до этого там стояло в некоторых строках "client", а я поменял на индекс "id". В чем вообще их разница?
И по поводу 0. То есть если не указывать индекс игрока, то все будет "спамить" в общий?

BiZaJe · 17 Дек 2022

Kioo, 0 это всем показать
Вместо 0 пишешь переменную где хранится индекс игрока
А лучше скинь полноценный кусок кода

bizon · 17 Дек 2022

Первый аргумент - индекс игрока, которому шлём сообщение.
Аргумент 0 в данном случае принимается функцией как отослать всем игрокам.

Kioo · 18 Дек 2022

BiZaJe, не знаю, актуально ли это на данный момент или нет, так как поздно отвечаю, но вот полноценный код. Может так даже полезней будет

Код:

#include <amxmodx>
#include <hamsandwich>
#include <cstrike>

/*
    Plugin info
*/
#define PLUGIN "Buy Respawn"
#define VERSION "1.0.2"
#define AUTHOR "Rodrigo286"

/*
    Variables
*/
new gCost;
new gUses;
new gEnabled;
new gMessages;
new respawns[33];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

/*
    Cvars
*/
    register_cvar("amxx_buy_respawn_version", VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_UNLOGGED|FCVAR_SPONLY)
    gEnabled = register_cvar("amxx_buy_respawn_enabled", "1") // Plugin is enbaled?
    gCost = register_cvar("amxx_buy_respawn_cost", "3000") // How much respawn cost?
    gUses = register_cvar("amxx_buy_respawn_per_round", "2") // How many respawns allowed per round?
    gMessages = register_cvar("amxx_buy_respawn_messages", "1") // Info messages enabled?
/*
    Commands
*/
    register_clcmd("say !respawn", "respawnCMD"); // Command to buy respawn
    register_clcmd("say /respawn", "respawnCMD"); // Command to buy respawn

/*
    Events
*/
    register_event("HLTV", "LogEvent_RoundStart", "a", "1=0", "2=0");
}

public LogEvent_RoundStart()
{
    arrayset(respawns, 0, sizeof(respawns));
}

public respawnCMD(id)
{
    new money = cs_get_user_money(id);

    new cost = get_pcvar_num(gCost);

    new uses = get_pcvar_num(gUses);

    new payment = money - cost;

    new messages = get_pcvar_num(gMessages);

    if(get_user_team(id) == 3 || get_user_team(id) == 0)
    {
        client_print_color(id,print_team_default, "^4[RESPAWN] ^1Выбери команду перед покупкой возрождения");
        return PLUGIN_HANDLED;
    }

    if(get_pcvar_num(gEnabled) != 1)
    {
        if(messages != 0)
            client_print_color(id,print_team_default, "^4[RESPAWN] ^1Покупка возрождения сейчас отключена");

        return PLUGIN_HANDLED;
    }

    if(is_user_alive(id))
    {
        client_print_color(id,print_team_default, "^4[RESPAWN] ^1Доступно только мертвым игрокам!");
        return PLUGIN_HANDLED;
    }

    if(uses == respawns[id])
    {
        client_print_color(id,print_team_default, "^4[RESPAWN] ^1Вы купили максимум возрождений за этот раунд!");
        return PLUGIN_HANDLED;
    }

    if(money < cost)
    {
        client_print_color(id,print_team_default, "^4[RESPAWN] ^1Недостаточно средств", cost);
        return PLUGIN_HANDLED;
    }

    cs_set_user_money(id, payment);

    ExecuteHamB(Ham_CS_RoundRespawn, id);

    respawns[id] += 1;

    if(messages != 0)
        client_print_color(id,print_team_default, "^4[RESPAWN] ^1Вы купили ^4Возрождение", cost);

    return PLUGIN_CONTINUE;
}

public client_connect(id)
{
/*
    Reset respawn uses on player connect
*/
    respawns[id] = 0;
}

18 Дек 2022

BiZaJe, и спасибо за небольшое пояснение

18 Дек 2022

bizon, вот как, спасибо, теперь стало еще более понятнее

Kioo · 18 Дек 2022

BiZaJe, все заработало, спасибо!

Проблема с плагином "Buy Respawn"

Kioo

Вложения

BiZaJe

Kioo

BiZaJe

bizon

Kioo

Kioo

Пользователи, просматривающие эту тему