Run time error 10: native error (native "cs_get_user_team")

Sherlok_h · 23 Фев 2020

Раз в сутки, но в разное время, появляется такая ошибка в логах. Подскажите, как исправить?

fl0wer · 23 Фев 2020

Поменять хук на спавн.

Sherlok_h · 23 Фев 2020

fl0wer, а можно, пожалуйста, чуть более подробно, в какой строке и что на что поменять? А то я не сильно разбираюсь в скриптинге

fl0wer · 23 Фев 2020

Sherlok_h, у себя в плагине замени с 1-33 строку на:

Код:

#pragma semicolon 1

#include <amxmodx>
#include <reapi>

new const RED[] = "red";
new const BLUE[] = "blue";

public plugin_init()
{
    register_plugin("BLady Admin", "1.0", "fl0wer");

    RegisterHookChain(RG_CBasePlayer_Spawn, "@CBasePlayer__Spawn_Post", true);
}

public plugin_precache()
{
    #define full_player_model_path(%0)            fmt("models/player/%s/%s.mdl", %0, %0)

    precache_model(full_player_model_path(RED));
    precache_model(full_player_model_path(BLUE));
}

@CBasePlayer__Spawn_Post(id)
{
    if (get_entvar(id, var_deadflag) != DEAD_NO)
        return;

    if (~get_user_flags(id) & ADMIN_LEVEL_E)
        return;

    switch (get_member(id, m_iTeam))
    {
        case TEAM_TERRORIST: rg_set_user_model(id, RED);
        case TEAM_CT: rg_set_user_model(id, BLUE);
    }
}

Shel · 23 Фев 2020

Код:

#include <amxmodx>
#include <amxmisc>
#include <reapi>
public plugin_init(){
    RegisterHookChain(RG_CBasePlayer_SetClientUserInfoModel,"SetClientUserInfoModel");
    RegisterHookChain(RG_CBasePlayer_Spawn,"CBasePlayer_Spawn_Post",true);
}
new const formated[] = "models/player/%s/%s.mdl";
new const RED[] = "red";
new const BLUE[] = "blue";
public plugin_precache(){
    new szMdl[65];
    formatex(szMdl,charsmax(szMdl),formated,BLUE,BLUE);precache_model(szMdl);
    formatex(szMdl,charsmax(szMdl),formated,RED,RED);precache_model(szMdl);
}
public CBasePlayer_Spawn_Post(const iPlayer){
    if(!is_user_alive(iPlayer))return;
    static Flags;Flags = get_user_flags(iPlayer) & ADMIN_LEVEL_E;
    if(!Flags)return;
    switch(get_member(iPlayer,m_iTeam)) {
        case TEAM_TERRORIST: rg_set_user_model(iPlayer,RED);
        case TEAM_CT: rg_set_user_model(iPlayer,BLUE);
    }
}
public SetClientUserInfoModel(const pPlayer/* ,infobuffer[],szNewModel[] */){
    if(!is_user_alive(pPlayer))return HC_CONTINUE;
    static Flags;Flags = get_user_flags(pPlayer) & ADMIN_LEVEL_E;
    if(!Flags)return HC_CONTINUE;
    switch(get_member(pPlayer,m_iTeam)){
        case TEAM_TERRORIST: SetHookChainArg(3,ATYPE_STRING,RED);
        case TEAM_CT: SetHookChainArg(3,ATYPE_STRING,BLUE);
    }
    return HC_CONTINUE;
}

fl0wer · 23 Фев 2020

Shel написал(а):
/* ,infobuffer[],szNewModel[] */

вотета самовыражение.

Sherlok_h · 24 Фев 2020

fl0wer, Shel, спасибо за варианты. Попробовал от Флоувер - ошибки нет, думаю и во втором варианте от Шела тоже её не будет

Shel · 24 Фев 2020

Во втором варианте меньше потребление памяти(refs instead dups). + недочет со сменой посредством смены model исправлен. Сам смотри.

fl0wer · 24 Фев 2020

Shel написал(а):
Во втором варианте меньше потребление памяти (refs instead dups)

Как же оно меньше, если у тебя на один хук больше? (code instead brain)

Shel написал(а):
недочет со сменой посредством смены model исправлен. Сам смотри.

Я думаю оно тут исправлено :scratch_one-s_head:

https://github.com/s1lentq/ReGameDL...c2d2d8498f23aa/regamedll/dlls/player.cpp#L207
Если в другом месте поменяли модель, очевидно, что это и требовалось.