ошибка компиляции

Статус
В этой теме нельзя размещать новые ответы.
Сообщения
173
Реакции
6
Ошибка
// C:\Users\Denys\Desktop\scripting\jb_reasons.sma(1) : error 010: invalid function or declaration
//
// 1 Error.
// Could not locate output file C:\Users\Denys\Desktop\scripting\compiled\jb_reasons.amx (compile failed).
Компилятор
Локальный
Amx Mod X
1.9.0
Исходный код
#include <amxmodx>
#include <amxmisc>
#include <colored_print>

#define PLUGIN "[JB] Reasons"
#define VERSION "1.0"
#define AUTHOR "x3"

new const g_reasons[][] =
{
"Не выполнил приказ ",
"Проиграл в игру",
"Нападение на охрану",
"Ношение оружия",
"Зашёл в оружейку",
"Случайно, дам фд"
}

const KEYSMENU = (1<<0)|(1<<1)|(1<<2)|(1<<3)|(1<<4)|(1<<5)|(1<<6)|(1<<9)
new g_victim[33]
new bool:g_allow[33]

public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR)
register_event("DeathMsg", "event_DeathMsg", "a")
register_menu("Reason Menu", KEYSMENU, "menu_reason")
register_clcmd("jail_reason", "clcmd_jail_reason")
}

public event_DeathMsg()
{
static killer, victim, menu[256], len, i
killer = read_data(1)
victim = read_data(2)

if (get_user_team(killer) == 2 && get_user_team(victim) == 1)
{
g_victim[killer] = victim
len = 0
len += formatex(menu[len], charsmax(menu) - len, "\yВыберите причину^n^n")
for (i = 0;i < sizeof(g_reasons);i++)
len += formatex(menu[len], charsmax(menu) - len, "\r%d.\w %s^n", i + 1, g_reasons[i])

len += formatex(menu[len], charsmax(menu) - len, "\r7.\w Своя причина^n")
len += formatex(menu[len], charsmax(menu) - len, "^n^n\r0.\w Выход")
show_menu(killer, KEYSMENU, menu, -1, "Reason Menu")
}
}

public menu_reason(id, key)
{
static message[192]
switch (key)
{
case 0, 1, 2, 3, 4, 5:
{
static kname[32], vname[32]
get_user_name(id, kname, charsmax(kname))
get_user_name(g_victim[id], vname, charsmax(vname))
formatex(message, charsmax(message), "^x04[Jail] ^x03%s ^x01убил ^x03%s^x01, причина: ^x04%s", kname, vname, g_reasons[key])
colored_print(0, message)
}
case 6:
{
g_allow[id] = true
client_cmd(id, "messagemode jail_reason")
}
}

return PLUGIN_HANDLED
}

public clcmd_jail_reason(id)
{
if (g_allow[id])
{
static kname[32], vname[32], message[192]
read_args(message, charsmax(message))
remove_quotes(message)
trim(message)

if (!equal(message, ""))
{
get_user_name(id, kname, charsmax(kname))
get_user_name(g_victim[id], vname, charsmax(vname))
format(message, charsmax(message), "^x04[Jail] ^x03%s ^x01убил ^x03%s^x01, причина: ^x04%s", kname, vname, message)
colored_print(0, message)
}
g_allow[id] = false
}

return PLUGIN_HANDLED
}
заранее, спасибо за помощь
 
В этой теме было размещено решение! Перейти к решению.
Сообщения
77
Реакции
30
Помог
2 раз(а)
у меня скомпилировался, проверь инклуды
 
Сообщения
491
Реакции
339
Помог
11 раз(а)
Доисторический инклуд цветного чата. Заменил на вшитый в amxmodx 1.9.0.

Код:
#include <amxmodx>
#include <amxmisc>

#define PLUGIN "[JB] Reasons"
#define VERSION "1.0"
#define AUTHOR "x3"

new const g_reasons[][] =
{
    "Не выполнил приказ ",
    "Проиграл в игру",
    "Нападение на охрану",
    "Ношение оружия",
    "Зашёл в оружейку",
    "Случайно, дам фд"
}

const KEYSMENU = (1<<0)|(1<<1)|(1<<2)|(1<<3)|(1<<4)|(1<<5)|(1<<6)|(1<<9)
new g_victim[33]
new bool:g_allow[33]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event("DeathMsg", "event_DeathMsg", "a")
    register_menu("Reason Menu", KEYSMENU, "menu_reason")
    register_clcmd("jail_reason", "clcmd_jail_reason")
}

public event_DeathMsg()
{
    static killer, victim, menu[256], len, i
    killer = read_data(1)
    victim = read_data(2)
    
    if (get_user_team(killer) == 2 && get_user_team(victim) == 1)
    {
        g_victim[killer] = victim
        len = 0
        len += formatex(menu[len], charsmax(menu) - len, "\yВыберите причину^n^n")
        for (i = 0;i < sizeof(g_reasons);i++)
            len += formatex(menu[len], charsmax(menu) - len, "\r%d.\w %s^n", i + 1, g_reasons[i])
            
        len += formatex(menu[len], charsmax(menu) - len, "\r7.\w Своя причина^n")           
        len += formatex(menu[len], charsmax(menu) - len, "^n^n\r0.\w Выход")
        show_menu(killer, KEYSMENU, menu, -1, "Reason Menu")
    }
}

public menu_reason(id, key)
{
    switch (key)
    {
        case 0, 1, 2, 3, 4, 5: client_print_color(0, print_team_default, "^4[Jail]^3 %n ^1убил^3 %n^1, причина:^4 %s", id, g_victim[id], g_reasons[key]);

        case 6:
        {
            g_allow[id] = true
            client_cmd(id, "messagemode jail_reason")
        }
    }
    
    return PLUGIN_HANDLED
}

public clcmd_jail_reason(id)
{
    if (g_allow[id])
    {
        static message[192]
        read_args(message, charsmax(message))
        remove_quotes(message)
        trim(message)
        
        if(!equal(message, ""))
            client_print_color(0, print_team_default, "^4[Jail]^3 %n ^1убил^3 %n^1, причина:^4 %s", id, g_victim[id], message);

        g_allow[id] = false
    }
    
    return PLUGIN_HANDLED
}
 
Статус
В этой теме нельзя размещать новые ответы.

Пользователи, просматривающие эту тему

Сейчас на форуме нет ни одного пользователя.
Сверху Снизу