Special Round- Knife Round Plugin Not Working

DrStrange · 8 Сен 2019

For Problem, Kindly Read Error Log [Box] at Top.

P.S: During the test of plugin, I was using metamod-p37 but now I have replaced it with:

Metamod-r v1.3.0.128, API (5:13) Metamod-r build: 17:47:54 Aug 24 2018 Metamod-r from: https://github.com/theAsmodai/metamod-r/commit/0cf2f70

BlackSignature · 8 Сен 2019

original code. try set cvar to low value (3 or 4), restart server (shutdown and start again), then test. you can make restarts just to over rounds.

DrStrange · 8 Сен 2019

BlackSignature написал(а):
Посмотреть вложение 18736

original code. try set cvar to low value (3 or 4), restart server (shutdown and start again), then test. you can make restarts just to over rounds.

But when I tried it didn't work !! I was only able to change cvar nothing else. I compiled with AMXX 1.90 [5249], which compiler did you use?
Server is ReHLDS, Aurthor said it might work with ReHLDS.

BlackSignature · 8 Сен 2019

DrStrange, hm... i suppose that you change cvar in .sma without changing it in console. I'm right? Changing value in .sma for cvar that already has been registered doesn't change its value. You need to change it manually.

8 Сен 2019

i add debug print (chat/server console), it will print round number/round to trigger at the start of each round

DrStrange · 8 Сен 2019

BlackSignature написал(а):
DrStrange, hm... i suppose that you change cvar is .sma without changing it in console. I'm right? Changing value in .sma for cvar that already has been registered doesn't change its value. You need to change it manually.

First I tried compiled as it was, no effect was produced at round 15, then at 18th or 19th round, I changed cvar to 10 & waited for results on round 20 & 21 but nothing happend.

BlackSignature · 8 Сен 2019

DrStrange, round compires by 'equal' logic so if you set value lower than current round number, it won't work :)

DrStrange · 8 Сен 2019

It means plugin won't repeat? Knife round every x [cvar] number of rounds?

8 Сен 2019

Like: knife round at 15, 30, 45 etc.

BlackSignature · 8 Сен 2019

It means that if current round is 12 and you set cvar to 10, logic will stuck

Код:

    g_knife_round++
    // variable value reached our cvar number ?
    if (g_knife_round == get_pcvar_num(cvar_knife_round))

== needs to be changed to >= to cover cvar changing "on the fly"

DrStrange · 8 Сен 2019

BlackSignature написал(а):
It means that if current round is 12 and you set cvar to 10, logic will stuck

Код:

g_knife_round++ // variable value reached our cvar number ? if (g_knife_round == get_pcvar_num(cvar_knife_round))

Can you optimize the code? It would be little edit? I believe ...

BlackSignature · 8 Сен 2019

DrStrange,

== needs to be changed to >= to cover cvar changing "on the fly"

DrStrange · 8 Сен 2019

BlackSignature написал(а):
It means that if current round is 12 and you set cvar to 10, logic will stuck

Код:

g_knife_round++ // variable value reached our cvar number ? if (g_knife_round == get_pcvar_num(cvar_knife_round))

== needs to be changed to >= to cover cvar changing "on the fly"

Sorry just saw it, I will be back in a while and mark it as best answer, if it worked accordingly.

Thanks BlackSignature for quick help !!

8 Сен 2019

BlackSignature Compilation Error. // Edit: My Mistake, Fixed: you said >=, I made => this, hence got compilation error. (fixed code too)

Код:

/*


Knife Round
===========

Description
After every X rounds , an special knife round will occur.
For plugin to work properly add knife_round_delay "10" (what ever number of rounds you want) in amxx.cfg or use cvar atleast once in server.

*/
#include <amxmodx>
#include <fun>
#include <engine>

// Red , Green , Blue
new const HUD_COLOR[3] = {0 , 255 , 0}

// Hud X position
const Float: HUD_POSITION_X = -1.0
// Hud Y position
const Float: HUD_POSITION_Y = 0.25

// Hud display time
const HOLD_TIME = 5

