не работает top_awards

asla4ok · 15 Июн 2020

плагин выборочно как-то дает вип за топ 10 у кого-то есть у кого-то нету
пробовал ставить YOUR_STATS_SYSTEM 0 и 2 одно и тоже
стоит CSSTATSX SQL by serfreeman1337 с заменой модуля

Vasadko12 · 17 Июн 2020

asla4ok, нужен eror.log

bibako · 18 Июн 2020

asla4ok,

Код:

/*
* Top Awards 10/22/2012
*Плагин добавляет флаг(и) TOPx игрокам
Квары:
top_ranks - максимальный ранг, который может иметь игрок (конец TOPX)
top_flags - какие флаги добавляются
*

Игнорируются игроки с флагом IGNORE_FLAG (по умолчанию это флаг m) и игроки, уже имеющие ВСЕ добавляемые флаги.
Поясняющая надпись игроку выводится цветным чатом.
*
Credits:
- original plugin's authors SimonLogic & RoleX
- c-s.net.ua users 3aB}{o3 & cs-portal for the idea and link
*/

#include <amxmodx>                                                                 
#include <csstats>

#define IGNORE_FLAG (ADMIN_LEVEL_A + ADMIN_BAN)    /* flag "m" */

new pRanks, pFlags
                  
native get_statsnum_sql()
native get_user_stats_sql(index, stats[8], bodyhits[8])
native get_stats_sql(index, stats[8], bodyhits[8], name[], len, authid[] = "", authidlen = 0)
native get_stats_sql_thread(id,position,top,callback[]);
                  
public plugin_init() {
    register_plugin( "Top Awards", "0.11c", "Safety1st" )
    register_dictionary( "topawards.txt" )
    pRanks = register_cvar( "top_ranks", "15" )
    pFlags = register_cvar( "top_flags", "mn" )                                                        
}                                

public client_putinserver(id) {
    set_task( 0.3, "CheckStats", id )    // we need to use delay otherwise we will get rank = 0
}

public CheckStats(id) {
    new iFlags = get_user_flags(id)
    new szAddFlags[16]
    get_pcvar_string( pFlags, szAddFlags, 15 )
    new iAddFlags  = read_flags(szAddFlags)

    if ( iFlags & IGNORE_FLAG || iFlags & iAddFlags == iAddFlags )
        // ignore player with IGNORE_FLAG or having all additional flags
        return

    new iRanks = get_pcvar_num(pRanks)
    if ( !iRanks )
        return

    new szStats[8], szBodyHits[8]
    new iRank = get_user_stats_sql( id, szStats, szBodyHits )

    if ( iRank && iRank <= iRanks ) {
        // 1st check for safety. may be player not ranked at all yet
        set_user_flags( id, iFlags | iAddFlags )
        new data[2]
        data[0] = id
        data[1] = iRanks
        set_task( 5.0, "PrintMessage", _, data, 2 )
    }
}

public PrintMessage( data[2] ) {
    if ( !is_user_connected(data[0]) )
        return

    ColorPrint( data[0], "%L", data[0], "TOP_AWARDS", data[1] )
}

ColorPrint( iReceiver, const szRawMessage[ ], any:... ) {
    static iMsgSayText = 0
    if( !iMsgSayText )
        iMsgSayText = get_user_msgid( "SayText" )

    new szMessage[192]
    vformat( szMessage, charsmax(szMessage) - 1, szRawMessage, 3 )
    replace_all( szMessage, charsmax(szMessage) - 1, "!n", "^1" )
    replace_all( szMessage, charsmax(szMessage) - 1, "!t", "^3" )
    replace_all( szMessage, charsmax(szMessage) - 1, "!g", "^4" )
    if ( szMessage[0] != '^1' || szMessage[0] != '^3' || szMessage[0] != '^4' )
        format( szMessage, charsmax(szMessage) - 1, "^1%s", szMessage )    // we must set initial default color if it is not provided explicitly

    message_begin( MSG_ONE_UNRELIABLE, iMsgSayText, _, iReceiver )
    write_byte(iReceiver)    // use target player as sender to see colors at all (and his own team color for ^3)
    write_string(szMessage)
    message_end()
}

не работает top_awards

asla4ok

Vasadko12

bibako

Пользователи, просматривающие эту тему