ZP Kill Rewards. Выпадание мешков при режимах

WILL_BE · 11 Дек 2017

Приветствую всех! Не могу разобраться в определенном участке кода. Суть плагина: с игроков при убийстве выпадает мешок с ammo, я немного переделал под свои нужды, выставил в каких случаях и сколько должно выпадать с мешка ammo. Проблема заключается в том, что при

Код:

if(!zp_get_user_nemesis(toucher) && zp_is_nemesis_round() || !zp_get_user_survivor(toucher) && zp_is_survivor_round() || !zp_get_user_sniper(toucher) && zp_is_sniper_round() || !zp_get_user_assassin(toucher) && zp_is_assassin_round())

выпадают мешки с игроков в 20 ammo, а должно быть (к примеру): режим Немезиды, убив Немезиду выпадает мешок с 20 ammo, Немезида убив человека выпадает мешок с 2 ammo. Прошу наставления на путь истинный :)

SergeyShorokhov · 12 Дек 2017

И только в режиме Special-Round такие сладости валятся? или в целом, на протяжении игры?

WILL_BE написал(а):
Немезида убив человека

1) этот момент я не увидел где отлавливается. А, нигде :derisive:

.
По идее в моменте убийства - должно определяться кол-во AmmoPack в мешке.

2) Выноси в отдельную функцию код, который упростит тебе задачу по логическому решению.
К примеру:

Код:

public fwd_Touch(toucher, touched)
{
...
    zp_give_user_ammo_packs(toucher, GetAmmoBonusCount(toucher));
...
}

const COUNT_FOR_SPECIAL = 2;
const COUNT_FOR_PLAYERS = 20;
GetAmmoBonusCount(pPlayer)
{
    if(zp_is_nemesis_round() && !zp_get_user_nemesis(pPlayer)
        || (zp_is_survivor_round() && !zp_get_user_survivor(pPlayer))
        || (zp_is_sniper_round() && !zp_get_user_sniper(pPlayer))
        || (zp_is_assassin_round() && !zp_get_user_assassin(pPlayer))
    )
        return COUNT_FOR_PLAYERS;
    else
        return COUNT_FOR_SPECIAL;
}

WILL_BE · 12 Дек 2017

Код:

warning 209: function "GetAmmoBonusCount" should return a value

Всегда хотел узнать, как правильно убирать ошибку с return'om?

SergeyShorokhov · 12 Дек 2017

WILL_BE покажи функцию

WILL_BE · 12 Дек 2017

wopox1337, твой пример выше

SergeyShorokhov · 12 Дек 2017

WILL_BE, странно. Убери тогда else. люблю этот компилятор

WILL_BE · 13 Дек 2017

завтра приду, проверю

WILL_BE · 14 Дек 2017

wopox1337, что твоя версия, что моя, различий в корректной работоспособности - 0 :)

14 Дек 2017

Видимо, некорректно указал ошибку: Если в режимах (к примеру Немезида), Немезида убьет человека, а другой человек подберет мешок, то ему выпадет 20 аммо, за место корректного 2.

SergeyShorokhov · 14 Дек 2017

wopox1337 написал(а):
1) этот момент я не увидел где отлавливается. А, нигде .

WILL_BE · 14 Дек 2017

Я к этому и ввиду, что не знаю как правильно это сделать, и прошу помощи у куда более опытных :)

SergeyShorokhov · 15 Дек 2017

WILL_BE, на моменте смерти определяй убийцу (человек или Немезида и прочее).

И передавай в функцию создания пакета инфу эту. На pev пакета, допустим pev_iuser4 выставляй кол-во аммопаков, которое содержит. На таче эту инфу используй.

WILL_BE · 15 Дек 2017

wopox1337, Если правильно понимаю, то в

Код:

fw_PlayerKilled

определяю кто убийца, далее в

Код:

fwd_Touch

показываю отлов кто убил,
а вот последнее про pev не понял.

SergeyShorokhov · 15 Дек 2017

WILL_BE, ну, к примеру, в момент смерти можем узнать кто был убитым, и соответственно информацию передать в функцию добавления мешка на карту fn addItem()

Код:

public fw_PlayerKilled(victim, attacker, shouldgib)
{
    static Float: fOrigin[3];
    pev(victim, pev_origin, fOrigin);

    addItem(fOrigin, GetAmmoBonusCount(victim));
}

WILL_BE написал(а):
про pev не понял

Создание entity( для начинающих )
вот тут можешь ознакомиться с некоторым составом PEV (Private Entity Variable - приватная переменная у entity)
весь движок почти построен на pev, по отношению как миниум к entity. Каждая entity имеет свои данные, в которые мы имеем возможность:

Записывать (set_pev, set_pdata_*, entity_set_*, set_entvar, set_member);
Читать (pev, get_pdata_*, entity_get_*, get_entvar, get_member).

различными модулями по мере необходимости. Естественно, большинство данных entity были ранее созданы для Half-Life, позже портированы, и доработаны для мода Counter-Strike. Для entity игроков - большинство PEV заняты и используются.
Но, для созданной нами entity: (она имеет больший список PEV, из за наследования класса CBaseEntity)

Код:

new ent = fm_create_entity("info_target") // создаём entity класса "info_target"

много PEV свободных. Мы их и можем использовать под наши задачи, к примеру: хранение кол-ва AmmoPack'ов в пакете.

SergeyShorokhov · 25 Янв 2018

ясно, видимо не осилил WILL_BE .

Вот код.

Код:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta_util>
#include <zombie_plague_advance>
#include <hamsandwich>
#include <fakemeta>
// #include <engine>

