Помощь по настройке

Dmitry142rus · 10 Мар 2018

Ребятки всем привет. Арендую на myarene pro машину . Раньше стоял

sys_ticrate:1100

сейчас же стоит

sys_ticrate:1000

посмотрел в панель и вижу вот такие ошибки у игроков намного чаще стали появляться SZ_GetSpace: overflow on 777
вот FPS стало значительно прыгать
CPU In Out Uptime Users FPS Players
37.67 183.33 290.41 39 240 630.58 25

CPU In Out Uptime Users FPS Players
44.00 306.13 533.87 41 248 437.15 26

CPU In Out Uptime Users FPS Players
40.00 222.61 386.33 41 252 630.98 24

CPU In Out Uptime Users FPS Players
42.00 230.04 404.97 43 254 330.66 22

кто что скажет ? Что Может чего не так ???

present · 13 Мар 2018

Dmitry142rus, https://dev-cs.ru/threads/201/

RockTheStreet · 13 Мар 2018

Пример:

Код:

 [13] Sockets                 1.8.2       HLSW Dev Team        running   
 [14] Sockets2                1.8.1.3746  HLSW Dev Team        running

GALAXY · 13 Мар 2018

Dmitry142rus, это от плагинов. По крайней мере на новых версиях REHLDS я такого не вижу у себя, только когда зависают игроки на сервере. Раньше был плагин автобаланса у меня от автора DUKHAZER. Еще тогда стоял HLDS. Каждые две секунды этим шлаком забивалась моя консоль. И только когда я его отключил у меня все нормализовалось.

Код:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define MAX_FLUX 4                //Максимальное кол-во разницы в очках команд, после чего будет совершен баланс по силам.
#define REPLACE_INTERVAL 2        //Интервал между балансировкой команд по силам.
#define RESET_INTERVAL 5        //Интервал между обнулением иммунитета от переброса у перенесенных.
#define ADMIN_FLAG ADMIN_BAN     //Необходимый флаг для получения иммунитета от автобаланса [0 - Выключить].

enum _:TEAMS {TT, CT};
new apPlayers[32], iPlayers, i, bool:g_bWasReplaced[33], bool:g_bImmunity[33], bool:g_bNeedReplace[33], g_iFrags[33], g_iDeaths[33], g_iRoundCount, g_iScore[TEAMS];

public plugin_init()
{
    register_plugin("Team Balancer Lite", "1.0", "DUKKHAZ0R");
    RegisterHam(Ham_Spawn, "player", "fw_HamPlayerSpawn_Pre");
    register_logevent("LogEventRoundEnd", 2, "1=Round_End");
    register_event("DeathMsg", "eDeathMsg", "a", "1>0");
    register_event("TeamScore", "eTeamScore", "a");
    register_event("HLTV", "eRoundStart", "a", "1=0", "2=0");
}

public eRoundStart()
{
    if(g_iRoundCount++ >= RESET_INTERVAL)
    {
        arrayset(g_bWasReplaced, false, 33);
        g_iRoundCount = 0;
    }
}

#if ADMIN_FLAG != 0
public client_putinserver(id)
    g_bImmunity[id] = (get_user_flags(id) & ADMIN_FLAG) ? true : false;
#endif

public client_disconnect(id)
{
    g_bNeedReplace[id] = g_bWasReplaced[id] = false;
    g_iFrags[id] = g_iDeaths[id] = 0;
}

public eDeathMsg()
{
    g_iFrags[read_data(1)]++;
    g_iDeaths[read_data(2)]++;
}

public eTeamScore()
{
    static Team[32]; read_data(1, Team, charsmax(Team));
    switch(Team[0])
    {
        case 'T': g_iScore[TT] = read_data(2);
        case 'C': g_iScore[CT] = read_data(2);
    }
}

public fw_HamPlayerSpawn_Pre(id)
{
    if(g_bNeedReplace[id])
    {
        fm_set_user_team(id, 3 - get_pdata_int(id, 114));
        g_bNeedReplace[id] = false;
        g_bWasReplaced[id] = true;
    }
}