// buy menu commands
new const g_szBuyCmds[ ][ ] = {
    "usp", "glock", "deagle", "p228", "elites", "fn57", "m3", "xm1014", "mp5", "tmp", "p90", "mac10", "ump45", "ak47",
    "galil", "famas", "sg552", "m4a1", "aug", "scout", "awp", "g3sg1", "sg550", "m249", "vest", "vesthelm", "flash", "hegren",
    "sgren", "defuser", "nvgs", "shield", "primammo", "secammo", "km45", "9x19mm", "nighthawk", "228compact", "12gauge",
    "autoshotgun", "smg", "mp", "c90", "cv47", "defender", "clarion", "krieg552", "bullpup", "magnum", "d3au1", "krieg550",
    "buyammo1", "buyammo2"
}

new const VERSION[] = "1.0"

// players class (needed when we want to block weapon pick up)
new const PLAYER_CLASS[] = "player"

// variable to increase value
new g_knife_round

// is knife round ?
new bool: g_is_knife_round

// cvar
new cvar_knife_round

public plugin_init()
{
    register_plugin("Knife Round" , VERSION , "LearninG")
    // looping through buy commands
    for (new i; i<sizeof g_szBuyCmds; i++)
    {
        register_clcmd(g_szBuyCmds[i] , "block_buy")
    }
    // called when user touch weapons , shield ...
    register_touch("armoury_entity", PLAYER_CLASS, "PlayerTouchArmoury")
    register_touch("weaponbox", PLAYER_CLASS, "PlayerTouchWeaponBox")
    register_touch("weapon_shield", PLAYER_CLASS, "PlayerTouchShield")

    // event_new_round
    register_logevent("event_new_round",2,"0=World triggered","1=Round_Start")
    register_event( "30" , "event_intermission" , "a" )
    register_cvar("knife_round_version", VERSION, FCVAR_SERVER | FCVAR_SPONLY)

    // store cvar in variable
    cvar_knife_round = register_cvar("knife_round_delay" , "10")
}

// called when new round begins
public event_new_round()
{
    g_is_knife_round = false
    // increase variable value by 1
    g_knife_round++
    // variable value reached our cvar number ?
    if (g_knife_round >= get_pcvar_num(cvar_knife_round))
    {
        // Start round
        g_is_knife_round = true
        g_knife_round = 0
        // looping through all connected players
        new players[32], num
        get_players(players, num, "a")

        for( --num; num >= 0; num-- )
        {
            // take away players weapon
            strip_user_weapons(players[num])
            // give them a knife
            give_item(players[num] , "weapon_knife")
            // set our hud message and show it to them.
            set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, 6.0, 0.3, 0.3, HOLD_TIME)
            show_hudmessage(players[num] , "Knife Only Round!!!")
        }
    }
}

public block_buy()
{
    // is knife round ?
    if (g_is_knife_round)
    {
        // block buy commands
        return PLUGIN_HANDLED
    }
    // allow buy commands
    return PLUGIN_CONTINUE
}