const COUNT_FOR_SPECIAL = 2;
const COUNT_FOR_PLAYERS = 20;

#define zp_give_user_ammo_packs(%0,%1)    zp_set_user_ammo_packs(%0, zp_get_user_ammo_packs(%0) + %1)
const pev_ammocount = pev_iuser4;

#define PLUGIN "[ZPA] Addon: Kill Rewards"
#define VERSION "2.1"
#define AUTHOR "freelanser & WILL BE"

new const item_class_name[] = "zAmmoPack"

/* Here you can change the model */
new g_model[] = "models/pza_mok.mdl"

/* Here is the sound, when you take it */
new sound[]   =  { "pza_ammo_sound.wav" }

public plugin_precache()
{
    precache_model(g_model)
    precache_sound(sound)
}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

    register_forward(FM_Touch, "fwd_Touch")
    RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")
     register_event("HLTV", "EVENT_round_start", "a", "1=0", "2=0")
}

public EVENT_round_start()
{
    deleteAllItems()
}

public deleteAllItems()
{
    new ent = FM_NULLENT
    static string_class[] = "classname"
    while((ent = engfunc(EngFunc_FindEntityByString, ent, string_class, item_class_name)))
        set_pev(ent, pev_flags, FL_KILLME)
}

public addItem(Float: fOrigin[3], AmmoCount)
{
    new ent = fm_create_entity("info_target")
    set_pev(ent, pev_classname, item_class_name)
 
    engfunc(EngFunc_SetModel,ent, g_model)

    set_pev(ent,pev_mins,Float:{-10.0,-10.0,0.0})
    set_pev(ent,pev_maxs,Float:{10.0,10.0,25.0})
    set_pev(ent,pev_size,Float:{-10.0,-10.0,0.0,10.0,10.0,25.0})
    engfunc(EngFunc_SetSize,ent,Float:{-10.0,-10.0,0.0},Float:{10.0,10.0,25.0})

    set_pev(ent,pev_solid,SOLID_BBOX)
    set_pev(ent,pev_movetype,MOVETYPE_TOSS)
 
    set_pev(ent, pev_origin, fOrigin)
    set_pev(ent, pev_ammocount, AmmoCount)
     
    set_pev(ent, pev_renderfx, kRenderFxGlowShell)

    static Float:velocity[3];
    pev(ent,pev_velocity,velocity);
    velocity[2] = random_float(265.0,285.0);
    set_pev(ent,pev_velocity,velocity)

    switch(random_num(1,4))
    {
        case 1: set_pev(ent,pev_rendercolor,Float:{0.0,0.0,255.0})
        case 2: set_pev(ent,pev_rendercolor,Float:{0.0,255.0,0.0})
        case 3: set_pev(ent,pev_rendercolor,Float:{255.0,0.0,0.0})
        case 4: set_pev(ent,pev_rendercolor,Float:{255.0,255.0,255.0})
    }
}

public fwd_Touch(toucher, touched)
{
    if (!is_user_alive(toucher) || !pev_valid(touched))
        return FMRES_IGNORED
 
    new classname[32]
    pev(touched, pev_classname, classname, charsmax(classname))

    if (!equal(classname, item_class_name))
        return FMRES_IGNORED

    zp_give_user_ammo_packs(toucher, pev(touched, pev_ammocount));

    emit_sound(toucher, CHAN_AUTO, sound, 1.0, ATTN_NORM, 0, PITCH_NORM)
    set_pev(touched, pev_effects, EF_NODRAW)
    set_pev(touched, pev_solid, SOLID_NOT)
     
    return FMRES_IGNORED
}

public fw_PlayerKilled(victim, attacker, shouldgib)
{
    static Float: fOrigin[3];
    pev(victim, pev_origin, fOrigin);

    addItem(fOrigin, GetAmmoBonusCount(victim));
}

GetAmmoBonusCount(pPlayer)
{
    if(zp_is_nemesis_round() && !zp_get_user_nemesis(pPlayer)
        || (zp_is_survivor_round() && !zp_get_user_survivor(pPlayer))
        || (zp_is_sniper_round() && !zp_get_user_sniper(pPlayer))
        || (zp_is_assassin_round() && !zp_get_user_assassin(pPlayer))
    )
        return COUNT_FOR_PLAYERS;
    else
        return COUNT_FOR_SPECIAL;



    /* if(zp_is_nemesis_round() && !zp_get_user_nemesis(pPlayer)
        return COUNT_FOR_PLAYERS;
 
    if(zp_is_survivor_round() && !zp_get_user_survivor(pPlayer))
        return COUNT_FOR_PLAYERS;
 
    if(zp_is_sniper_round() && !zp_get_user_sniper(pPlayer))
        return COUNT_FOR_PLAYERS;
 
    if(zp_is_assassin_round() && !zp_get_user_assassin(pPlayer))
        return COUNT_FOR_PLAYERS
 
    else return COUNT_FOR_SPECIAL; */

}

WILL_BE · 26 Янв 2018

wopox1337, совсем забыл про тему, здоровьем занялся, благодарю.

ZP Kill Rewards. Выпадание мешков при режимах

WILL_BE

Вложения

SergeyShorokhov

WILL_BE

SergeyShorokhov

WILL_BE

SergeyShorokhov

WILL_BE

WILL_BE

SergeyShorokhov

WILL_BE

SergeyShorokhov

WILL_BE

SergeyShorokhov

SergeyShorokhov

WILL_BE

Пользователи, просматривающие эту тему