Antiidlebot

elit59 · 16 Окт 2021

Код:

#include <amxmodx>
#include <fakemeta>
#include <reapi>

// Automatically create config in 'configs/plugins', and execute it?
#define AUTO_CFG

// General log in 'amxmodx/logs'
new const LOG_WARNS[] = "AntiIdleBot.log"
// Debug log in 'amxmodx/logs'
new const LOG_DEBUG[] = "AntiIdleBot_Debug.log"

#define MAX_IP_LENGTH 16

enum _:CVAR_ENUM {
    Float:CVAR_F__AUTH_TIME,
    CVAR__MAX_WARNS,
    CVAR__BAN_MINUTES,
    CVAR__FORCE_WRITEIP,
    CVAR__EXEC_LISTIP_CFG,
    CVAR__DEBUG_MODE
}

enum _:CHECK_DATA_STRUCT {
    CHECK_DATA__TASKID,
    Float:CHECK_DATA_F__TIME
}

enum {
    WARN_TYPE__DELAYED,
    WARN_TYPE__RECONNECT
}

new g_eCheckData[CHECK_DATA_STRUCT]
new g_eCvar[CVAR_ENUM]
new Trie:g_tIpWarns
new Trie:g_tIpsInCheck

// thanks juice for this method
new g_net_from;

enum _:netadr_t
{
  NETADR_type = 0,
  NETADR_ip[4] = 4,
  NETADR_ipx[10],
  NETADR_port[2]
};

#define RH_ClientConnected (RH_SV_WriteFullClientUpdate + (EngineFunc: 1))

public plugin_precache() {
    register_plugin("AntiIdleBot", "1.1.0-fm", "mx?!") // just code. antibot method by Ragamafona

    bind_pcvar_float( create_cvar( "aib_auth_time", "3.0",
        .description = "Time to auth client (do not change it if you don't exactly know what you are doing!)"),
        g_eCvar[CVAR_F__AUTH_TIME]
    );

    bind_pcvar_num( create_cvar( "aib_max_warns", "3",
        .description = "Max warns per IP to ban it (warns resets every mapchange)",
        .has_min = true, .min_val = 1.0 ),
        g_eCvar[CVAR__MAX_WARNS]
    );

    bind_pcvar_num( create_cvar( "aib_ban_minutes", "120",
        .description = "Ban time in minutes (0 = permanent)",
        .has_min = true, .min_val = 0.0 ),
        g_eCvar[CVAR__BAN_MINUTES]
    );

    bind_pcvar_num( create_cvar( "aib_force_writeip", "1",
        .description = "Force 'writeip' command to store permanent bans to listip.cfg?" ),
        g_eCvar[CVAR__FORCE_WRITEIP]
    );

    bind_pcvar_num( create_cvar( "aib_exec_listip_cfg", "0",
        .description = "Execute listip.cfg to restore permanent bans after restarting the server?" ),
        g_eCvar[CVAR__EXEC_LISTIP_CFG]
    );

    bind_pcvar_num( create_cvar( "aib_debug_mode", "0",
        .description = "Enable debug mode to test plugin or solve problems?" ),
        g_eCvar[CVAR__DEBUG_MODE] );

#if defined AUTO_CFG
    AutoExecConfig()
#endif

    set_task(5.0, "task_Init")

    g_tIpWarns = TrieCreate()
    g_tIpsInCheck = TrieCreate()

    init_memory();
}

init_memory() {
    new GameConfig:gameConfig = LoadGameConfigFile("net_from");

    if (!gameConfig) {
        set_fail_state("gameConfig error");
    }

    new address = GameConfGetAddress(gameConfig, "net_from");
    CloseGameConfigFile(gameConfig);

    if (!address) {
        set_fail_state("address error");
    }

    g_net_from = is_linux_server() ? address : get_tr2(address, TR_AllSolid);

    RegisterHookChain(RH_ClientConnected, "RH_ClientConnected_Pre");
}

public task_Init() {
    if(g_eCvar[CVAR__EXEC_LISTIP_CFG]) {
        server_cmd("exec listip.cfg")
    }
}

