Поиск ищу возрождение игрока

Статус
В этой теме нельзя размещать новые ответы.
Сообщения
142
Реакции
-14
Обратите внимание, если вы хотите заключить сделку с этим пользователем, он заблокирован
Доброе утро) видел где то плагин на то что когда первых двух игроков убивают за обе стороны команды то они возрождаются
не могу вспомнить как назывался и где валялся данный плагин
 
Сообщения
142
Реакции
-14
Обратите внимание, если вы хотите заключить сделку с этим пользователем, он заблокирован
Решено!
 
Сообщения
1,539
Реакции
2,318
Помог
39 раз(а)
что-то мы решения не видим...
 
Сообщения
142
Реакции
-14
Обратите внимание, если вы хотите заключить сделку с этим пользователем, он заблокирован
Сообщения
11
Реакции
1
Код:
/* AMX Mod X - Script
*   Copyright © 2014 AMX-X - L]Ep6Ep.
*   https://vk.com/amxx.scripts
*
*  29.12.18 beta - обновить .amxx файл
*  [!] Исправили квар fpr_time
*  [!] Исправили чат-сообщение, теперь не спамит
*
*  BETA 1.0
*  [#] - релиз
*/
#include <amxmodx>
#include <cstrike>
#include <fakemeta_util>
#include <hamsandwich>
#if AMXX_VERSION_NUM < 183
   #include <colorchat>
#endif
new firstsplayers, firstsplayerr, cvar_round, cvar_money,
   cvar_players, cvar_te, cvar_ct, cvar_timegod, Curret_Round, cvar_time1, cvar_time2;

public plugin_init() {
   register_plugin("FirstPlayersRespawn", "29.12.18 beta", "L]Ep6Ep.")
   register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
   register_event("TextMsg", "event_game_restart", "a", "2=#Game_will_restart_in")
   register_event("TextMsg", "event_game_restart", "a", "2=#Game_Commencing")
}
public plugin_cfg() {
   server_cmd("exec addons/amxmodx/configs/FirstPlayersRespawn.cfg")
   cvar_te = register_cvar("fpr_players_t", "2")
   cvar_ct = register_cvar("fpr_players_ct", "2")
   cvar_time1 = register_cvar("fpr_time", "30")
   cvar_round = register_cvar("fpr_firstround", "1")
   cvar_players = register_cvar("fpr_minplayers", "10")
   cvar_timegod = register_cvar("fpr_protection", "3")
   cvar_money = register_cvar("fpr_money", "650")
   cvar_time2 = register_cvar("fpr_time_death", "3")
}
public client_death(killer, victim) {
   if(Curret_Round < get_pcvar_num(cvar_round) || get_playersnum() < get_pcvar_num(cvar_players)) {
      if(firstsplayers < get_pcvar_num(cvar_te)) {
         if(get_user_team(victim) == 1) {
            firstsplayers++
            set_task(get_pcvar_float(cvar_time2), "respawn", victim)
            client_print_color(victim, print_team_default, "^1[^4SPAWN^1] ^3Первые ^4%d ^3игрока возрождаются", get_pcvar_num(cvar_te))
         }
      }
      if(firstsplayerr < get_pcvar_num(cvar_ct)) {
         if(get_user_team(victim) == 2) {
            firstsplayerr++
            set_task(get_pcvar_float(cvar_time2), "respawn", victim)
            client_print_color(victim, print_team_default, "^1[^4SPAWN^1] ^3Первые ^4%d ^3игрока возрождаются", get_pcvar_num(cvar_ct))
         }
      }
   }
}
public respawn(id) {
   ExecuteHamB(Ham_CS_RoundRespawn, id)
   cs_set_user_money(id, cs_get_user_money(id) + get_pcvar_num(cvar_money))
   fm_set_user_godmode(id, 1)
   set_task(get_pcvar_float(cvar_timegod), "offgodmod", id)
}
public offgodmod(id)
   fm_set_user_godmode(id, 0)
public event_game_restart()
   Curret_Round = 0