public PlayerTouchArmoury(ent, id)
{
    if (g_is_knife_round)
    {
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public PlayerTouchWeaponBox(ent, id)
{
    // player has touched a weapon , when round is knife_round
    if (g_is_knife_round)
    {
        // block weapon pickup
        return PLUGIN_HANDLED
    }
    // allow pick up
    return PLUGIN_CONTINUE
}

// player has touched shield.
public PlayerTouchShield(ent, id)
{
    if (g_is_knife_round)
    {
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public event_intermission()
{
    g_is_knife_round = false
    g_knife_round = 0
}

BlackSignature · 8 Сен 2019

DrStrange,

Код:

- =>
+ >=

DrStrange · 8 Сен 2019

BlackSignature написал(а):
DrStrange,

Код:

- => + >=

Yes, it works, perfectly now. if you could do me a little favor? that cvar sv_restart makes plugin to count round again from 1 instead of what's going on from start.

BlackSignature · 8 Сен 2019

DrStrange, you mean, you want to reset round counter when restart occurs?

add to plugin_init()

Код:

register_event("TextMsg", "event_restart_game", "a", "2=#Game_Commencing", "2=#Game_will_restart_in")

add to main plugin body

Код:

public event_restart_game() {
    g_knife_round = 0
}

DrStrange · 8 Сен 2019

Thanks it compiled successfully but as far results are concerned I can't report you them now, since server is empty.

Код:

/*


Knife Round
===========

Description
After every X rounds , an special knife round will occur.
For plugin to work properly add knife_round_delay "10" (what ever number of rounds you want) or use cvar atleast once in server.

*/
#include <amxmodx>
#include <fun>
#include <engine>

// Red , Green , Blue
new const HUD_COLOR[3] = {0 , 255 , 0}

// Hud X position
const Float: HUD_POSITION_X = -1.0
// Hud Y position
const Float: HUD_POSITION_Y = 0.25

// Hud display time
const HOLD_TIME = 10

// buy menu commands
new const g_szBuyCmds[ ][ ] = {
    "usp", "glock", "deagle", "p228", "elites", "fn57", "m3", "xm1014", "mp5", "tmp", "p90", "mac10", "ump45", "ak47", 
    "galil", "famas", "sg552", "m4a1", "aug", "scout", "awp", "g3sg1", "sg550", "m249", "vest", "vesthelm", "flash", "hegren",
    "sgren", "defuser", "nvgs", "shield", "primammo", "secammo", "km45", "9x19mm", "nighthawk", "228compact", "12gauge",
    "autoshotgun", "smg", "mp", "c90", "cv47", "defender", "clarion", "krieg552", "bullpup", "magnum", "d3au1", "krieg550",
    "buyammo1", "buyammo2"
} 

new const VERSION[] = "1.0"

// players class (needed when we want to block weapon pick up)
new const PLAYER_CLASS[] = "player"

// variable to increase value
new g_knife_round

// is knife round ?
new bool: g_is_knife_round

// cvar
new cvar_knife_round

public plugin_init()
{
    register_plugin("Knife Round" , VERSION , "LearninG")
    // looping through buy commands
    for (new i; i<sizeof g_szBuyCmds; i++)
    {
        register_clcmd(g_szBuyCmds[i] , "block_buy")
    }
    // called when user touch weapons , shield ...
    register_touch("armoury_entity", PLAYER_CLASS, "PlayerTouchArmoury")
    register_touch("weaponbox", PLAYER_CLASS, "PlayerTouchWeaponBox")
    register_touch("weapon_shield", PLAYER_CLASS, "PlayerTouchShield")

    // event_new_round
    register_logevent("event_new_round",2,"0=World triggered","1=Round_Start")
    register_event("TextMsg", "event_restart_game", "a", "2=#Game_Commencing", "2=#Game_will_restart_in")
    register_event( "30" , "event_intermission" , "a" )
    register_cvar("knife_round_version", VERSION, FCVAR_SERVER | FCVAR_SPONLY)

    // store cvar in variable
    cvar_knife_round = register_cvar("knife_round_delay" , "10")
}

// called when new round begins
public event_new_round()
{
    g_is_knife_round = false
    // increase variable value by 1
    g_knife_round++
    // variable value reached our cvar number ?
    if (g_knife_round >= get_pcvar_num(cvar_knife_round))
    {
        // Start round
        g_is_knife_round = true
        g_knife_round = 0
        // looping through all connected players
        new players[32], num
        get_players(players, num, "a")

        for( --num; num >= 0; num-- )
        {
            // take away players weapon 
            strip_user_weapons(players[num])
            // give them a knife
            give_item(players[num] , "weapon_knife")
            // set our hud message and show it to them.
            set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, 6.0, 0.3, 0.3, HOLD_TIME)
            show_hudmessage(players[num] , "Special Round- Knife Only Round !!!")
        }
    }
}

public event_restart_game() {
    g_knife_round = 0
}

public block_buy()
{
    // is knife round ?
    if (g_is_knife_round)
    {
        // block buy commands
        return PLUGIN_HANDLED
    }
    // allow buy commands
    return PLUGIN_CONTINUE
}

public PlayerTouchArmoury(ent, id)
{
    if (g_is_knife_round)
    {
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public PlayerTouchWeaponBox(ent, id)
{
    // player has touched a weapon , when round is knife_round
    if (g_is_knife_round)
    {
        // block weapon pickup
        return PLUGIN_HANDLED
    }
    // allow pick up
    return PLUGIN_CONTINUE
}

// player has touched shield.
public PlayerTouchShield(ent, id)
{
    if (g_is_knife_round)
    {
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}

public event_intermission()
{
    g_is_knife_round = false
    g_knife_round = 0
}

BlackSignature · 8 Сен 2019

DrStrange, also

Код:

// Hud display time
const HOLD_TIME = 10

is wrong

Код:

 * @param red           Red component of hudmessage color
 * @param green         Green component of hudmessage color
 * @param blue          Blue component of hudmessage color
 * @param x             Location of the message on the x axis in percent
 * @param y             Location of the message on the y axis in percent
 * @param effects       Display effect
 * @param fxtime        Duration of the effect
 * @param holdtime      Time the message stays on screen
 * @param fadeintime    Time it takes the message to fully appear (fade-in)
 * @param fadeouttime   Time it takes the message to fully disappear (fade-out)
 * @param channel       Channel to use on the client
 *
 * @noreturn
 */
native set_hudmessage(red = 200, green = 100, blue = 0, Float:x = -1.0, Float:y = 0.35, effects = 0, Float:fxtime = 6.0, Float:holdtime = 12.0, Float:fadeintime = 0.1, Float:fadeouttime = 0.2, channel = -1);

as you can see holdtime in not at the end + it is a float value

change

Код:

- const HOLD_TIME = 10
+ const Float:HOLD_TIME = 10.0
+ const HUD_CHANNEL = -1

- set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, 6.0, 0.3, 0.3, HOLD_TIME)
+ set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, HOLD_TIME, 0.3, 0.3, HUD_CHANNEL)

DrStrange · 8 Сен 2019

BlackSignature написал(а):

DrStrange, also

Код:

// Hud display time
const HOLD_TIME = 10

is wrong

Код:

* @param red           Red component of hudmessage color
* @param green         Green component of hudmessage color
* @param blue          Blue component of hudmessage color
* @param x             Location of the message on the x axis in percent
* @param y             Location of the message on the y axis in percent
* @param effects       Display effect
* @param fxtime        Duration of the effect
* @param holdtime      Time the message stays on screen
* @param fadeintime    Time it takes the message to fully appear (fade-in)
* @param fadeouttime   Time it takes the message to fully disappear (fade-out)
* @param channel       Channel to use on the client
*
* @noreturn
*/
native set_hudmessage(red = 200, green = 100, blue = 0, Float:x = -1.0, Float:y = 0.35, effects = 0, Float:fxtime = 6.0, Float:holdtime = 12.0, Float:fadeintime = 0.1, Float:fadeouttime = 0.2, channel = -1);

as you can see holdtime in not at the end + it is a float value

change

Код:

- const HOLD_TIME = 10
+ const Float:HOLD_TIME = 10.0
+ const HUD_CHANNEL = -1

- set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, 6.0, 0.3, 0.3, HOLD_TIME)
+ set_hudmessage(HUD_COLOR[0] , HUD_COLOR[1] , HUD_COLOR[2] , HUD_POSITION_X , HUD_POSITION_Y , 0, 8.0, HOLD_TIME, 0.3, 0.3, HUD_CHANNEL)

Hy, once again Thanks !! For noticing these small errors, I updated the code.

Special Round- Knife Round Plugin Not Working

DrStrange

BlackSignature

DrStrange

BlackSignature

Вложения

DrStrange

BlackSignature

DrStrange

BlackSignature

DrStrange

BlackSignature

DrStrange

BlackSignature

DrStrange

BlackSignature

DrStrange

BlackSignature

DrStrange

Пользователи, просматривающие эту тему