public RH_ClientConnected_Pre() {
    new address = get_tr2(g_net_from + NETADR_ip, TR_AllSolid);

    new szIP[MAX_IP_LENGTH]

    formatex( szIP, charsmax(szIP), "%d.%d.%d.%d", address & 0xFF,
        (address >>> 8) & 0xFF,    (address >>> 16) & 0xFF, (address >>> 24) & 0xFF );

    if(TrieGetArray(g_tIpsInCheck, szIP, g_eCheckData, sizeof(g_eCheckData))) { // reconnect while ip is still checking
        if(g_eCvar[CVAR__DEBUG_MODE]) {
            log_to_file( LOG_DEBUG, "[AIB DEBUG] RH_ClientConnected_Pre(): reconnect %s (old taskid: %i)",
                szIP, g_eCheckData[CHECK_DATA__TASKID] );
        }

        remove_task(g_eCheckData[CHECK_DATA__TASKID])

        if(func_WarnIP(szIP, g_eCheckData, WARN_TYPE__RECONNECT)) { // force delayed warn
            return // ip banned, stop here
        }
    }

    new iTaskID

    do {
        iTaskID = random_num(0, 99999)
    }
    while(task_exists(iTaskID))

    if(g_eCvar[CVAR__DEBUG_MODE]) {
        log_to_file(LOG_DEBUG, "[AIB DEBUG] RH_ClientConnected_Pre(): %s (taskid: %i)", szIP, iTaskID)
    }

    g_eCheckData[CHECK_DATA__TASKID] = iTaskID
    g_eCheckData[CHECK_DATA_F__TIME] = get_gametime()

    TrieSetArray(g_tIpsInCheck, szIP, g_eCheckData, sizeof(g_eCheckData))

    if(g_eCvar[CVAR__DEBUG_MODE] && g_eCvar[CVAR_F__AUTH_TIME] < 0.1) { // emulate detection by normal client ;)
        task_WarnIP(szIP)
        return
    }

    set_task(floatmax(0.1, g_eCvar[CVAR_F__AUTH_TIME]), "task_WarnIP", iTaskID, szIP, sizeof(szIP))
}

public client_connect(pPlayer) {
    new szIP[MAX_IP_WITH_PORT_LENGTH]
    get_user_ip(pPlayer, szIP, charsmax(szIP), .without_port = 1)

    if(!TrieGetArray(g_tIpsInCheck, szIP, g_eCheckData, sizeof(g_eCheckData))) {
        if(g_eCvar[CVAR__DEBUG_MODE]) {
            log_to_file(LOG_DEBUG, "[AIB DEBUG] client_connect(): %s (warned? taskid not found!)", szIP)
        }

        return
    }

    TrieDeleteKey(g_tIpsInCheck, szIP)
    remove_task(g_eCheckData[CHECK_DATA__TASKID])

    if(g_eCvar[CVAR__DEBUG_MODE]) {
        log_to_file(LOG_DEBUG, "[AIB DEBUG] client_connect(): %s (taskid: %i, elapsed %f)",
            szIP, g_eCheckData[CHECK_DATA__TASKID], get_gametime() - g_eCheckData[CHECK_DATA_F__TIME] );
    }
}

public task_WarnIP(const szIP[]) {
    if(!TrieGetArray(g_tIpsInCheck, szIP, g_eCheckData, sizeof(g_eCheckData))) {
        abort(AMX_ERR_GENERAL, "[Error] %s not found in trie!", szIP)
        return
    }

    func_WarnIP(szIP, g_eCheckData, WARN_TYPE__DELAYED)
}

bool:func_WarnIP(const szIP[], const eCheckData[CHECK_DATA_STRUCT], iWarnType) {
    TrieDeleteKey(g_tIpsInCheck, szIP)

    new iWarnCount
    TrieGetCell(g_tIpWarns, szIP, iWarnCount)
    iWarnCount++
    TrieSetCell(g_tIpWarns, szIP, iWarnCount)

    log_to_file(LOG_WARNS, "[AIB] %i/%i %s warn for %s (taskid: %i, elapsed %f)",
        iWarnCount, g_eCvar[CVAR__MAX_WARNS], (iWarnType == WARN_TYPE__DELAYED) ? "delayed" : "reconnect",
        szIP, eCheckData[CHECK_DATA__TASKID], get_gametime() - eCheckData[CHECK_DATA_F__TIME]
    );

    if(g_eCvar[CVAR__DEBUG_MODE]) {
        log_to_file(LOG_DEBUG, "[AIB DEBUG] %i/%i %s warn for %s (taskid: %i, elapsed %f)",
            iWarnCount, g_eCvar[CVAR__MAX_WARNS], (iWarnType == WARN_TYPE__DELAYED) ? "delayed" : "reconnect",
            szIP, eCheckData[CHECK_DATA__TASKID], get_gametime() - eCheckData[CHECK_DATA_F__TIME]
        );
    }

    if(iWarnCount >= g_eCvar[CVAR__MAX_WARNS]) {
        server_cmd("addip %i %s", g_eCvar[CVAR__BAN_MINUTES], szIP)

        if(!g_eCvar[CVAR__BAN_MINUTES] && g_eCvar[CVAR__FORCE_WRITEIP]) {
            server_cmd("writeip")
        }

        log_to_file(LOG_WARNS, "[AIB] %s banned for %i minute(s)", szIP, g_eCvar[CVAR__BAN_MINUTES])

        if(g_eCvar[CVAR__DEBUG_MODE]) {
            log_to_file(LOG_DEBUG, "[AIB DEBUG] %s banned for %i minute(s)", szIP, g_eCvar[CVAR__BAN_MINUTES])
        }

        return true
    }

    return false
}

d3m37r4 · 16 Окт 2021

elit59, переведи ошибку. Вернись в тему с плагином, перечитай ее и ты поймешь, что ты сделал не так.

BlackSignature · 16 Окт 2021

elit59, реапи надо поставить с проброшенным ClientConnected, там же написано

elit59 · 17 Окт 2021

ok. fixed!

Antiidlebot

elit59

d3m37r4

111111

BlackSignature

elit59

Пользователи, просматривающие эту тему