public LogEventRoundEnd()
{
    static iNumTt, iNumCt, iTeam, iReplaceCount; get_players_in_team(iNumTt, iNumCt);
    if(iReplaceCount++ >= REPLACE_INTERVAL && abs(g_iScore[TT] - g_iScore[CT]) >= MAX_FLUX)
    {
        static iDistance, pBestPlayer, pLooser, iBestPlayerFrags, iLooserFrags, iLeaderTeam, szLooserName[32], szBestPlayerName[32];
        iLeaderTeam = (g_iScore[TT] > g_iScore[CT]) ? 1 : 2;
        pBestPlayer = pLooser = iBestPlayerFrags = iLooserFrags = 0;
        get_players(apPlayers, iPlayers, "ch");
        for(i = 0; i < iPlayers; i++)
        {
            iTeam = get_pdata_int(apPlayers[i], 114);
            iDistance = g_iFrags[apPlayers[i]] - g_iDeaths[apPlayers[i]];
            if(g_bWasReplaced[apPlayers[i]] || g_bImmunity[apPlayers[i]]) continue;
            if(iTeam == iLeaderTeam && iDistance > iBestPlayerFrags)
            {
                pBestPlayer = apPlayers[i];
                iBestPlayerFrags = iDistance;
            }
            else if(iTeam == (3 - iLeaderTeam) && iDistance < iLooserFrags)
            {
                pLooser = apPlayers[i];
                iLooserFrags = iDistance;
            }
        }
        if(pBestPlayer && pLooser)
        {
            iReplaceCount = 0;
            g_bNeedReplace[pBestPlayer] = g_bNeedReplace[pLooser] = true;
            get_user_name(pLooser, szLooserName, charsmax(szLooserName));
            get_user_name(pBestPlayer, szBestPlayerName, charsmax(szBestPlayerName));
            ChatColor("^1[^4Lite TeamBalancer^1] Сильного ^3%s ^1заменили на слабого ^3%s^1!", szBestPlayerName, szLooserName);
        }
    }
    while(abs(iNumTt - iNumCt) > 1)
    {
        static pTarget, szTargetName[32], iTargetTeam; iTargetTeam = (iNumTt > iNumCt) ? 1 : 2;
        get_players(apPlayers, iPlayers, "ch");
        for(i = 0; i < iPlayers; i++)
        {
            iTeam = get_pdata_int(apPlayers[i], 114);
            if(!g_bWasReplaced[apPlayers[i]] && !g_bImmunity[apPlayers[i]] && !g_bNeedReplace[apPlayers[i]] && iTargetTeam == iTeam)
            {
                iTeam == 1 ? iNumCt++ : iNumTt++; iTeam == 1 ? iNumTt-- : iNumCt--;
                pTarget = apPlayers[i];
                break;
            }
        }
        g_bNeedReplace[pTarget] = true;
        get_user_name(pTarget, szTargetName, charsmax(szTargetName));
        ChatColor("^1[^4Lite TeamBalancer^1] Игрок ^3%s ^1перенесен за %s", szTargetName, iTeam == 1 ? "контр-террористов." : "террористов.");
    }
}

stock get_players_in_team(&iNumTt, &iNumCt)
{
#if AMXX_VERSION_NUM < 182
    iNumTt = iNumCt = 0;
    get_players(apPlayers, iPlayers, "h");
    for(i = 0; i < iPlayers; i++)
    {
        switch(get_pdata_int(apPlayers[i], 114))
        {
            case 1: iNumTt++;
            case 2: iNumCt++;
        }
    }
#else
    get_players(apPlayers, iNumTt, "e", "TERRORIST");
    get_players(apPlayers, iNumCt, "e", "CT");
#endif
}

stock ChatColor(const input[], any:...)
{
    static szMsg[191]; vformat(szMsg, charsmax(szMsg), input, 2);
    get_players(apPlayers, iPlayers, "ch");
    for(new i; i < iPlayers; i++)
    {
        message_begin(MSG_ONE_UNRELIABLE, 76, _, apPlayers[i]);
        write_byte(apPlayers[i]);
        write_string(szMsg);
        message_end();
    }
}

stock fm_set_user_team(const id, const iTeam)
{
    set_pdata_int(id, 114, iTeam, 5);
    dllfunc(DLLFunc_ClientUserInfoChanged, id, engfunc(EngFunc_GetInfoKeyBuffer, id));

    static MsgId_TeamInfo; if(!MsgId_TeamInfo) MsgId_TeamInfo = get_user_msgid("TeamInfo");

    message_begin(MSG_ALL, MsgId_TeamInfo);
    write_byte(id);
    write_string(iTeam == 1 ? "TERRORIST" : "CT");
    message_end();
}

Помощь по настройке

Dmitry142rus

present

RockTheStreet

Саппорт года

GALAXY

Пользователи, просматривающие эту тему