Поиск ищу плагины для сервера кс 1.6

Сообщения
1
Реакции
0
Привет, форумчане!
Ищу плагин для сервера кс 1.6 который будет отображать только твои убийства или же когда убивают тебя, провел больше часа в поисках и ничего не нашел.
 

ssx

Сообщения
272
Реакции
71
Раньше, когда постоянно было 32\32 на HL DM сервере, использовал такой вот плагин (вроде как сам писал для себя), чтобы отображало только свои киллы\смерти ибо при мясе не успеваешь читать.

Код:
#include <amxmodx>

public plugin_init()
{
    register_plugin("Death Messages", "1.0", "SSX")
    new mod_name[32];
    get_modname(mod_name, 31);
    if (equal(mod_name, "cstrike") )
    {
        register_event("DeathMsg", "OnDeathMsg", "a")
    }
    else
    {
        register_event("DeathMsg", "OnDeathMsg_HL", "a")
    }

    register_message(get_user_msgid("DeathMsg"),"message");
}

public message(msg_id,msg_dest,msg_entity)
{
    return PLUGIN_HANDLED;
}

public OnDeathMsg()
{
    new killer = read_data(1)
    new victim = read_data(2)
    new headshot = read_data(3)
    new weapon[32]
    read_data( 4, weapon, charsmax(weapon) )

    make_deathmsg(killer,victim,headshot, weapon)
}

public OnDeathMsg_HL()
{
    new killer = read_data(1)
    new victim = read_data(2)
    new weapon[32]
    read_data( 3, weapon, charsmax(weapon) )

    make_deathmsg_hl(killer,victim, weapon)
}
stock make_deathmsg_hl(killer, victim, const weapon[])
{
    if (is_user_connected(killer) )
    {
        message_begin(MSG_ONE, get_user_msgid("DeathMsg"), {0,0,0}, killer);
        write_byte(killer);
        write_byte(victim);
        write_string(weapon);
        message_end();
    }

    if (is_user_connected(victim) && killer != victim)
    {
        message_begin(MSG_ONE, get_user_msgid("DeathMsg"), {0,0,0}, victim);
        write_byte(killer);
        write_byte(victim);
        write_string(weapon);
        message_end();
    }

    return 1;
}

П.С. Вспомнил что хотел переделать этот плагин чтобы отображал свои киллы\смерти + те что в радиусе n юнитов от меня.
 
Сообщения
182
Реакции
42
Помог
4 раз(а)
его искал?
Код:
#include <amxmodx>
#include <reapi>

new sprites[][] = {
    "",
    "number_1",
    "number_2",
    "number_3",
    "number_4",
    "number_5",
    "number_6",
    "number_7",
    "number_8",
    "number_9"
}

new g_maxplayers,g_statusicon
new cvColor,cvBlinkTime,cvOverCount
new idid[33]
new clor[3]
new Float:blinkTime
new overCountSpr[40]

#define RESETBLINK_TASKID    45454

public plugin_init(){
    register_plugin("[ReAPI] Kills Counter","0.3","serfreeman1337")
   
    g_maxplayers = get_member_game(m_nMaxPlayers);
    g_statusicon = get_user_msgid("StatusIcon")
   
    cvColor = register_cvar("ks_color","255 255 0")
    cvBlinkTime = register_cvar("ks_blink_time","2.0")
    cvOverCount = register_cvar("ks_over_count_spr","dmg_rad")

    RegisterHookChain(RG_CBasePlayer_Killed, "CBasePlayer_Killed", true);
    RegisterHookChain(RG_CBasePlayer_Spawn, "CBasePlayer_Spawn", true);
}

public plugin_cfg(){
    new data[20],raw[3][5]
    get_pcvar_string(cvColor,data,19)
   
    parse(data,raw[0],4,raw[1],4,raw[2],4)
   
    clor[0] = str_to_num(raw[0])
    clor[1] = str_to_num(raw[1])
    clor[2] = str_to_num(raw[2])
   
    blinkTime = get_pcvar_float(cvBlinkTime)
    get_pcvar_string(cvOverCount,overCountSpr,39)
}

public CBasePlayer_Spawn(id)
    icon(id,0)
   
public CBasePlayer_Killed(victim, killer)
{
    if (0 < killer <= g_maxplayers)
    {
        if (get_member(victim, m_iTeam) != get_member(killer, m_iTeam) && is_user_alive(killer))
            icon(killer,1);
    }
   
    icon(victim,0)
}

public icon(id,style){
    if(!style){
        if(!idid[id])
            return PLUGIN_CONTINUE
           
        message_begin(MSG_ONE,g_statusicon,_,id)
        write_byte(0)
        write_string(idid[id] < 10 ? sprites[idid[id]] : overCountSpr)
        message_end()
       
        idid[id] = 0
       
        return PLUGIN_CONTINUE
    }
   
    if(0 < idid[id] < 10){
        message_begin(MSG_ONE,g_statusicon,_,id)
        write_byte(0)
        write_string(sprites[idid[id]])
        message_end()
    }
   
    idid[id] ++

    message_begin(MSG_ONE,g_statusicon,_,id)
    write_byte(blinkTime > 0.0 ? 2 : 1)
    write_string(idid[id] < 10 ? sprites[idid[id]] : overCountSpr)
    write_byte(clor[0])
    write_byte(clor[1])
    write_byte(clor[2])
    message_end()
   
    if(blinkTime > 0.0){
        remove_task(RESETBLINK_TASKID + id)
        set_task(2.0,"resetblink",RESETBLINK_TASKID + id)
    }
   
    return PLUGIN_CONTINUE
}

public resetblink(tId){
    new id = tId - RESETBLINK_TASKID
   
    if(!is_user_connected(id))
        return
   
    message_begin(MSG_ONE,g_statusicon,_,id)
    write_byte(1)
    write_string(idid[id] < 10 ? sprites[idid[id]] : overCountSpr)
    write_byte(clor[0])
    write_byte(clor[1])
    write_byte(clor[2])
    message_end()
}
 

Вложения

Пользователи, просматривающие эту тему

Сейчас на форуме нет ни одного пользователя.
Сверху Снизу