Плагин/Модуль DodFun не найден

[EOS]

Добрый вечер. Хочу обнулить игроку очки и смерти, и нашёл либу dodfun и хочу её использовать для этой цели, но нет либо самого плагина или модуля. Сервер ReHLDS.

 

[Алексеич]

EOS, в чем тут модификация?

 

[EOS]

Алексеич,

#include <dodfun>

dod_set_user_score(id, 0) // Вот эту функцию юзаю

Далее запускаю сервер. И вот лог.

[AMXX] Plugin "zombie_project.amxx" failed to load: Module/Library "dodfun" required for plugin. Check modules.ini.

 

[Nordic Warrior]

EOS, ты делаешь для игры Day of Defeat?

 

[EOS]

Nordic Warrior, Нет. Зомби мод.

 

[Nordic Warrior]

EOS, Counter-Strike?

 

[EOS]

Та же самая ошибка и с cstrike

2 Окт 2023

Nordic Warrior, Да

 

[Nordic Warrior]

EOS, а, ну так вот, модуль dodfun это для игры Day of Defeat.

 

[EOS]

Nordic Warrior, Как мне тогда установить игроку очки и смерти?

 

[Nordic Warrior]

EOS, есть несколько способов, например если использовать ReAPI, то:

set_entvar(id, var_frags, фраги) // Обратить внимание, что для этого способа используется число с плавающей точкой, то есть например 1.0
set_member(id, m_iDeaths, смерти)

Пример в плагине обнуления счёта:

Спойлер

#include <amxmodx>
#include <reapi>

new const VERSION[] = "1.1.1";

new g_iMessageIdScoreInfo;

public plugin_init()
{
    register_plugin("Reset Score", VERSION, "Nordic Warrior");

    register_clcmd("say /rs", "ResetScore");
    register_clcmd("say .кы", "ResetScore");
    register_clcmd("say_team /rs", "ResetScore");
    register_clcmd("say_team .кы", "ResetScore");

    g_iMessageIdScoreInfo = get_user_msgid("ScoreInfo");
}

public ResetScore(id)
{
    if(!is_user_connected(id))
        return;

    set_entvar(id, var_frags, 0.0);
    set_member(id, m_iDeaths, 0);

    UpdateScoreBoard(id);

    client_print_color(id, print_team_default, "^3[^4RS^3] ^4Игрок ^3%n, ^4ваш счёт успешно обнулён.", id);

    rg_send_audio(id, "buttons/bell1.wav");
}

stock UpdateScoreBoard(const id)
{
    message_begin(MSG_BROADCAST, g_iMessageIdScoreInfo);
    write_byte(id);
    write_short(0);
    write_short(0);
    write_short(0);
    write_short(get_member(id, m_iTeam));
    message_end();
}

Так же стоит обратить внимание на то, что чтобы счёт (смерти) обновился в таблице счёта, нужно либо вручную отправлять сообщение ScoreInfo, либо вместо примера выше, использовать специальный натив, имеющий в себе функционал обновления счёта в таблице, cs_set_user_deaths.

 

[fl0wer]

Nordic Warrior, Как мне тогда установить игроку очки и смерти?

Можешь использовать модуль fun, делает тоже самое, только не для dod.