Поиск Disable spray logo plugin

[mIDnight]

Search for spray disable logo plugin, priority on reapi if possible

 

[maFFyoZZyk]

#include <amxmodx>
#include <engine>

#define CHAT_TIME 5.0   
    // Время в которое, сообщение не будет отображаться (чтобы не было флуда)
    // Закомментируйте, если вам не нужно оповещение в чат

public plugin_init()
{
    register_plugin("Spray Block", "0.4", "neugomon")
    register_impulse(201, "logo")
    register_impulse(101, "flashlight")
}
public logo(id)
{
#if defined CHAT_TIME
    static Float:fLastTime[33], Float:fCurTime;

    fCurTime = get_gametime();
    if(is_user_alive( id ) && (fCurTime - fLastTime[id] > CHAT_TIME))
    {
        client_print(id, print_center, "На сервере запрещено использование спрея");
        fLastTime[id] = fCurTime;
    }
#endif
    
    return 1
}
public flashlight(id)    return 1;

 

[mIDnight]

Thanks, Is possible to be reworked to work without engine inc ?

 

[Nordic Warrior]

Midnight1337, RG_CBasePlayer_ImpulseCommands

 

[maFFyoZZyk]

Midnight1337, ну вот попробуй, я не тестировал, не знаю...будет ли оно работать...компилится, а вот за остальное я не знаю

#include <amxmodx>
#include <reapi>

#define CHAT_TIME 5.0   
    // Время в которое, сообщение не будет отображаться (чтобы не было флуда)
    // Закомментируйте, если вам не нужно оповещение в чат

public plugin_init()
{
    register_plugin("", "", "")
    RegisterHookChain(RG_CBasePlayer_ImpulseCommands, "CBasePlayer_ImpulseCommands", .post=false);
}
public CBasePlayer_ImpulseCommands(const id)
{
    static impulse;
    impulse = get_entvar(id, var_impulse);
#if defined CHAT_TIME
    static Float:fLastTime[33], Float:fCurTime;

    fCurTime = get_gametime();
#endif
    switch(impulse)
    {
        case 201:
        {
#if defined CHAT_TIME
            if(is_user_alive( id ) && (fCurTime - fLastTime[id] > CHAT_TIME))
            {
                client_print(id, print_center, "На сервере запрещено использование спрея");
                fLastTime[id] = fCurTime;
            }
#endif
            set_entvar(id, var_impulse, 0);
            return HC_SUPERCEDE;
        }
        case 100:
        {
#if defined CHAT_TIME
            if(is_user_alive( id ) && (fCurTime - fLastTime[id] > CHAT_TIME))
            {
                client_print(id, print_center, "На сервере запрещено использование фонарика");
                fLastTime[id] = fCurTime;
            }
#endif
            set_entvar(id, var_impulse, 0);
            return HC_SUPERCEDE;
        }
    }
    return HC_CONTINUE;
}

 

[mIDnight]

maFFyoZZyk It's working thanks, just small edit please flashlight should not be blocked only spray

 

[mIDnight]

maFFyoZZyk i edited by my self is good to stay like this, should make any errors ?

#include <amxmodx>
#include <reapi>

public plugin_init()
{
    register_plugin("", "", "")
    RegisterHookChain(RG_CBasePlayer_ImpulseCommands, "CBasePlayer_ImpulseCommands", .post=false);
}
public CBasePlayer_ImpulseCommands(const id)
{
    set_entvar(id, var_impulse, 201);
    return HC_SUPERCEDE;
}
[code]

 

[maFFyoZZyk]

Midnight1337,

#include <amxmodx>
#include <reapi>

public plugin_init()
{
    register_plugin("", "", "")
    RegisterHookChain(RG_CBasePlayer_ImpulseCommands, "CBasePlayer_ImpulseCommands", .post=false);
}

public CBasePlayer_ImpulseCommands(const id)
{
    static impulse;
    impulse = get_entvar(id, var_impulse);

    if(impulse == 201)
    {
        set_entvar(id, var_impulse, 0);
        return HC_SUPERCEDE;
    }
    return HC_CONTINUE;
}

 

[mIDnight]

maFFyoZZyk Thank you so much.