public event_round_start() {
   firstsplayers = 0
   firstsplayerr = 0
   Curret_Round++
   set_task(get_pcvar_float(cvar_time1), "first_off")
}
public first_off() {
   firstsplayerr++
   firstsplayers++
}
/* Copyright © 2014 AMX-X - L]Ep6Ep. */
Код:
#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "1.0"
#define MAXCLIENTS 32
#define TASK_INDEX_GUARD 2819232
#define TASK_INDEX_SPAWN 2182023

#define fm_get_user_money(%0) get_pdata_int(%0, 115)

#if AMXX_VERSION_NUM < 183
    #include <colorchat>
    #define client_disconnected client_disconnect
#endif

new g_iSpawnCounts, bool:g_iSpawnBlock = false;

public plugin_init() {
    register_plugin("First players respawn", VERSION, "OverGame");
    
    register_cvar("fpr_online", "10");
    register_cvar("fpr_spawn_count", "3");
    register_cvar("fpr_spawn_time", "10.0");
    register_cvar("fpr_spawn_money", "300");
    register_cvar("fpr_spawn_godmode", "5.0");
    
    register_logevent("LogEvent_RoundStart", 2, "1=Round_Start");
    register_logevent("LogEvent_RoundEnd", 2, "1=Round_End");
    RegisterHam(Ham_Killed, "player", "PlayerKilled_Post", true);
    RegisterHam(Ham_Spawn, "player", "PlayerSpawn_Post", true);
}

public client_disconnected(id) {
    remove_task(TASK_INDEX_GUARD + id);
}

public LogEvent_RoundStart() {
    new iPlayers = get_cvar_num("fpr_online");
    g_iSpawnCounts = get_cvar_num("fpr_spawn_count");
    
    if(get_playersnum() >= iPlayers) {
        g_iSpawnBlock = false;
        
        new Float:fTime = get_cvar_float("fpr_spawn_time");
        set_task(fTime, "BlockSpawn", TASK_INDEX_SPAWN);
        
        client_print_color(0, print_team_default, "^04[RESPAWN] ^01Доступно спавнов ^04[%d] ^01в течение ^04[%d] ^01сек!", g_iSpawnCounts, floatround(fTime));
    }
    else {
        g_iSpawnBlock = true;
    }
}

public LogEvent_RoundEnd() {
    for(new id = 1; id <= MAXCLIENTS; id++) {
        if(!is_user_connected(id)) {
            continue;
        }
        
        if(is_user_alive(id) && fm_get_user_godmode(id))
            fm_set_user_godmode(id, false);
        
        remove_task(TASK_INDEX_GUARD + id);
    }
    
    remove_task(TASK_INDEX_SPAWN);
}

public BlockSpawn(i_Task) {
    g_iSpawnBlock = true;
}

public PlayerKilled_Post(i_Victim) {
    if(!g_iSpawnBlock && g_iSpawnCounts) {
        g_iSpawnCounts--;
        ExecuteHamB(Ham_CS_RoundRespawn, i_Victim);
    }
}

public PlayerSpawn_Post(id) {
    new Float:fTime = get_cvar_float("fpr_spawn_godmode");
    
    if(fTime > 0.0) {
        fm_set_user_godmode(id, true);
        set_task(fTime, "Guard_OffTime", TASK_INDEX_GUARD + id);
    }
    
    new iMoney = get_cvar_num("fpr_spawn_money");
    
    if(iMoney > 0) {
        fm_set_user_money(id, fm_get_user_money(id) + iMoney);
    }
}

public Guard_OffTime(id) {
    id = id - TASK_INDEX_GUARD;
    
    if(is_user_connected(id)) {
        fm_set_user_godmode(id, false);
    }
}

stock fm_set_user_money(index, count, flash = true) {
    set_pdata_int(index, 115, count);
    message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("Money"), _, index);
    write_long(count);
    write_byte(flash ? 1 : 0);
    message_end();
    
    return true;
}

stock fm_get_user_godmode(index) {
    new Float:val;
    pev(index, pev_takedamage, val);

    return (val == DAMAGE_NO);
}

stock fm_set_user_godmode(index, godmode = 0) {
    set_pev(index, pev_takedamage, godmode == 1 ? DAMAGE_NO : DAMAGE_AIM);

    return 1;
}
 

Download all Attachments

Статус
В этой теме нельзя размещать новые ответы.

Пользователи, просматривающие эту тему

Сейчас на форуме нет ни одного пользователя.
Сверху Снизу